I_InsurPlcySubCoverage

@EndUserText.label: 'Cvrg SubCoverage of CvPcg in Insur Plcy'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [  '_InsurancePolicyLimit',
                              '_InsurPolicySubCvrgClause',
                              '_InsurPlcySubCvrgDeductible',
                              '_InsurPlcySubCvrgPlndProcg']
}
@ObjectModel: {
   representativeKey: 'InsurPlcySubCvrgID',
   semanticKey: [ 'InsurPlcyInsuranceSubCoverage' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IPPlcySubCvrg'
}

define view entity I_InsurPlcySubCoverage
  as select from I_InsurPlcySubCoverageBasic as SubCoverage

  association        to parent I_InsurancePolicyCoverage as _InsurancePolicyCoverage   on  $projection.InsurPlcyUUID              = _InsurancePolicyCoverage.InsurPlcyUUID
                                                                                       and $projection.InsurPlcyInsurContr        = _InsurancePolicyCoverage.InsurPlcyInsurContr
                                                                                       and $projection.InsurPlcyCoveragePackageID = _InsurancePolicyCoverage.InsurPlcyCoveragePackageID
                                                                                       and $projection.InsurPlcyCoverageID        = _InsurancePolicyCoverage.InsurPlcyCoverageID

  composition [0..*] of I_InsurancePolicyLimit           as _InsurancePolicyLimit
  composition [0..*] of I_InsurPolicySubCvrgClause       as _InsurPolicySubCvrgClause
  composition [0..*] of I_InsurPlcySubCvrgDeductible     as _InsurPlcySubCvrgDeductible
  composition [0..1] of I_InsurPlcySubCvrgPlndProcg      as _InsurPlcySubCvrgPlndProcg


  association [1..1] to I_InsurPlcyCvrgInsrdSumCalc      as _InsurPlcyCvrgInsrdSumCalc on  $projection.InsurPlcySubCvrgInsrdSumCalc = _InsurPlcyCvrgInsrdSumCalc.InsurPlcyCvrgInsrdSumCalcMeth
  association [1..1] to I_Currency                       as _Currency                  on  $projection.InsurPlcySubCoverageCurrency = _Currency.Currency
  association [1..*] to I_InsurPlcyTemplateT             as _InsurPlcyTemplateT        on  $projection.InsurPlcySubCoverageTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate

{

  key SubCoverage.InsurPlcyUUID,
  key SubCoverage.InsurPlcyInsurContr,
  key SubCoverage.InsurPlcyCoveragePackageID,
  key SubCoverage.InsurPlcyCoverageID,
  key SubCoverage.InsurPlcySubCvrgID,
      SubCoverage.InsurPlcyJrnlNmbr,
      SubCoverage.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      SubCoverage.InsurPlcyProductPackageID,
      SubCoverage.InsurPlcyInsuranceSubCoverage,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      // @ObjectModel.sapObjectNodeTypeReference: 'InsurancePolicyTemplate'

      SubCoverage.InsurPlcySubCoverageTemplate,
      SubCoverage.InsurPlcySubCoverageStartDate,
      SubCoverage.InsurPlcySubCoverageEndDate,
      @Semantics.amount.currencyCode: 'InsurPlcySubCoverageCurrency'
      SubCoverage.InsurPlcySubCvrgInsrdSumAmount,
      @ObjectModel.foreignKey.association: '_Currency'
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      SubCoverage.InsurPlcySubCoverageCurrency,
      SubCoverage.InsurPlcySubCvrgInsuredSumPct,
      @ObjectModel.foreignKey.association: '_InsurPlcyCvrgInsrdSumCalc'
      SubCoverage.InsurPlcySubCvrgInsrdSumCalc,
      @Semantics.systemDateTime.lastChangedAt: true
      SubCoverage.LastChangeDateTime,

      /* Associations */
      _InsurancePolicyCoverage,
      _InsurancePolicyLimit,
      _InsurPolicySubCvrgClause,
      _InsurPlcySubCvrgDeductible,
      _InsurPlcySubCvrgPlndProcg,

      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _Currency,
      @Consumption.hidden: true
      _InsurPlcyCvrgInsrdSumCalc

}
where
      SubCoverage.InsurPlcyJrnlEndNmbr       =  2147483647
  and SubCoverage.InsurPlcyBusinessObject    =  'P'
  and SubCoverage.InsurPlcyCoveragePackageID <> 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYSUBCOVERAGEBASIC"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_INSURANCEPOLICYCOVERAGE",
"I_INSURANCEPOLICYLIMIT",
"I_INSURPLCYCVRGINSRDSUMCALC",
"I_INSURPLCYSUBCVRGDEDUCTIBLE",
"I_INSURPLCYSUBCVRGPLNDPROCG",
"I_INSURPLCYTEMPLATET",
"I_INSURPOLICYSUBCVRGCLAUSE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/