I_JITCallHeaderBasic

@EndUserText.label: 'Basic view for JIT Call Header'

@ClientHandling: {
  type: #INHERITED,
  algorithm: #SESSION_VARIABLE
}

@AbapCatalog: {
  sqlViewName: 'IJITCALLHDR',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #REQUIRED
}

@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@ObjectModel: {
  usageType.dataClass: #TRANSACTIONAL,
  usageType.serviceQuality: #B,
  usageType.sizeCategory: #XXL
}

@AccessControl.privilegedAssociations: ['_CreatedByUser','_LastChangedByUser' ]
define view I_JITCallHeaderBasic
  as select from njit_call_d_hdr

  association [1..1] to I_Customer_to_BusinessPartner as _CustomerToBusinessPartner on $projection.ShipToParty = _CustomerToBusinessPartner.Customer

  association [0..1] to I_JITLifecycleStatus          as _JITLifecycleStatus        on $projection.JITLifecycleStatus = _JITLifecycleStatus.JITLifecycleStatus

  association [0..1] to I_JITCallType                 as _JITCallType               on $projection.JITCallType = _JITCallType.JITCallType

  association [1..1] to I_JITCustomer                 as _JITCustomer               on $projection.ShipToParty = _JITCustomer.ShipToParty
                                                                                   and $projection.CustomerUUID = _JITCustomer.CustomerUUID

  association [0..1] to I_MatlUsageIndicator          as _MatlUsageIndicator        on $projection.MatlUsageIndicator = _MatlUsageIndicator.MatlUsageIndicator

  //association [0..1] to I_User                        as _CreatedByUser             on $projection.CreatedByUser = _CreatedByUser.UserID

  association [0..1] to I_UserContactCard             as _CreatedByUser             on $projection.CreatedByUser = _CreatedByUser.ContactCardID
  //association [0..1] to I_User                        as _LastChangedByUser         on $projection.LastChangedByUser = _LastChangedByUser.UserID

  association [0..1] to I_UserContactCard             as _LastChangedByUser         on $projection.LastChangedByUser = _LastChangedByUser.ContactCardID

  association [0..1] to I_Customer                    as _Customer                  on $projection.ShipToParty = _Customer.Customer

  //  association [0..1] to I_JITCallAlertCount          as _JITCallAlertCount          on  $projection.InternalJITCallNumber = _JITCallAlertCount.InternalJITCallNumber

  //                                                                                    and $projection.JITHeaderUUID         = _JITCallAlertCount.JITHeaderUUID

  association [0..1] to I_SalesOrganization           as _SalesOrganization         on $projection.SalesOrganization = _SalesOrganization.SalesOrganization

  association [0..1] to I_DistributionChannel         as _DistributionChannel       on $projection.DistributionChannel = _DistributionChannel.DistributionChannel

  association [0..1] to I_Division                    as _Division                  on $projection.Division = _Division.Division

  association [0..1] to I_JITComponentIsReordered     as _JITComponentIsReordered   on $projection.JITComponentIsReordered = _JITComponentIsReordered.JITComponentIsReordered
  
  association [0..*] to I_JITCallCompGroupBasic       as _JITCallCompGroupBasic     on $projection.JITHeaderUUID = _JITCallCompGroupBasic.JITHeaderUUID
{

  key db_key                           as JITHeaderUUID,
  key int_call_num                     as InternalJITCallNumber,
      ext_call_num                     as ExternalJITCallNumber,
      log_severity                     as ApplLogHighestMessageSeverity,
      njit_scenario                    as JITScenario,
      //      cast( kunnr as abap.char( 10 ) )                as ShipToParty,

      customeruuid                     as CustomerUUID,
      kunnr                            as ShipToParty,
      kunag                            as SoldToParty,
      //cast( kunag as abap.char( 10 ) ) as SoldToParty,

      lifecycle_stat                   as JITLifecycleStatus,
      call_type                        as JITCallType,
      vhvin                            as VehicleIdentificationNumber,
      vhcle_model                      as VehicleModel,
      vkorg                            as SalesOrganization,
      vtweg                            as DistributionChannel,
      spart                            as Division,
      ablad                            as UnloadingPointName,
      knref                            as CustomerPartnerDescription,
      abrvw                            as MatlUsageIndicator,
      cast( lifnr as abap.char( 10 ) ) as ActiveSupplier,
      concat(ext_call_num,kunnr)       as JITCallProcessingLogID,
      ext_sequence_num                 as JITExtSequenceNumber,

      // Administrative Data

      @Semantics.systemDateTime.createdAt: true
      crea_date_time                   as CreationDateTime,
      @Semantics.user.createdBy: true
      crea_uname                       as CreatedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      lchg_date_time                   as LastChangeDateTime,
      @Semantics.user.lastChangedBy:true
      lchg_uname                       as LastChangedByUser,

      jitcomponentisreordered          as JITComponentIsReordered,

      // Associations

      _CustomerToBusinessPartner,
      _JITLifecycleStatus,
      _JITCallType,
      _JITCustomer,
      _MatlUsageIndicator,
      _CreatedByUser,
      _LastChangedByUser,
      _Customer,
      _SalesOrganization,
      _Division,
      _DistributionChannel,
      _JITComponentIsReordered,
      _JITCallCompGroupBasic

}
where
  njit_scenario = '1' // Scenario: S2C

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"NJIT_CALL_D_HDR"
],
"ASSOCIATED":
[
"I_CUSTOMER",
"I_CUSTOMER_TO_BUSINESSPARTNER",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_JITCALLCOMPGROUPBASIC",
"I_JITCALLTYPE",
"I_JITCOMPONENTISREORDERED",
"I_JITCUSTOMER",
"I_JITLIFECYCLESTATUS",
"I_MATLUSAGEINDICATOR",
"I_SALESORGANIZATION",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/