I_InspSubsetResultValueTP

@AbapCatalog.sqlViewName: 'IINSUBRESVALTP'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Single Value of an Inspection Charc Rslt'
@AccessControl.privilegedAssociations:  [ '_InspectionCharacteristic' ]
@VDM.viewType: #TRANSACTIONAL

// Draft 2.0 Annotations

@ObjectModel.semanticKey:  [ 'InspectionLot' , 'InspPlanOperationInternalID' , 'InspectionCharacteristic' , 'InspResultValueInternalID'  ] 
@ObjectModel:{
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: true,
//    transactionalProcessingEnabled: true,

//    draftEnabled: true,

    writeDraftPersistence: 'QINSPRSLTVAL_D' 
    }
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #L,
    serviceQuality: #A
}

define view I_InspSubsetResultValueTP as select from I_InspectionResultValue 
association [1..1] to I_InspectionSubsetTP         as _InspectionSubset         on  $projection.InspectionLot               = _InspectionSubset.InspectionLot
                                                                                and $projection.InspPlanOperationInternalID = _InspectionSubset.InspPlanOperationInternalID
                                                                                and $projection.InspectionSubsetInternalID  = _InspectionSubset.InspectionSubsetInternalID
association [1..1] to I_InspSubsetCharcResultTP  as _InspSubsetCharacteristic  on  $projection.InspectionLot               = _InspSubsetCharacteristic.InspectionLot
                                                                                  and $projection.InspPlanOperationInternalID = _InspSubsetCharacteristic.InspPlanOperationInternalID
                                                                                  and $projection.InspectionSubsetInternalID  = _InspSubsetCharacteristic.InspectionSubsetInternalID
                                                                                  and $projection.InspectionCharacteristic    = _InspSubsetCharacteristic.InspectionCharacteristic
{
      @ObjectModel.foreignKey.association: '_InspectionLot'
  key InspectionLot,
      @ObjectModel.foreignKey.association: '_InspectionOperation'
  key InspPlanOperationInternalID,
      @ObjectModel.foreignKey.association: '_InspectionSubset'
  key InspectionSubsetInternalID,  
      @ObjectModel.foreignKey.association: '_InspectionCharacteristic'
  key InspectionCharacteristic,
  key InspResultValueInternalID,
      @ObjectModel.foreignKey.association: '_InspectionResultAttribute'
      InspectionResultAttribute,
      CreationDate,
      InspResultItemInternalID,
      InspectionResultMeasuredValue,
      InspResultHasMeasuredValue,
      InspectionResultOriginalValue,
      InspectionResultText,
      InspLotSingleUnitNumber,
      InspectionResultItem,
      InspRsltFreeDefinedTestEquip,
      @ObjectModel.foreignKey.association: '_InspectionValuationResult'
      InspectionValuationResult,
      @ObjectModel.foreignKey.association: '_CharcAttributeCodeGrp'
      CharacteristicAttributeCodeGrp,
      InspectionResultCodeGroup2,
      InspectionResultCodeGroup3,
      InspectionResultCodeGroup4,
      InspectionResultCodeGroup5,
      @ObjectModel.foreignKey.association: '_CharcAttributeCode'
      CharacteristicAttributeCode,
      InspectionResultCode2,
      InspectionResultCode3,
      InspectionResultCode4,
      InspectionResultCode5,
      CharacteristicAttributeCatalog,
      InspectionResultCatalog2,
      InspectionResultCatalog3,
      InspectionResultCatalog4,
      InspectionResultCatalog5,
      InspectionStartDate,
      InspectionStartTime,
      InspectionEndDate,
      InspectionEndTime,
      
      // Association

      _InspectionLot,
      _InspectionOperation,
      _InspectionCharacteristic,
      _CharcAttributeCodeGrp,
      _CharcAttributeCode,
      _InspectionResultAttribute,
      _InspectionValuationResult,
      
      // Association to Draft

      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT ]
       _InspectionSubset,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT ] 
       _InspSubsetCharacteristic 
}
where 
InspectionResultAttribute <> '/'                 // Exclude Deleted Single Result value

    
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPECTIONRESULTVALUE"
],
"ASSOCIATED":
[
"I_CHARCATTRIBUTECODE",
"I_CHARCATTRIBUTECODEGRP",
"I_INSPECTIONCHARACTERISTIC",
"I_INSPECTIONLOT",
"I_INSPECTIONOPERATION",
"I_INSPECTIONRESULTATTRIBUTE",
"I_INSPECTIONSUBSETTP",
"I_INSPECTIONVALUATIONRESULT",
"I_INSPSUBSETCHARCRESULTTP"
],
"BASE":
[
"I_INSPECTIONRESULTVALUE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/