I_InsurPolicySubCvrgClause

@EndUserText.label: 'SubCoverage Clause of CvPcg in Plcy'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'InsurPlcyClauseID',
   semanticKey: [ 'InsurPlcyClauseID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IPPlcySubCvrgCls'
}

define view entity I_InsurPolicySubCvrgClause
  as select from I_InsurPlcyClauseBasic as Clause
  
    left outer to one join I_InsurPlcyClauseLongTxtBasic as LongText on Clause.InsurPlcyClauseDetailTextUUID = LongText.InsurPlcyClauseDetailTextUUID
                                                    
  association        to parent I_InsurPlcySubCoverage as _InsurPlcySubCoverage      on  $projection.InsurPlcyUUID              = _InsurPlcySubCoverage.InsurPlcyUUID
                                                                                    and $projection.InsurPlcyInsurContr        = _InsurPlcySubCoverage.InsurPlcyInsurContr
                                                                                    and $projection.InsurPlcyCoveragePackageID = _InsurPlcySubCoverage.InsurPlcyCoveragePackageID
                                                                                    and $projection.InsurPlcyCoverageID        = _InsurPlcySubCoverage.InsurPlcyCoverageID
                                                                                    and $projection.InsurPlcySubCvrgID         = _InsurPlcySubCoverage.InsurPlcySubCvrgID

  association [1..1] to I_InsurPlcyClauseTypeLink     as _InsurancePolicyClauseType on  $projection.InsurPlcyClauseType     = _InsurancePolicyClauseType.InsurPlcyClauseType
                                                                                    and $projection.InsurPlcyClauseTemplate = _InsurancePolicyClauseType.InsurPlcyClauseTemplate
  association [1..*] to I_InsurPlcyTemplateT          as _InsurPlcyTemplateT        on  $projection.InsurPlcyClauseTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate

{

  key Clause.InsurPlcyUUID,
  key Clause.InsurPlcyInsurContr,
  key Clause.InsurPlcyCoveragePackageID,
  key Clause.InsurPlcyCoverageID,
  key Clause.InsurPlcySubCvrgID,
  key Clause.InsurPlcyInsuredObjectID,
  key Clause.InsurPlcyClauseID,
      Clause.InsurPlcyJrnlNmbr,
      Clause.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Clause.InsurPlcyProductPackageID,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      // @ObjectModel.sapObjectNodeTypeReference: 'InsurancePolicyTemplate'

      Clause.InsurPlcyClauseTemplate,
      Clause.InsurPlcyIndivClauseAgrmtText,
      Clause.InsurPlcyClauseDetailTextUUID,
      LongText.LongText,
      LongText.TextObjectCategory,
      LongText.TextObjectKey,
      LongText.Language,
      @ObjectModel.foreignKey.association: '_InsurancePolicyClauseType'
      @ObjectModel.sapObjectNodeTypeReference: 'InsurancePolicyClauseType'
      Clause.InsurPlcyClauseType,
      @Semantics.businessDate.from: true
      Clause.InsurPlcyClauseStartDate,
      @Semantics.businessDate.to: true
      Clause.InsurPlcyClauseEndDate,
      @Semantics.systemDateTime.lastChangedAt: true
      Clause.LastChangeDateTime,

      /* Associations */
      _InsurPlcySubCoverage,
      @Consumption.hidden: true
      _InsurancePolicyClauseType,
      @Consumption.hidden: true
      _InsurPlcyTemplateT

}
where
      Clause.InsurPlcyJrnlEndNmbr       =  2147483647
  and Clause.InsurPlcyBusinessObject    =  'P'
  and Clause.InsurPlcyInsuredObjectID   =  0
  and Clause.InsurPlcyCoveragePackageID <> 0
  and Clause.InsurPlcyCoverageID        <> 0
  and Clause.InsurPlcySubCvrgID         <> 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYCLAUSEBASIC",
"I_INSURPLCYCLAUSELONGTXTBASIC"
],
"ASSOCIATED":
[
"I_INSURPLCYCLAUSETYPELINK",
"I_INSURPLCYSUBCOVERAGE",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/