I_JITCallCompMaterialBasic

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #NOT_REQUIRED
}
@EndUserText.label: 'JIT Call Components'
@ObjectModel: {
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #B,
    sizeCategory: #XXL
  }
}
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
define view entity I_JITCallCompMaterialBasic
  as select from njit_call_d_cmat
  association [1..1] to I_JITCallHeaderBasic    as _JITCallHeaderBasic    on  $projection.JITHeaderUUID = _JITCallHeaderBasic.JITHeaderUUID
  association [1..1] to I_Product               as _ProductCompMatl       on  $projection.Material = _ProductCompMatl.Product
  association [0..1] to I_JITCallCompGroupBasic as _JITCallCompGroupBasic on  $projection.JITCallCompGrpUUID    = _JITCallCompGroupBasic.JITCallCompGrpUUID
                                                                          and $projection.InternalJITCallNumber = _JITCallCompGroupBasic.InternalJITCallNumber
                                                                          and $projection.CompGrpNumber         = _JITCallCompGroupBasic.CompGrpNumber
  association [0..*] to I_JITCallDocRefBasic    as _JITCallDocRefBasic    on  $projection.JITCallComponentUUID = _JITCallDocRefBasic.JITCallComponentUUID
  association [0..1] to I_ProductPlant          as _ProductPlant          on  $projection.Material = _ProductPlant.Product
                                                                          and $projection.Plant    = _ProductPlant.Plant
{
  key db_key                                                                                      as JITCallComponentUUID,
  key root_key                                                                                    as JITHeaderUUID,      //CE2008

  key parent_key                                                                                  as JITCallCompGrpUUID, //CE2008

  key int_call_num                                                                                as InternalJITCallNumber,
  key comp_grp_num                                                                                as CompGrpNumber,
  key call_item_num                                                                               as JITCallItemNumber,
      matnr                                                                                       as Material,
      kdmat                                                                                       as MaterialByCustomer,
      ext_call_item_num                                                                           as ExtJITCallItemNumber,
      vbeln                                                                                       as SalesOrder,
      posnr                                                                                       as SalesOrderItem,
      spart                                                                                       as Division,
      @Semantics.quantity.unitOfMeasure: 'QUANTITYUNIT'
      requested_quantity                                                                          as RequestedQuantity,
      @Semantics.quantity.unitOfMeasure: 'QUANTITYUNIT'
      delivered_quantity                                                                          as ActualDeliveredQuantity,
      meins                                                                                       as QuantityUnit,
      int_stat                                                                                    as JITIntProcessingStatus, //CE2008

      jitcallcompmatlbackflushstatus                                                              as JITCallCompMatlBackflushStatus, //CE2011

      jitcallcompmatlbackflushtype                                                                as JITCallCompMatlBackflushType,   //CE2011

      jitcallcompbackflushstsupdtdon                                                              as JITCallCompBackflushStsUpdtdOn, //CE2011

      _JITCallCompGroupBasic._JITSupplyControlHeader.JITProdnConfirmationControl, //CE2011

      _JITCallCompGroupBasic.SupplyControlUUID,
      _ProductCompMatl._ProductGroup.MaterialGroup                                                as MaterialGroup,
      _ProductCompMatl._ProductGroup._Text[1:Language=$session.system_language].MaterialGroupName as MaterialGroupName,
      _JITCallCompGroupBasic.Plant                                                                as Plant,
      //Associations

      _ProductCompMatl,
      _JITCallDocRefBasic,
      _JITCallCompGroupBasic,
      _ProductPlant,
      _JITCallHeaderBasic
}
where
  _JITCallHeaderBasic.JITScenario = '1'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JITCALLCOMPGROUPBASIC",
"I_JITCALLHEADERBASIC",
"I_JITSUPPLYCONTROLHEADER",
"I_PRODUCT",
"I_PRODUCTGROUP",
"I_PRODUCTGROUPTEXT",
"NJIT_CALL_D_CMAT"
],
"ASSOCIATED":
[
"I_JITCALLCOMPGROUPBASIC",
"I_JITCALLDOCREFBASIC",
"I_JITCALLHEADERBASIC",
"I_PRODUCT",
"I_PRODUCTPLANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/