I_InsurApplContrNamedDriver

@EndUserText.label: 'InsOb Named Drvr of Contr in Insur Appl'
@VDM: {
  viewType:#COMPOSITE,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'InsurPlcyInsrdVehNmdDrvrID',
   semanticKey: [ 'InsurPlcyInsrdVehNmdDrvrID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #L
   },
   supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE ]
}
@Metadata: {
  allowExtensions:false,
  ignorePropagatedAnnotations:false
}
@Analytics: {
  technicalName: 'IAContrNmdDrvr'
}
define view entity I_InsurApplContrNamedDriver
  as select from P_InsurPolicyJournalKeys    as PlcyJrnl
    inner join   I_InsurPlcyNamedDriverBasic as NamedDriver on  PlcyJrnl.InsurPlcyUUID                  =  NamedDriver.InsurPlcyUUID
                                                            and PlcyJrnl.InsurPlcyInsurContr            =  NamedDriver.InsurPlcyInsurContr
                                                            and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr >= NamedDriver.InsurPlcyJrnlNmbr
                                                            and PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr <  NamedDriver.InsurPlcyJrnlEndNmbr

  association        to parent I_InsurApplContrInsuredObject as _InsurApplContrInsuredObject  on  $projection.InsurPlcyUUID                  = _InsurApplContrInsuredObject.InsurPlcyUUID
                                                                                              and $projection.InsurPlcyInsurContr            = _InsurApplContrInsuredObject.InsurPlcyInsurContr
                                                                                              and $projection.InsurPlcyCoveragePackageID     = _InsurApplContrInsuredObject.InsurPlcyCoveragePackageID
                                                                                              and $projection.InsurPlcyCoverageID            = _InsurApplContrInsuredObject.InsurPlcyCoverageID
                                                                                              and $projection.InsurPlcyInsuredObjectID       = _InsurApplContrInsuredObject.InsurPlcyInsuredObjectID
                                                                                              and $projection.InsurPlcyContrDataDetnJrnlNmbr = _InsurApplContrInsuredObject.InsurPlcyContrDataDetnJrnlNmbr

  association [1..1] to I_InsurPlcyNmdDrvrGender             as _InsurPlcyNmdDrvrGender       on  $projection.InsurPlcyNamedDriverGender     = _InsurPlcyNmdDrvrGender.InsurPlcyNamedDriverGender
  association [1..1] to I_InsurPlcyDrvrMaritalStsLink        as _InsurPlcyNmdDrvrMaritalSts   on  $projection.InsurPlcyNmdDrvrMaritalStatus  = _InsurPlcyNmdDrvrMaritalSts.InsurPlcyNmdDrvrMaritalStatus
                                                                                              and $projection.InsurPlcyNmdDrvrTemplate       = _InsurPlcyNmdDrvrMaritalSts.InsurPlcyNmdDrvrTemplate
  association [1..1] to I_InsurPlcyNmdDrvrCategoryLink       as _InsurPlcyNmdDrvrCategoryLink on  $projection.InsurPlcyNmdDrvrDrvrCategoryID = _InsurPlcyNmdDrvrCategoryLink.InsurPlcyNmdDrvrDrvrCategoryID
                                                                                              and $projection.InsurPlcyNmdDrvrTemplate       = _InsurPlcyNmdDrvrCategoryLink.InsurPlcyNmdDrvrTemplate
  association [1..*] to I_InsurPlcyTemplateT                 as _InsurPlcyTemplateT           on  $projection.InsurPlcyNmdDrvrTemplate       = _InsurPlcyTemplateT.InsurPlcyTemplate

{

  key NamedDriver.InsurPlcyUUID,
  key NamedDriver.InsurPlcyInsurContr,
  key NamedDriver.InsurPlcyCoveragePackageID,
  key NamedDriver.InsurPlcyCoverageID,
  key NamedDriver.InsurPlcyInsuredObjectID,
  key NamedDriver.InsurPlcyInsrdVehNmdDrvrID,
  key cast( PlcyJrnl.InsurPlcyContrDataDetnJrnlNmbr as /pm0/vdm_contr_detn_jrnlnmbr preserving type ) as InsurPlcyContrDataDetnJrnlNmbr,
      NamedDriver.InsurPlcyJrnlNmbr,
      NamedDriver.InsurPlcyJrnlEndNmbr,
      @Consumption.hidden: true
      NamedDriver.InsurPlcyProductPackageID,
      @ObjectModel.text.association: '_InsurPlcyTemplateT'
      NamedDriver.InsurPlcyNmdDrvrTemplate,

      //FS-PM Auto specific Fields

      NamedDriver.AddressID,
      NamedDriver.InsurPlcyNamedDriver,
      NamedDriver.InsurPlcyNmdDrvrBirthDate,
      @ObjectModel.foreignKey.association: '_InsurPlcyNmdDrvrCategoryLink'
      NamedDriver.InsurPlcyNmdDrvrDrvrCategoryID,
      @ObjectModel.foreignKey.association: '_InsurPlcyNmdDrvrGender'
      NamedDriver.InsurPlcyNamedDriverGender,
      NamedDriver.InsurPlcyNmdDrvrDrvrLicNumber,
      NamedDriver.InsurPlcyNmdDrvrDrvrLicIssDte,
      @ObjectModel.foreignKey.association: '_InsurPlcyNmdDrvrMaritalSts'
      NamedDriver.InsurPlcyNmdDrvrMaritalStatus,
      @Semantics.systemDateTime.lastChangedAt: true
      NamedDriver.LastChangeDateTime,
      
      /* Associations */
      _InsurApplContrInsuredObject,
      @Consumption.hidden: true
      _InsurPlcyNmdDrvrGender,
      @Consumption.hidden: true
      _InsurPlcyNmdDrvrMaritalSts,
      @Consumption.hidden: true
      _InsurPlcyNmdDrvrCategoryLink,
      @Consumption.hidden: true
      _InsurPlcyTemplateT

}
where
      NamedDriver.InsurPlcyCoveragePackageID = 0
  and NamedDriver.InsurPlcyCoverageID        = 0
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSURPLCYNAMEDDRIVERBASIC",
"P_INSURPOLICYJOURNALKEYS"
],
"ASSOCIATED":
[
"I_INSURAPPLCONTRINSUREDOBJECT",
"I_INSURPLCYDRVRMARITALSTSLINK",
"I_INSURPLCYNMDDRVRCATEGORYLINK",
"I_INSURPLCYNMDDRVRGENDER",
"I_INSURPLCYTEMPLATET"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/