I_JVAFsclYearPerdCoCodeForITD

@AbapCatalog.sqlViewName: 'IJVFYPERDCOITD'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'JVA Fiscal Year Period For Company Code'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType: { serviceQuality: #X,
                          sizeCategory: #XXL,
                          dataClass: #MIXED }

define view I_JVAFsclYearPerdCoCodeForITD

  as select from I_FiscalYearPeriod as YearPeriod

    inner join   I_CompanyCode      as CompanyCode on CompanyCode.FiscalYearVariant = YearPeriod.FiscalYearVariant

    inner join   I_JVAGlobalCompanyParameter       on I_JVAGlobalCompanyParameter.CompanyCode = CompanyCode.CompanyCode

    inner join   I_JVALedger        as Ledger      on Ledger.CompanyCode = CompanyCode.CompanyCode

    inner join   I_JntVntrEquityGrp as VntEquGroup on VntEquGroup.CompanyCode = CompanyCode.CompanyCode

  association [1..1] to I_CompanyCode              as _CompanyCode        on  _CompanyCode.CompanyCode = $projection.CompanyCode

  association [0..1] to I_FiscalYearForCompanyCode as _FiscalYearCompCode on  _FiscalYearCompCode.FiscalYear  = $projection.CurrentFiscalYear
                                                                          and _FiscalYearCompCode.CompanyCode = $projection.CompanyCode

{
  key    Ledger.Ledger,
  key    CompanyCode.CompanyCode,
         @EndUserText: {
           label: 'Current Fiscal Year',
           quickInfo: 'Current Fiscal Year' }
  key    YearPeriod.FiscalYear   as CurrentFiscalYear,
         @EndUserText: {
          label: 'Current Fiscal Period',
          quickInfo: 'Current Fiscal Period' }
  key    YearPeriod.FiscalPeriod as CurrentFiscalPeriod,
  key    VntEquGroup.JointVenture,
  key    VntEquGroup.JntOpgAgrmtEquityGrp,

         @EndUserText: {
          label: 'Previous Fiscal Year',
          quickInfo: 'Previous Fiscal Year' }
         YearPeriod.FiscalYear   as PreviousFiscalYear,
         @EndUserText: {
         label: 'Previous Fiscal Period',
         quickInfo: 'Previous Fiscal Period' }

         YearPeriod.FiscalPeriod as PreviousFiscalPeriod,
         YearPeriod.FiscalYearVariant,
         YearPeriod.FiscalPeriodStartDate,
         YearPeriod.FiscalPeriodEndDate,
         YearPeriod.IsSpecialPeriod,
         YearPeriod.FiscalYearStartDate,
         YearPeriod.FiscalYearEndDate,
         YearPeriod.NextFiscalPeriod,
         YearPeriod.NextFiscalPeriodFiscalYear,
         YearPeriod.FiscalYearPeriod,

         YearPeriod._FiscalPeriodStartDate,
         YearPeriod._FiscalYear,
         YearPeriod._FiscalYearVariant,
         YearPeriod._Text,

         // Associations

         _CompanyCode,
         _FiscalYearCompCode

}

where
  YearPeriod.FiscalPeriod between '001' and '012'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_FISCALYEARPERIOD",
"I_JNTVNTREQUITYGRP",
"I_JVAGLOBALCOMPANYPARAMETER",
"I_JVALEDGER"
],
"ASSOCIATED":
[
"I_CALENDARDATE",
"I_COMPANYCODE",
"I_FISCALYEAR",
"I_FISCALYEARFORCOMPANYCODE",
"I_FISCALYEARPERIODTEXT",
"I_FISCALYEARVARIANT"
],
"BASE":
[
"I_FISCALYEARPERIOD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/