@AbapCatalog.sqlViewName: 'ILCMDOCUMENTTP'
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck:#CHECK
@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType : #TRANSACTIONAL
//@ObjectModel.modelCategory: #BUSINESS_OBJECT
@ObjectModel: {
representativeKey: 'LglCntntMDocumentUUID',
semanticKey: 'LglCntntMDocument',
//Only at Root
compositionRoot: true,
transactionalProcessingEnabled: true,
//All Levels
draftEnabled: true,
createEnabled: 'EXTERNAL_CALCULATION',
updateEnabled: 'EXTERNAL_CALCULATION',
deleteEnabled: 'EXTERNAL_CALCULATION',
writeActivePersistence: 'LCM_DOCUMENT',
writeDraftPersistence: 'LCM_DOCUMENT_D',
usageType.serviceQuality: #C,
usageType.sizeCategory: #XL,
usageType.dataClass: #TRANSACTIONAL,
entityChangeStateId:'LglCntntMChangedUTCDateTime'
}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.sapObjectNodeType.name:'LegalDocument'
@EndUserText.label: 'TP View for Legal Document'
define view I_LcmDocumentTP
as select from I_LcmDocument
// Stamps
association [0..*] to I_LglCntntMDocumentStampTP as _LglCntntMDocumentStampTP on $projection.LglCntntMDocumentUUID = _LglCntntMDocumentStampTP.LglCntntMDocumentUUID
// Template Metadata
association [1..1] to I_LglCntntMDocTemplateInfoTP as _LglCntntMDocTemplateInfoTP on $projection.LglCntntMDocumentUUID = _LglCntntMDocTemplateInfoTP.LglCntntMDocumentUUID
// Categories
association [0..*] to I_LglCntntMDocParCategoryTP as _LglCntntMDocParCategoryTP on $projection.LglCntntMDocumentUUID = _LglCntntMDocParCategoryTP.LglCntntMDocumentUUID
// Virtual document version
association [1..1] to I_LglCntntMVirtualDocVersTP as _LglCntntMVirtualDocVersTP on $projection.LglCntntMDocumentUUID = _LglCntntMVirtualDocVersTP.LglCntntMDocumentUUID
// Parent Document
association [0..*] to I_LcmDocument as _ParentDocument on $projection.LglCntntMParentDocument = _ParentDocument.LglCntntMDocument
// Status Changes
association [0..*] to I_LglCntntMDocStatusChgsTP as _LglCntntMDocStatusChgsTP on $projection.LglCntntMDocumentUUID = _LglCntntMDocStatusChgsTP.LglCntntMDocumentUUID
//Obligation
association [1..*] to I_LglCntntMDocObligationTP as _LglCntntMDocObligationTP on $projection.LglCntntMDocumentUUID = _LglCntntMDocObligationTP.LglCntntMDocumentUUID
// Aggregation
association [1..1] to I_LglCntntMDocAggregation as _LglCntntMDocAggregation on _LglCntntMDocAggregation.LglCntntMDocumentUUID = $projection.LglCntntMDocumentUUID
//Extension
association [1..1] to E_LegalDocument as _Extenstion on $projection.LglCntntMDocumentUUID = _Extenstion.LglCntntMDocumentUUID
//Template
association [0..1] to I_LglCntntMTemplate as _LglCntntMTemplate on $projection.LglCntntMTmplUUID = _LglCntntMTemplate.LglCntntMTmplUUID
//Document Agreement
association [0..1] to I_LglCntntMDocAgreementTP as _LglCntntMDocAgreementTP on $projection.LglCntntMDocumentUUID = _LglCntntMDocAgreementTP.LglCntntMDocumentUUID
{
// LCM Document
key I_LcmDocument.LglCntntMDocumentUUID as LglCntntMDocumentUUID,
I_LcmDocument.LglCntntMDocument as LglCntntMDocument,
I_LcmDocument.LglCntntMDocumentLinkedObject as LglCntntMDocumentLinkedObject,
I_LcmDocument.LglCntntMDocumentLinkedObjKey as LglCntntMDocumentLinkedObjKey,
I_LcmDocument.LglCntntMDocumentIsTopVersion as LglCntntMDocumentIsTopVersion,
I_LcmDocument.LegalTransaction as LegalTransaction,
I_LcmDocument.LegalTransactionUUID as LegalTransactionUUID,
I_LcmDocument.LegalTransactionTitle as LegalTransactionTitle,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
I_LcmDocument.LglCntntMDocContentType as LglCntntMDocContentType,
// @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
I_LcmDocument.LglCntntMLanguage as LglCntntMLanguage,
I_LcmDocument.LglCntntMParentDocument as LglCntntMParentDocument,
I_LcmDocument.LglCntntMDocAccessLvl as LglCntntMDocAccessLvl,
I_LcmDocument.LglCntntMChangedByUser as LglCntntMChangedByUser,
// @Semantics.systemDate.lastChangedAt: true
I_LcmDocument.LglCntntMChangedUTCDateTime as LglCntntMChangedUTCDateTime,
I_LcmDocument.LglCntntMCreatedByUser as LglCntntMCreatedByUser,
// @Semantics.systemDateTime.createdAt: true
I_LcmDocument.LglCntntMCreatedUTCDateTime as LglCntntMCreatedUTCDateTime,
I_LcmDocument.IsEndOfPurposeBlocked as IsEndOfPurposeBlocked,
I_LcmDocument.LglCntntMIsMandatory as LglCntntMIsMandatory,
//Data Aging
I_LcmDocument.LglCntntMAgingTemperature as LglCntntMAgingTemperature,
I_LcmDocument.DocumentDescription as DocumentDescription,
I_LcmDocument.LglCntntMProfile as LglCntntMProfile,
I_LcmDocument.InternalDocumentStatus as InternalDocumentStatus,
I_LcmDocument.LglCntntMSignatureDocStatus as LglCntntMSignatureDocStatus,
@VDM.lifecycle.status:#DEPRECATED
@VDM.lifecycle.successor: 'LegalDocumentVersion'
I_LcmDocument.DocumentVersion as DocumentVersion,
I_LcmDocument.LegalDocumentVersion as LegalDocumentVersion, //new field for document version number(NUMC4)
I_LcmDocument.LglCntntMDocType as LglCntntMDocType,
I_LcmDocument.LglCntntMDocAssemblyStatus as LglCntntMDocAssemblyStatus,
I_LcmDocument.LglCntntMLongTextUUID as LglCntntMLongTextUUID,
I_LcmDocument.LglCntntMLongText as LglCntntMLongText,
I_LcmDocument.LglCntntMLongTextMimeType as LglCntntMLongTextMimeType,
I_LcmDocument.LglCntntMTmplUUID as LglCntntMTmplUUID,
I_LcmDocument.LglCntntMVirtualDocVersKey as LglCntntMVirtualDocVersKey,
I_LcmDocument.LglCntntMVirtualDocSyncSts as LglCntntMVirtualDocSyncSts,
I_LcmDocument.LglCntntMCntxtDocUUID as LglCntntMCntxtDocUUID,
I_LcmDocument.LglCntntMCreatedFromDocUUID as LglCntntMCreatedFromDocUUID,
//API
I_LcmDocument.LegalDocumentSource as LegalDocumentSource,
//Legal document reference number
I_LcmDocument.LglCntntMDocReferenceNumber as LglCntntMDocReferenceNumber,
//Low touch document attributes
I_LcmDocument.LglCntntMDocLowTouchLevel as LglCntntMDocLowTouchLevel,
@ObjectModel.readOnly: true
I_LcmDocument.LglCntntMDocRefreshStatus as LglCntntMDocRefreshStatus,
// DMS attributes
// Changes done as part of CDS service quality
cast( '' as abap.char(200) ) as FileName,
cast( '' as abap.char(128) ) as MimeType,
cast( '' as dokar ) as DocumentInfoRecordDocType,
cast( '' as abap.char(25) ) as DocumentInfoRecordDocNumber,
cast( '' as abap.char(3) ) as DocumentInfoRecordDocPart,
cast( '' as abap.char(2) ) as DocumentInfoRecordDocVersion,
cast( '' as abap.char(32) ) as LogicalDocument,
cast( '' as abap.char(32) ) as PhysicalDocument,
cast( '' as sysuuid_c ) as FileUUID,
// Calculated flags and fields
'' as LglCntntMDocIsVersCreateEnable,
'' as LglCntntMDocumentHasStamp,
'' as LglCntntMDocIsCheckedIn,
'' as LglCntntMDocIsCrteStmpEnbld,
'' as LglCntntMDocIsCrteOblgnEnbld,
'' as LglCntntMDocIsFileChanged,
// Field used to control the variable push during VD creation
'' as LglCntntMIsVarblPushRqd,
cast( 00 as lcm_created_on ) as LglCntntMDocCheckOutTime,
'--' as LglCntntMDocPrevStatus,
cast( '' as lcm_doc_created_from ) as LegalDocumentCreatedFrom,
// Template Name
cast( '' as lcm_tmpl_name ) as LglCntntMTmplName,
// Fields for navigation to Virtual Document
// cast ('' as is_cloud_system ) as IsCloudSystem,
cast ('' as abap.char(4) ) as IsCloudSystem,
cast ( '' as abap.char(255) ) as LglCntntMDocVirtualDocURL,
cast ( case
when InternalDocumentStatus <> 'AC' or LglCntntMDocContentType = 'SAP1' then 'X'
else ''
end as lcm_amendment_is_hidden ) as LglCntntMAdminvUpdtIsHidden,
LglCntntMNmbrOfAdminvDocUpdt,
// LglCntntMMainDocument,
LglCntntMDocumentKind,
I_LcmDocument.LglCntntMDocPaperType as LglCntntMDocPaperType,
// Field to Download Virtual Document
cast ('' as abap.char(255) ) as LglCntntMVirtualDocDownloadURL,
// Read only attributes from Legal transaction and Context
@ObjectModel.readOnly: true
I_LcmDocument.LglCntntMGovLaw as LglCntntMGovLaw,
@ObjectModel.readOnly: true
_Context.LglCntntMContext as LglCntntMContext,
I_LcmDocument.LglCntntMDocLockedReasonCode as LglCntntMDocLockedReasonCode,
I_LcmDocument.LglCntntMDocIsToBeDeleted as LglCntntMDocIsToBeDeleted,
_LglCntntMTemplate.LglCntntMTmplID as LglCntntMTmplID,
LglCntntMCntxtDocumentID,
LglCntntMIsIntegRelevant,
// Child associations
// Stamps
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_LglCntntMDocumentStampTP,
// Template Metadata
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_LglCntntMDocTemplateInfoTP,
// Categories(Parent category)
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_LglCntntMDocParCategoryTP,
// Status Changes
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_LglCntntMDocStatusChgsTP,
//Virtual document version
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_LglCntntMVirtualDocVersTP,
// Obligations
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_LglCntntMDocObligationTP,
//Document Agreement
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_LglCntntMDocAgreementTP,
//Authorization
I_LcmDocument._LegalTransaction,
I_LcmDocument._DocAttach,
I_LcmDocument._ContentTypeText,
@Consumption.filter.hidden: true
I_LcmDocument._DocumentKindText,
@Consumption.filter.hidden: true
I_LcmDocument._AccessLvlText,
@Consumption.filter.hidden: true
I_LcmDocument._DocStatusText,
@Consumption.filter.hidden: true
I_LcmDocument._SgntrDocStatusText,
@Consumption.filter.hidden: true
I_LcmDocument._DocSyncStatusText,
@Consumption.filter.hidden: true
I_LcmDocument._LglCntntMDocLowTouchLvlTxt,
// @Consumption.filter.hidden: true
// I_LcmDocument._LglCntntMDocAutoRefreshTxt,
/*
@Consumption.filter.hidden: true
I_LcmDocument._AssemblyStatusText , */
I_LcmDocument._LglCntntMDocAssemblyInfo,
@Consumption.filter.hidden: true
I_LcmDocument._LglCntntMDocPaperTypeTxt,
_LglCntntMTemplate
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LCMCONTEXT",
"I_LCMDOCUMENT",
"I_LGLCNTNTMTEMPLATE"
],
"ASSOCIATED":
[
"E_LEGALDOCUMENT",
"I_LCMDOCUMENT",
"I_LEGALTRANSACTION",
"I_LGLCNTNTMACCESSLVLTEXT",
"I_LGLCNTNTMDOCAGGREGATION",
"I_LGLCNTNTMDOCAGREEMENTTP",
"I_LGLCNTNTMDOCASSEMBLYINFO",
"I_LGLCNTNTMDOCCONTENTTYPETEXT",
"I_LGLCNTNTMDOCINFOATTACHMENT",
"I_LGLCNTNTMDOCLOWTOUCHLVLTXT",
"I_LGLCNTNTMDOCOBLIGATIONTP",
"I_LGLCNTNTMDOCPAPERTYPETXT",
"I_LGLCNTNTMDOCPARCATEGORYTP",
"I_LGLCNTNTMDOCSTATUSCHGSTP",
"I_LGLCNTNTMDOCSTATUSTEXT",
"I_LGLCNTNTMDOCSYNCSTATUSTEXT",
"I_LGLCNTNTMDOCTEMPLATEINFOTP",
"I_LGLCNTNTMDOCUMENTKINDTEXT",
"I_LGLCNTNTMDOCUMENTSTAMPTP",
"I_LGLCNTNTMSGNTRDOCSTATUSTEXT",
"I_LGLCNTNTMTEMPLATE",
"I_LGLCNTNTMVIRTUALDOCVERSTP"
],
"BASE":
[
"I_LCMDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/