I_LcmDocument

@AbapCatalog.sqlViewName: 'ILCMDOCUMENT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck:#CHECK
@VDM.viewType : #COMPOSITE
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations:  [ '_DocLock', '_CreatedBy', '_ChangedBy' ]

@ObjectModel: {

  representativeKey: 'LglCntntMDocumentUUID',
  usageType.serviceQuality: #C,
  usageType.sizeCategory: #L,
  usageType.dataClass: #TRANSACTIONAL
}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@EndUserText.label: 'Document'
define view I_LcmDocument
  as select from I_LegalDocument as Document

  association [1..1] to I_LglCntntMDocStatus           as _DocStatus                    on  $projection.InternalDocumentStatus = _DocStatus.InternalDocumentStatus
  // Doc Attachment

  association [1..1] to I_LglCntntMDocInfoAttachment   as _DocAttach                    on  $projection.LglCntntMDocumentLinkedObjKey = _DocAttach.LinkedSAPObjectKey

  association [1..1] to I_LcmContext                   as _Context                      on  $projection.LglCntntMContextUUID = _Context.LglCntntMContextUUID


  association [0..1] to Sgbt_Nte_Cds_Cont              as _Note                         on  _Note.noteid         = $projection.LglCntntMLongTextUUID
                                                                                        and _Note.objectnodetype = 'LegalDocument'
                                                                                        and _Note.notetype       = 'LCM_LONGTEXT'

  association [0..1] to I_LglCntntMDocLock             as _DocLock                      on  $projection.LglCntntMDocumentUUID         = _DocLock.LglCntntMDocumentUUID
                                                                                        and $projection.LglCntntMDocumentLinkedObjKey = _DocLock.LglCntntMDocumentLinkedObjKey


  association [0..1] to I_LglCntntMAccessLvlText       as _AccessLvlText                on  $projection.LglCntntMDocAccessLvl = _AccessLvlText.LglCntntMAccessLvl
                                                                                        and Language                          = $session.system_language


  association [0..1] to I_LanguageText                 as _LanguageText                 on  $projection.LglCntntMLanguage = _LanguageText.LanguageCode
                                                                                        and Language                      = $session.system_language

  association [0..1] to I_LglCntntMDocContentTypeText  as _ContentTypeText              on  $projection.LglCntntMDocContentType = _ContentTypeText.LglCntntMDocContentType
                                                                                        and Language                            = $session.system_language

  association [0..1] to I_LglCntntMDocCntntTypeSrchTxt as _LglCntntMDocCntntTypeSrchTxt on  $projection.LglCntntMDocContentType = _LglCntntMDocCntntTypeSrchTxt.LglCntntMDocContentType
                                                                                        and Language                            = $session.system_language

  association [0..1] to I_LglCntntMDocStatusText       as _DocStatusText                on  $projection.InternalDocumentStatus = _DocStatusText.InternalDocumentStatus
                                                                                        and Language                           = $session.system_language

  association [0..1] to I_LglCntntMSgntrDocStatusText  as _SgntrDocStatusText           on  $projection.LglCntntMSignatureDocStatus = _SgntrDocStatusText.LglCntntMSignatureDocStatus
                                                                                        and Language                                = $session.system_language

  //association [0..1] to I_LglCntntMDocAssemblyStsText as _AssemblyStatusText       on  $projection.LglCntntMDocAssemblyStatus = _AssemblyStatusText.LglCntntMDocAssemblyStatus

  //                                                                                 and Language                               = $session.system_language


  association [0..1] to I_LglCntntMDocSyncStatusText   as _DocSyncStatusText            on  $projection.LglCntntMVirtualDocSyncSts = _DocSyncStatusText.LglCntntMVirtualDocSyncSts
                                                                                        and Language                               = $session.system_language

  association [0..1] to I_LglCntntMDocLowTouchLvlTxt   as _LglCntntMDocLowTouchLvlTxt   on  $projection.LglCntntMDocLowTouchLevel = _LglCntntMDocLowTouchLvlTxt.LglCntntMDocLowTouchLevel
                                                                                        and Language                              = $session.system_language

  association [0..1] to I_LglCntntMDocumentKindText    as _DocumentKindText             on  $projection.LglCntntMDocumentKind = _DocumentKindText.LglCntntMDocumentKind
                                                                                        and _DocumentKindText.Language        = $session.system_language

  //  association [0..1] to I_LglCntntMDocAutoRefreshTxt   as _LglCntntMDocAutoRefreshTxt   on  $projection.LglCntntMDocAutoRefresh = _LglCntntMDocAutoRefreshTxt.LglCntntMDocAutoRefresh

  //                                                                                        and Language                            = $session.system_language


  association [0..1] to I_LglCntntMDocRefreshStatus    as _LglCntntMDocRefreshStatus    on  $projection.LglCntntMDocument = _LglCntntMDocRefreshStatus.LglCntntMDocument

  //  association [0..1] to I_LglCntntMDocRefreshStsTxt    as _LglCntntMDocRefreshStsTxt    on  $projection.LglCntntMDocRefreshStatus = _LglCntntMDocRefreshStsTxt.LglCntntMDocRefreshStatus

  //                                                                                        and Language                              = $session.system_language

  // Additional associations for ESH

  association [1..1] to I_LglCntntMDocTemplateInfo     as _LglCntntMDocTemplateInfo     on  $projection.LglCntntMDocumentUUID = _LglCntntMDocTemplateInfo.LglCntntMDocumentUUID

  association [0..1] to I_LglCntntMDocInfoAttchAll     as _DocAttachAll                 on  $projection.LglCntntMDocumentLinkedObjKey = _DocAttachAll.LinkedSAPObjectKey

  association [0..*] to I_LglCntntMDocumentStamp       as _LglCntntMDocumentStamp       on  $projection.LglCntntMDocumentUUID = _LglCntntMDocumentStamp.LglCntntMDocumentUUID

  association [0..*] to I_LegalTransactionDocLink      as _LegalTransactionDocLink      on  $projection.LglCntntMDocument = _LegalTransactionDocLink.LglCntntMDocument

  association [0..1] to I_LCMUserAddressAssignment     as _CreatedBy                    on  $projection.LglCntntMCreatedByUser = _CreatedBy.ContactCardID

  association [0..1] to I_LCMUserAddressAssignment     as _ChangedBy                    on  $projection.LglCntntMChangedByUser = _ChangedBy.ContactCardID

  association [1..1] to I_LglCntntMDocAssemblyInfo     as _LglCntntMDocAssemblyInfo     on  $projection.LglCntntMDocumentUUID   = _LglCntntMDocAssemblyInfo.LglCntntMDocumentUUID
                                                                                        and Document.LglCntntMVirtualDocVersKey = _LglCntntMDocAssemblyInfo.LglCntntMVirtualDocVersKey

  association [0..1] to I_LglCntntMDocPaperTypeTxt     as _LglCntntMDocPaperTypeTxt     on $projection.LglCntntMDocPaperType = _LglCntntMDocPaperTypeTxt.LglCntntMDocPaperType
                                                                                        and _LglCntntMDocPaperTypeTxt.Language = $session.system_language

  //Extension

  association [1..1] to E_LegalDocument                as _Extenstion                   on  $projection.LglCntntMDocumentUUID = _Extenstion.LglCntntMDocumentUUID


{

      // LCM Document properties

  key Document.LglCntntMDocumentUUID                       as LglCntntMDocumentUUID,
      Document.LglCntntMDocument                           as LglCntntMDocument,
      Document.LglCntntMDocumentLinkedObject               as LglCntntMDocumentLinkedObject,
      Document.LglCntntMDocumentLinkedObjKey               as LglCntntMDocumentLinkedObjKey,
      Document.LglCntntMDocumentIsTopVersion               as LglCntntMDocumentIsTopVersion,
      Document.LegalTransaction                            as LegalTransaction,
      Document.LegalTransactionUUID                        as LegalTransactionUUID,
      Document.LglCntntMDocContentType                     as LglCntntMDocContentType,
      Document.LglCntntMLanguage                           as LglCntntMLanguage,
      Document.LglCntntMParentDocument                     as LglCntntMParentDocument,
      Document.LglCntntMChangedByUser                      as LglCntntMChangedByUser,
      Document.LglCntntMChangedUTCDateTime                 as LglCntntMChangedUTCDateTime,
      Document.LglCntntMCreatedByUser                      as LglCntntMCreatedByUser,
      Document.LglCntntMCreatedUTCDateTime                 as LglCntntMCreatedUTCDateTime,
      Document.DocumentDescription                         as DocumentDescription,
      Document.LglCntntMLongTextUUID                       as LglCntntMLongTextUUID,
      Document.LglCntntMIsMandatory                        as LglCntntMIsMandatory,
      Document.LegalDocumentSource                         as LegalDocumentSource,
      Document.LglCntntMDocAccessLvl                       as LglCntntMDocAccessLvl,

      Document.LglCntntMAgingTemperature                   as LglCntntMAgingTemperature,
      InternalDocumentStatus                               as InternalDocumentStatus,
      Document.LglCntntMSignatureDocStatus                 as LglCntntMSignatureDocStatus,
      @VDM.lifecycle.status:#DEPRECATED
      @VDM.lifecycle.successor: 'LegalDocumentVersion'
      DocumentVersion                                      as DocumentVersion,
      LegalDocumentVersion                                 as LegalDocumentVersion, //new field for document version number(NUMC4)

      @Semantics.booleanIndicator: true
      Document.IsEndOfPurposeBlocked                       as IsEndOfPurposeBlocked,
      Document.LglCntntMDocType                            as LglCntntMDocType,
      //Document.LglCntntMDocAssemblyStatus           as  LglCntntMDocAssemblyStatus,

      _LglCntntMDocAssemblyInfo.LglCntntMDocAssemblyStatus as LglCntntMDocAssemblyStatus,
      Document.LglCntntMTmplUUID                           as LglCntntMTmplUUID,
      //      Document.LglCntntMVirtualDocRefKey                             as  LglCntntMVirtualDocRefKey,

      Document.LglCntntMVirtualDocVersKey                  as LglCntntMVirtualDocVersKey,
      Document.LglCntntMVirtualDocSyncSts                  as LglCntntMVirtualDocSyncSts,
      Document.LglCntntMCntxtDocUUID                       as LglCntntMCntxtDocUUID,
      Document.LglCntntMDocIsToBeDeleted                   as LglCntntMDocIsToBeDeleted,
      Document.LglCntntMDocReferenceNumber                 as LglCntntMDocReferenceNumber,
      Document.LglCntntMDocLowTouchLevel                   as LglCntntMDocLowTouchLevel,
      Document.LglCntntMCreatedFromDocUUID                 as LglCntntMCreatedFromDocUUID,
      Document.LglCntntMDocPaperType                       as LglCntntMDocPaperType,
      // LCM Legal Transaction

      _LegalTransaction.LglCntntMProfile                   as LglCntntMProfile,
      _LegalTransaction.LglCntntMGovLaw                    as LglCntntMGovLaw,
      _LegalTransaction.LglCntntMContextUUID               as LglCntntMContextUUID,
      _LegalTransaction.LegalTransactionTitle              as LegalTransactionTitle,

      // LCM Notes

      _Note.content                                        as LglCntntMLongText,
      _Note.mimetype                                       as LglCntntMLongTextMimeType,

      _DocStatusText.LglCntntMDocStatusName                as LglCntntMDocStatusName,
      _DocLock.LglCntntMDocLockedReasonCode                as LglCntntMDocLockedReasonCode,
      LglCntntMCntxtDocumentID,
      LglCntntMIsIntegRelevant,

      _LglCntntMDocRefreshStatus.LglCntntMDocRefreshStatus as LglCntntMDocRefreshStatus,

      LglCntntMNmbrOfAdminvDocUpdt,
      LglCntntMDocumentKind,

      // Authorization

      _LegalTransaction,
      _Note,
      _Context,
      _DocLock,
      _DocAttach,
      _AccessLvlText,
      _ContentTypeText,
      _DocumentKindText,
      _LanguageText,
      _DocStatusText,
      _SgntrDocStatusText,
      _DocSyncStatusText,
      _LglCntntMDocLowTouchLvlTxt,
      //      _LglCntntMDocAutoRefreshTxt,

      //_AssemblyStatusText,

      _LglCntntMDocAssemblyInfo,

      _LglCntntMDocTemplateInfo,
      _DocAttachAll,
      _LglCntntMDocumentStamp,
      _LegalTransactionDocLink,
      _CreatedBy,
      _ChangedBy,
      _LglCntntMDocRefreshStatus,
      //      _LglCntntMDocRefreshStsTxt,


      //ESH

      _LglCntntMDocCntntTypeSrchTxt,
      _LglCntntMDocPaperTypeTxt
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_LEGALDOCUMENT",
"I_LEGALTRANSACTION",
"I_LGLCNTNTMDOCASSEMBLYINFO",
"I_LGLCNTNTMDOCLOCK",
"I_LGLCNTNTMDOCREFRESHSTATUS",
"I_LGLCNTNTMDOCSTATUSTEXT",
"SGBT_NTE_CDS_CONT"
],
"ASSOCIATED":
[
"E_LEGALDOCUMENT",
"I_LANGUAGETEXT",
"I_LCMCONTEXT",
"I_LCMUSERADDRESSASSIGNMENT",
"I_LEGALTRANSACTION",
"I_LEGALTRANSACTIONDOCLINK",
"I_LGLCNTNTMACCESSLVLTEXT",
"I_LGLCNTNTMDOCASSEMBLYINFO",
"I_LGLCNTNTMDOCCNTNTTYPESRCHTXT",
"I_LGLCNTNTMDOCCONTENTTYPETEXT",
"I_LGLCNTNTMDOCINFOATTACHMENT",
"I_LGLCNTNTMDOCINFOATTCHALL",
"I_LGLCNTNTMDOCLOCK",
"I_LGLCNTNTMDOCLOWTOUCHLVLTXT",
"I_LGLCNTNTMDOCPAPERTYPETXT",
"I_LGLCNTNTMDOCREFRESHSTATUS",
"I_LGLCNTNTMDOCSTATUS",
"I_LGLCNTNTMDOCSTATUSTEXT",
"I_LGLCNTNTMDOCSYNCSTATUSTEXT",
"I_LGLCNTNTMDOCTEMPLATEINFO",
"I_LGLCNTNTMDOCUMENTKINDTEXT",
"I_LGLCNTNTMDOCUMENTSTAMP",
"I_LGLCNTNTMSGNTRDOCSTATUSTEXT",
"SGBT_NTE_CDS_CONT"
],
"BASE":
[
"I_LEGALDOCUMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/