I_JntVntrEquityGrp

@AbapCatalog.sqlViewName: 'IJVEQGRP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Joint Venture Equity Group'
//@Analytics.dataCategory: #DIMENSION

@Analytics.internalName:#LOCAL
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'JntOpgAgrmtEquityGrp'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions:true
@ObjectModel:{
  usageType.serviceQuality: #B,
  usageType.sizeCategory: #S,
  usageType.dataClass: #MASTER,
  supportedCapabilities: [#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ],
  modelingPattern: #NONE
}
@Metadata.ignorePropagatedAnnotations: true

define view I_JntVntrEquityGrp
  as select from t8jf
  association [1..1] to I_CompanyCode              as _CompanyCode              on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_JointVentureMasterFld    as _JointVentureMasterFld    on  $projection.CompanyCode  = _JointVentureMasterFld.CompanyCode
                                                                                and $projection.JointVenture = _JointVentureMasterFld.JointVenture
  association [0..*] to I_JntVntrEquityGrpText     as _JntVntrEquityGrpText     on  $projection.CompanyCode          = _JntVntrEquityGrpText.CompanyCode
                                                                                and $projection.JointVenture         = _JntVntrEquityGrpText.JointVenture
                                                                                and $projection.JntOpgAgrmtEquityGrp = _JntVntrEquityGrpText.JntOpgAgrmtEquityGrp
  association [0..*] to I_JointVentureSuspenseText as _JointVentureSuspenseText on  $projection.JntVntrEquityGrpIsSuspended = _JointVentureSuspenseText.JntVntrSuspenseStatus
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key bukrs                                                                         as CompanyCode,
      @ObjectModel.foreignKey.association: '_JointVentureMasterFld'
  key cast( vname as jv_name preserving type )                                      as JointVenture,
      @ObjectModel.text.association: '_JntVntrEquityGrpText'
  key egrup                                                                         as JntOpgAgrmtEquityGrp,

      @EndUserText.label: 'Equity Group Description'
      coalesce( _JntVntrEquityGrpText[1:Language = $session.system_language ].JntOpgAgrmtEquityGrpText,
                _JntVntrEquityGrpText[1:Language = 'E' ].JntOpgAgrmtEquityGrpText ) as JntOpgAgrmtEquityGrpText,
                
      @DefaultAggregation: #SUM
      opshare                                                                       as JntVntrOperatedShare,
      @DefaultAggregation: #SUM
      nopshare                                                                      as JntVntrNonOperatedShare,
      egroupact                                                                     as JointVentureEquityGroupActive,
      @ObjectModel.text.association: '_JointVentureSuspenseText'
      egroupsus                                                                     as JntVntrEquityGrpIsSuspended,
      grpsusper                                                                     as JntVntrEquityGrpSuspendedPerd,
      grpsusyear                                                                    as JntVntrEquityGrpSuspendedYr,
      egroupusus                                                                    as JntVntrEquityGrpIsNotSuspended,
      grpususper                                                                    as JntVntrGrpNotSuspendedPerd,
      grpususyer                                                                    as JntVntrGrpNotSuspendedYr,
      @EndUserText.label: 'NPI Group'
      npigroup                                                                      as JntVntrNetProfitIntrstGrp,

      _CompanyCode,
      _JointVentureMasterFld,
      _JntVntrEquityGrpText,
      _JointVentureSuspenseText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JNTVNTREQUITYGRPTEXT",
"T8JF"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_JNTVNTREQUITYGRPTEXT",
"I_JOINTVENTUREMASTERFLD",
"I_JOINTVENTURESUSPENSETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/