I_InspSubsetCharcResultTP

@AbapCatalog.sqlViewName: 'IINSPSSCHARTP'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_InspectionCharacteristic' ]

@VDM.viewType: #TRANSACTIONAL
@ObjectModel.usageType: { dataClass: #TRANSACTIONAL, sizeCategory: #L, serviceQuality: #D}

@EndUserText.label: 'Insp Charc & Summ. Values for Insp Point'
/* Draft 2.0 */
@ObjectModel.semanticKey:  [ 'InspectionLot' , 'InspPlanOperationInternalID' , 'InspectionCharacteristic' , 'InspectionSubsetInternalID' ] 
@ObjectModel:{
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: true,
    writeDraftPersistence: 'QSUBSETCHARCRR_D',
    entityChangeStateId: 'ChangedDateTime',
    lifecycle.enqueue: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT15M'                   // Default 'PT15M'

      //  notificationBeforeExpiryInterval: 'PT1M'   // Default 'PT5M'

    },
    lifecycle.processing: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT30M'                        // Default 'PT30M'

      //  notificationBeforeExpiryInterval: 'PT3M'     // Default 'PT10M'

    }
}

define view I_InspSubsetCharcResultTP as 
  select from I_InspSubsetCharacteristic            as InspSubsetChar
    left outer to one join I_InspSubsetResult       as InspSubsetResult        on  InspSubsetChar.InspectionLot               = InspSubsetResult.InspectionLot
                                                                               and InspSubsetChar.InspPlanOperationInternalID = InspSubsetResult.InspPlanOperationInternalID                                                                          
                                                                               and InspSubsetChar.InspectionSubsetInternalID  = InspSubsetResult.InspectionSubsetInternalID
                                                                               and InspSubsetChar.InspectionCharacteristic    = InspSubsetResult.InspectionCharacteristic

    left outer to one join I_InspectionLot          as InspectionLot           on InspSubsetChar.InspectionLot = InspectionLot.InspectionLot                                                                      
    
    left outer to one join I_QltyMgmtPlantLvlConfign as Configuration           on InspectionLot.Plant = Configuration.Plant
    left outer to one join P_InspSubsetCharcAgg      as InspSubsetCharcAggregate    
                                                                               on InspSubsetChar.InspectionLot                  = InspSubsetCharcAggregate.InspectionLot
                                                                              and InspSubsetChar.InspPlanOperationInternalID    = InspSubsetCharcAggregate.InspPlanOperationInternalID
                                                                              and InspSubsetChar.InspectionCharacteristic       = InspSubsetCharcAggregate.InspectionCharacteristic
                                                                                  
// Draft Associations

  association [1..1] to I_InspectionSubsetTP        as _InspectionSubset        on  $projection.InspectionLot                = _InspectionSubset.InspectionLot
                                                                                and  $projection.InspPlanOperationInternalID = _InspectionSubset.InspPlanOperationInternalID
                                                                                and  $projection.InspectionSubsetInternalID  = _InspectionSubset.InspectionSubsetInternalID    
  association [0..*] to I_InspSubsetResultValueTP   as _InspectionResultValue    on  $projection.InspectionLot               = _InspectionResultValue.InspectionLot
                                                                                and $projection.InspPlanOperationInternalID  = _InspectionResultValue.InspPlanOperationInternalID
                                                                                and $projection.InspectionSubsetInternalID   = _InspectionResultValue.InspectionSubsetInternalID
                                                                                and $projection.InspectionCharacteristic     = _InspectionResultValue.InspectionCharacteristic                                                                                
// Association

  association [1..1] to I_InspectionLot             as _InspectionLot            on  $projection.InspectionLot               = _InspectionLot.InspectionLot
  association [1..1] to I_InspectionOperation       as _InspectionOperation      on  $projection.InspectionLot               = _InspectionOperation.InspectionLot
                                                                                and  $projection.InspPlanOperationInternalID = _InspectionOperation.InspPlanOperationInternalID  
  association [1..1] to I_InspectionCharacteristic  as _InspectionCharacteristic on   $projection.InspectionLot              = _InspectionCharacteristic.InspectionLot
                                                                                and  $projection.InspPlanOperationInternalID = _InspectionCharacteristic.InspPlanOperationInternalID
                                                                                and  $projection.InspectionCharacteristic    = _InspectionCharacteristic.InspectionCharacteristic                                                                                                                                                                                                                                           
  
  association [1..1] to I_CharcAttributeCodeText    as _InspectionCharcAttriCodeText 
                                                                               on $projection.CharacteristicAttributeCode    = _InspectionCharcAttriCodeText.CharacteristicAttributeCode
                                                                              and $projection.CharacteristicAttributeCodeGrp = _InspectionCharcAttriCodeText.CharacteristicAttributeCodeGrp
                                                                              and _InspectionCharcAttriCodeText.Language     = $session.system_language
   
  association [1..1] to I_InspCharcValueAggregate   as _InspCharcValueAggregate      
                                                                               on $projection.InspectionLot                  = _InspCharcValueAggregate.InspectionLot
                                                                              and $projection.InspPlanOperationInternalID    = _InspCharcValueAggregate.InspPlanOperationInternalID
                                                                              and $projection.InspectionCharacteristic       = _InspCharcValueAggregate.InspectionCharacteristic
                                                                              and $projection.InspectionSubsetInternalID     = _InspCharcValueAggregate.InspectionSubsetInternalID   
  
                                                                                                                                                          
{
    
  @ObjectModel.foreignKey.association: '_InspectionLot'  
  key InspSubsetChar.InspectionLot,
  @ObjectModel.foreignKey.association: '_InspectionOperation'
  key InspSubsetChar.InspPlanOperationInternalID,  
  //@ObjectModel.foreignKey.association: '_InspectionSubsetInternalID'

  key InspSubsetChar.InspectionSubsetInternalID,  
  key InspSubsetChar.InspectionCharacteristic,
      InspSubsetChar.InspectionCharacteristicStatus,
      InspSubsetChar.QualityControlChart,
      InspSubsetChar.InspSampleAcceptanceNumber,
      InspSubsetChar.InspSampleRejectionNumber,
      InspSubsetChar.InspSampleValuationRule,
      InspSubsetChar.InspectionSampleSize,
      InspSubsetChar.InspLotDynRuleStage,
      InspSubsetChar.InspectionSeverity,  
                         
      @ObjectModel.readOnly: true
      InspSubsetResult.ChangedDateTime,
      @ObjectModel.readOnly: true
      InspSubsetResult.LastChangedByUser,
      @ObjectModel.readOnly: true
      InspSubsetResult.CreatedByUser,
      InspSubsetResult.Inspector,
      InspSubsetResult.InspectionResultStatus,
      InspSubsetResult.InspectionResultOrigin,
      InspSubsetResult.InspectionResultAttribute,
      @ObjectModel.foreignKey.association: '_InspectionValuationResult'
      InspSubsetResult.InspectionValuationResult,
      InspSubsetResult.InspectionResultMeanValue,
      InspSubsetResult.InspectionResultHasMeanValue,
      InspSubsetResult.InspectionResultMaximumValue, //Maximum value, single/Summary at  header level

      InspSubsetResult.InspResultHasMaximumValue,
      InspSubsetResult.InspectionResultMinimumValue, //Minimum value, single/Summary at  header level

      InspSubsetResult.InspResultHasMinimumValue,
      InspSubsetResult.InspectionResultOriginalValue,
      InspSubsetResult.InspResultValidValuesNumber,
      cast(InspSubsetResult.InspectionResultText as abap.sstring( 1024 ))               as  InspectionResultText,
      InspSubsetResult.InspectionResultHasLongText,                                // to be checked

      InspSubsetResult.Language,
      InspSubsetResult.InspRsltFreeDefinedTestEquip,
      InspSubsetResult.InspRsltBelowToleranceValsNmbr,
      InspSubsetResult.InspRsltAboveToleranceValsNmbr,
      InspSubsetResult.InspRsltNonconformingValsNmbr,
      InspSubsetResult.InspRsltAboveToleranceFraction,
      InspSubsetResult.InspRsltBelowToleranceFraction,
      InspSubsetResult.InspResultVariance,
      InspSubsetResult.CharacteristicAttributeCodeGrp,
      InspSubsetResult.InspectionResultCodeGroup2,
      InspSubsetResult.InspectionResultCodeGroup3,
      InspSubsetResult.InspectionResultCodeGroup4,
      InspSubsetResult.InspectionResultCodeGroup5,
      InspSubsetResult.CharacteristicAttributeCode,
      InspSubsetResult.InspectionResultCode2,
      InspSubsetResult.InspectionResultCode3,
      InspSubsetResult.InspectionResultCode4,
      InspSubsetResult.InspectionResultCode5,
      InspSubsetResult.CharacteristicAttributeCatalog,
      InspSubsetResult.InspectionResultCatalog2,
      InspSubsetResult.InspectionResultCatalog3,
      InspSubsetResult.InspectionResultCatalog4,
      InspSubsetResult.InspectionResultCatalog5,
      Configuration.InspSpecAddlDecimalPlaces,
      Configuration.InspSpecAddlDecimalPlaces + InspSubsetChar._InspectionCharacteristic.InspSpecDecimalPlaces        as  InspSpecSummarizedDcmlPlaces,
      
      @ObjectModel.readOnly: true
      _InspectionOperation.InspectionOperation,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecRecordingType,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecIsQuantitative,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecIsLongTermInspection,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecCharcCategory,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecResultCalculation,
      
      @ObjectModel.readOnly: true
      InspSubsetCharcAggregate.InspCharAcceptedCount,
      @ObjectModel.readOnly: true
      InspSubsetCharcAggregate.InspCharRejectedCount,
            
      @ObjectModel.readOnly: true
      _InspectionResultStatus._Text[1:Language=$session.system_language].InspectionResultStatusText,
      @ObjectModel.readOnly: true
      _InspCharacteristicStatus._Text[1:Language=$session.system_language].InspectionResultStatusText as CharcStatusName,
      
      
      @ObjectModel.readOnly: true         
      _InspectionCharacteristic.InspectionSpecificationText,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.HasInspCharcPrtlSmpl,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspCharacteristicSampleUnit,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.QuantityUnit,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspLotTestEquipInternalID,
      @ObjectModel.readOnly: true
//      _InspectionCharacteristic.InspectionScope,

      _InspectionCharacteristic.InspCharcQuantity as InspectionScope,  // InspectionScope --> deprecated! Replaced by InspCharcQuantity

      @ObjectModel.readOnly: true
      _InspectionCharacteristic._InspectionMethodVersion.InspectionMethod,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic._InspectionMethodVersion._InspectionMethodText[1:Language = $session.system_language].InspectionMethodText   as  InspectionMethodText,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecDecimalPlaces,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecHasTargetValue,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecHasUpperLimit,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecHasLowerLimit,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspectionMethodPlant,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspectionSpecification,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspectionMethodVersion,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspCharacteristicSampleSize,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecSampleQuantityFactor,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecControlIndicators,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecIsMeasuredValueRqd,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecTargetValue,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecUpperLimit,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecLowerLimit,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspectionSpecificationUnit,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic._InspectionSpecificationUnit._Text[1:Language=$session.system_language].UnitOfMeasureTechnicalName,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspectionSpecificationPlant,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspectionSpecificationVersion,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.SelectedCodeSet,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.SelectedCodeSetPlant,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic._CharcAttribSelectedCodeSet.SelectedCodeSetText,
      
      @ObjectModel.readOnly: true      
      _InspectionResultAttribute._Text[1:Language=$session.system_language].InspectionResultAttributeText as InspectionResultAttributeText,
      @ObjectModel.readOnly: true
      _InspectionCharcAttriCodeText.CharacteristicAttributeCodeTxt  as  CharacteristicAttributeCodeTxt,
      
      @ObjectModel.readOnly: true
      _InspCharcValueAggregate.InspResultValueCount,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspSpecImportanceCode,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic._InspSpecImportanceCode.InspSpecImportanceCodeText,
      @ObjectModel.readOnly: true
      _InspectionCharacteristic.InspResultIsDocumentationRqd,

//      @Semantics.user.createdBy: true

//      @ObjectModel.readOnly: true

//      qasr.ersteller                 as CreatedByUser,

//      @Semantics.businessDate.createdAt: true

//      @ObjectModel.readOnly: true

//      qasr.erstelldat                as CreationDate,

//      @Semantics.user.lastChangedBy: true

//      @ObjectModel.readOnly: true

//      qasr.aenderer                  as LastChangedByUser,

//      @Semantics.businessDate.lastChangedAt: true

//      @ObjectModel.readOnly: true

//      qasr.aenderdat                 as LastChangeDate,


      // Association to Draft Nodes

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT , #TO_COMPOSITION_PARENT ]
      _InspectionSubset,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _InspectionResultValue,
      
      // Associations FROM I_InspSubsetResult

      _CharcAttributeCode,
      _InspectionResultStatus,      
      _InspectionResultAttribute,
      _InspectionResultOrigin,
      _InspectionValuationResult,
      _InspectionValuationRsltTxt,
      
      // Associations FROM I_InspSubsetCharacteristic

      _InspectionLot,
      _InspectionOperation,
      _InspectionCharacteristic,
//      _InspSubsetResult,

      _InspCharacteristicStatus,
      _InspectionSeverity        
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHARCATTRIBSELECTEDCODESET",
"I_CHARCATTRIBUTECODETEXT",
"I_INSPCHARCVALUEAGGREGATE",
"I_INSPECTIONCHARACTERISTIC",
"I_INSPECTIONLOT",
"I_INSPECTIONMETHODVERSION",
"I_INSPECTIONMETHODVERSIONTEXT",
"I_INSPECTIONOPERATION",
"I_INSPECTIONRESULTATTRIBUTE",
"I_INSPECTIONRESULTSTATUS",
"I_INSPECTIONRESULTSTATUSTEXT",
"I_INSPRESULTATTRIBUTETEXT",
"I_INSPSPECIMPORTANCECODE",
"I_INSPSUBSETCHARACTERISTIC",
"I_INSPSUBSETRESULT",
"I_QLTYMGMTPLANTLVLCONFIGN",
"I_UNITOFMEASURE",
"I_UNITOFMEASURETEXT",
"P_INSPSUBSETCHARCAGG"
],
"ASSOCIATED":
[
"I_CHARCATTRIBUTECODE",
"I_CHARCATTRIBUTECODETEXT",
"I_INSPCHARCVALUEAGGREGATE",
"I_INSPECTIONCHARACTERISTIC",
"I_INSPECTIONLOT",
"I_INSPECTIONOPERATION",
"I_INSPECTIONRESULTATTRIBUTE",
"I_INSPECTIONRESULTORIGIN",
"I_INSPECTIONRESULTSTATUS",
"I_INSPECTIONSEVERITY",
"I_INSPECTIONSUBSETTP",
"I_INSPECTIONVALUATIONRESULT",
"I_INSPECTIONVALUATIONRSLTTEXT",
"I_INSPSUBSETRESULTVALUETP"
],
"BASE":
[
"I_INSPSUBSETCHARACTERISTIC",
"I_INSPSUBSETRESULT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/