I_InsurApplContrInsuredObject

@EndUserText.label: 'Contract Insrd Obj in Insurance Appl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations:  [  '_InsurApplContrInsrdObjClause',
                              '_InsurApplContrInsrdObjDcbl',
                              '_InsurApplContrObjSurchrgDisc',
                              '_InsurApplContrInsuredVehicle',
                              '_InsurApplContrNamedDriver',
                              '_InsurApplContrSpclEquip']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyInsuredObjectID',
   semanticKey: [ 'InsurPlcyInsrdObjUnqID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #L
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IAContrInsrdObj'
}
define view entity I_InsurApplContrInsuredObject
  as select from P_InsurPolicyJournalKeys      as PlcyJrnl
    inner join   I_InsurPlcyInsuredObjectBasic as Subject on  PlcyJrnl.InsurPlcyUUID                  =  Subject.InsurPlcyUUID
                                                          and PlcyJrnl.InsurPlcyInsurContr            =  Subject.InsurPlcyInsurContr
                                                          and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr >= Subject.InsurPlcyJrnlNmbr
                                                          and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr <  Subject.InsurPlcyJrnlEndNmbr

  association        to parent I_InsurApplContract     as _InsurApplContract        on  $projection.InsurPlcyUUID                  = _InsurApplContract.InsurPlcyUUID
                                                                                    and $projection.InsurPlcyInsurContr            = _InsurApplContract.InsurPlcyInsurContr
                                                                                    and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurApplContract.InsurPlcyContrDataDetnJrnlNmbr

  composition [0..*] of I_InsurApplContrInsrdObjClause as _InsurApplContrInsrdObjClause
  composition [0..*] of I_InsurApplContrInsrdObjDcbl   as _InsurApplContrInsrdObjDcbl
  composition [0..*] of I_InsurApplContrObjSurchrgDisc as _InsurApplContrObjSurchrgDisc
  composition [0..1] of I_InsurApplContrInsuredVehicle as _InsurApplContrInsuredVehicle
  composition [0..*] of I_InsurApplContrNamedDriver    as _InsurApplContrNamedDriver
  composition [0..*] of I_InsurApplContrSpclEquip      as _InsurApplContrSpclEquip
  composition [0..1] of I_InsurApplContrInsrdObjBldng  as _InsurApplContrInsrdObjBldng


  association [1..1] to I_InsurInsrdObjectCategory     as _InsurInsrdObjectCategory on  $projection.InsurPlcyInsuredObjectCategory = _InsurInsrdObjectCategory.InsurPlcyInsuredObjectCategory
  association [1..1] to I_InsurInsrdObjSubCategory     as _InsurInsrdObjSubCategory on  $projection.InsurPlcyInsrdObjSubCategory = _InsurInsrdObjSubCategory.InsurPlcyInsrdObjSubCategory
  association [1..*] to I_InsurPlcyTemplateT           as _InsurPlcyTemplateT       on  $projection.InsurPlcyInsrdObjectTemplate = _InsurPlcyTemplateT.InsurPlcyTemplate
  association [1..1] to I_InsurInsurableObject         as _InsurInsurableObject     on  $projection.InsurPlcyInsrdObjUnqID = _InsurInsurableObject.InsurInsrblObj
                                                                                    and $projection.InsurInsrblObjJrnlNmbr = _InsurInsurableObject.InsurInsrblObjJrnlNmbr

{
  key Subject.InsurPlcyUUID,
  key Subject.InsurPlcyInsurContr,
  key Subject.InsurPlcyCoveragePackageID,
  key Subject.InsurPlcyCoverageID,
  key Subject.InsurPlcyInsuredObjectID,
  key cast( PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      Subject.InsurPlcyJrnlNmbr,
      Subject.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      Subject.InsurPlcyProductPackageID,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      Subject.InsurPlcyInsrdObjectTemplate,
      @ObjectModel.foreignKey.association: '_InsurInsrdObjectCategory'
      Subject.InsurPlcyInsuredObjectCategory,
      @ObjectModel.foreignKey.association: '_InsurInsrdObjSubCategory'
      Subject.InsurPlcyInsrdObjSubCategory,
      @ObjectModel.foreignKey.association: '_InsurInsurableObject'
      Subject.InsurPlcyInsrdObjUnqID,
      Subject.InsurInsrblObjJrnlNmbr,
      @Semantics.systemDateTime.lastChangedAt: true
      Subject.LastChangeDateTime,

      /* Associations */
      _InsurApplContract,
      _InsurApplContrInsrdObjClause,
      _InsurApplContrInsrdObjDcbl,
      _InsurApplContrObjSurchrgDisc,
      _InsurApplContrInsuredVehicle,
      _InsurApplContrNamedDriver,
      _InsurApplContrSpclEquip,
      _InsurApplContrInsrdObjBldng,


      @Consumption.hidden: true
      _InsurPlcyTemplateT,
      @Consumption.hidden: true
      _InsurInsrdObjectCategory,
      @Consumption.hidden: true
      _InsurInsrdObjSubCategory,
      _InsurInsurableObject

}
where
      Subject.InsurPlcyCoveragePackageID = 0
  and Subject.InsurPlcyCoverageID        = 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYINSUREDOBJECTBASIC",
"P_INSURPOLICYJOURNALKEYS"
],
"ASSOCIATED":
[
"I_INSURAPPLCONTRACT",
"I_INSURAPPLCONTRINSRDOBJBLDNG",
"I_INSURAPPLCONTRINSRDOBJCLAUSE",
"I_INSURAPPLCONTRINSRDOBJDCBL",
"I_INSURAPPLCONTRINSUREDVEHICLE",
"I_INSURAPPLCONTRNAMEDDRIVER",
"I_INSURAPPLCONTROBJSURCHRGDISC",
"I_INSURAPPLCONTRSPCLEQUIP",
"I_INSURINSRDOBJECTCATEGORY",
"I_INSURINSRDOBJSUBCATEGORY",
"I_INSURINSURABLEOBJECT",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/