I_IN_OutgInvcAcctDocHdr

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Outgoing Invoice Account Document Header'
@Metadata.ignorePropagatedAnnotations: false
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
define view entity I_IN_OutgInvcAcctDocHdr
  as select distinct from I_JournalEntry as OutgInvcDocHdr
  inner join I_IN_AcctDocTypeClassfctn on ( I_IN_AcctDocTypeClassfctn.CompanyCode = OutgInvcDocHdr.CompanyCode or I_IN_AcctDocTypeClassfctn.CompanyCode = '' )
                                      and I_IN_AcctDocTypeClassfctn.AccountingDocumentType = OutgInvcDocHdr.AccountingDocumentType
  association [1..*] to I_IN_OutgInvcAcctRblItm   as _OutgInvcARItem      on  $projection.CompanyCode        = _OutgInvcARItem.CompanyCode
                                                                          and $projection.AccountingDocument = _OutgInvcARItem.AccountingDocument
                                                                          and $projection.FiscalYear         = _OutgInvcARItem.FiscalYear
  association [1..*] to I_OperationalAcctgDocItem as _OutgInvcRevenueItem on  $projection.CompanyCode                           = _OutgInvcRevenueItem.CompanyCode
                                                                          and $projection.AccountingDocument                    = _OutgInvcRevenueItem.AccountingDocument
                                                                          and $projection.FiscalYear                            = _OutgInvcRevenueItem.FiscalYear
                                                                          and _OutgInvcRevenueItem.FinancialAccountType         = 'S'
                                                                          and _OutgInvcRevenueItem.AccountingDocumentItemType   = ''
                                                                          and _OutgInvcRevenueItem.TransactionTypeDetermination = ''
                                                                          and _OutgInvcRevenueItem.IsAutomaticallyCreated       = ''
  association [0..*] to I_OperationalAcctgDocItem as _OutgInvcTaxItem     on  $projection.CompanyCode                       =  _OutgInvcTaxItem.CompanyCode
                                                                          and $projection.AccountingDocument                =  _OutgInvcTaxItem.AccountingDocument
                                                                          and $projection.FiscalYear                        =  _OutgInvcTaxItem.FiscalYear
                                                                          and _OutgInvcTaxItem.FinancialAccountType         =  'S'
                                                                          and _OutgInvcTaxItem.AccountingDocumentItemType   =  'T'
                                                                          and _OutgInvcTaxItem.TransactionTypeDetermination <> ''
                                                                          and _OutgInvcTaxItem.IsAutomaticallyCreated       =  'X'
{
  key OutgInvcDocHdr.CompanyCode,
  key OutgInvcDocHdr.FiscalYear,
  key OutgInvcDocHdr.AccountingDocument,
      OutgInvcDocHdr.AccountingDocumentType,
      OutgInvcDocHdr.DocumentDate,
      OutgInvcDocHdr.PostingDate,
      OutgInvcDocHdr.FiscalPeriod,
      OutgInvcDocHdr.AccountingDocumentCreationDate,
      OutgInvcDocHdr.CreationTime,
      OutgInvcDocHdr.LastManualChangeDate,
      OutgInvcDocHdr.LastAutomaticChangeDate,
      OutgInvcDocHdr.LastChangeDate,
      OutgInvcDocHdr.ExchangeRateDate,
      OutgInvcDocHdr.AccountingDocCreatedByUser,
      OutgInvcDocHdr.TransactionCode,
      OutgInvcDocHdr.IntercompanyTransaction,
      OutgInvcDocHdr.DocumentReferenceID,
      OutgInvcDocHdr.RecurringAccountingDocument,
      OutgInvcDocHdr.ReverseDocument,
      OutgInvcDocHdr.ReverseDocumentFiscalYear,
      OutgInvcDocHdr.AccountingDocumentHeaderText,
      OutgInvcDocHdr.TransactionCurrency,
      OutgInvcDocHdr.AbsoluteExchangeRate,
//      OutgInvcDocHdr.ExchangeRate,

      OutgInvcDocHdr.ExchRateIsIndirectQuotation,
      OutgInvcDocHdr.EffectiveExchangeRate,
      OutgInvcDocHdr.AccountingDocumentCategory,
      OutgInvcDocHdr.NetAmountIsPosted,
      OutgInvcDocHdr.JrnlEntryIsPostedToPrevPeriod,
      OutgInvcDocHdr.BusinessTransactionType,
      OutgInvcDocHdr.BatchInputSession,
      OutgInvcDocHdr.ReferenceDocumentType,
      OutgInvcDocHdr.OriginalReferenceDocument,
      OutgInvcDocHdr.FinancialManagementArea,
      OutgInvcDocHdr.CompanyCodeCurrency,
      OutgInvcDocHdr.AdditionalCurrency1,
      OutgInvcDocHdr.AdditionalCurrency2,
      OutgInvcDocHdr.ReversalIsPlanned,
      OutgInvcDocHdr.PlannedReversalDate,
      OutgInvcDocHdr.TaxIsCalculatedAutomatically,
      OutgInvcDocHdr.AdditionalCurrency1Role,
      OutgInvcDocHdr.AdditionalCurrency2Role,
      OutgInvcDocHdr.TaxBaseAmountIsNetAmount,
      OutgInvcDocHdr.SourceCompanyCode,
      OutgInvcDocHdr.LogicalSystem,
      OutgInvcDocHdr.ReferenceDocumentLogicalSystem,
      OutgInvcDocHdr.TaxAbsoluteExchangeRate,
//      OutgInvcDocHdr.TaxExchangeRate,

      OutgInvcDocHdr.TaxExchRateIsIndirectQuotation,
      OutgInvcDocHdr.TaxEffectiveExchangeRate,
      OutgInvcDocHdr.CtryCrcyTxAbsoluteExchangeRate,
      OutgInvcDocHdr.CtryCrcyTaxEffctvExchangeRate,
      OutgInvcDocHdr.ReversalReason,
      OutgInvcDocHdr.ParkedByUser,
      OutgInvcDocHdr.ParkingDate,
      OutgInvcDocHdr.ParkingTime,
      OutgInvcDocHdr.Branch,
      OutgInvcDocHdr.NmbrOfPages,
      OutgInvcDocHdr.IsDiscountDocument,
      OutgInvcDocHdr.Reference1InDocumentHeader,
      OutgInvcDocHdr.Reference2InDocumentHeader,
      OutgInvcDocHdr.InvoiceReceiptDate,
      OutgInvcDocHdr.Ledger,
      OutgInvcDocHdr.LedgerGroup,
      OutgInvcDocHdr.AlternativeReferenceDocument,
      OutgInvcDocHdr.TaxReportingDate,
      OutgInvcDocHdr.TaxFulfillmentDate,
      OutgInvcDocHdr.AccountingDocumentClass,
      OutgInvcDocHdr.ExchangeRateType,
      OutgInvcDocHdr.MarketDataAbsoluteExchangeRate,
      OutgInvcDocHdr.MktDataEffectiveExchangeRate,
      OutgInvcDocHdr.SenderLogicalSystem,
      OutgInvcDocHdr.SenderCompanyCode,
      OutgInvcDocHdr.SenderAccountingDocument,
      OutgInvcDocHdr.SenderFiscalYear,
      OutgInvcDocHdr.ReversalReferenceDocumentCntxt,
      OutgInvcDocHdr.ReversalReferenceDocument,
      OutgInvcDocHdr.LatePaymentReason,
      OutgInvcDocHdr.SalesDocumentCondition,
      OutgInvcDocHdr.IsReversal,
      OutgInvcDocHdr.IsReversed,
      OutgInvcDocHdr.GLBusinessTransactionGroup,
      OutgInvcDocHdr.CostAccountingValuationDate,
      OutgInvcDocHdr.TaxCountry,
      OutgInvcDocHdr.JournalEntryLastChangeDateTime,
      OutgInvcDocHdr.JrnlEntryCntrySpecificRef1,
      OutgInvcDocHdr.JrnlEntryCntrySpecificDate1,
      OutgInvcDocHdr.JrnlEntryCntrySpecificRef2,
      OutgInvcDocHdr.JrnlEntryCntrySpecificDate2,
      OutgInvcDocHdr.JrnlEntryCntrySpecificRef3,
      OutgInvcDocHdr.JrnlEntryCntrySpecificDate3,
      OutgInvcDocHdr.JrnlEntryCntrySpecificRef4,
      OutgInvcDocHdr.JrnlEntryCntrySpecificDate4,
      OutgInvcDocHdr.JrnlEntryCntrySpecificRef5,
      OutgInvcDocHdr.JrnlEntryCntrySpecificDate5,
      OutgInvcDocHdr.JrnlEntryCntrySpecificBP1,
      OutgInvcDocHdr.JrnlEntryCntrySpecificBP2,
      OutgInvcDocHdr.WithholdingTaxReportingDate,
      /* Associations */
      OutgInvcDocHdr._AccountingDocumentCategory,
      OutgInvcDocHdr._AccountingDocumentType,
      OutgInvcDocHdr._AccountingDocumentTypeText,
      OutgInvcDocHdr._AdditionalCurrency1,
      OutgInvcDocHdr._AdditionalCurrency1Role,
      OutgInvcDocHdr._AdditionalCurrency2,
      OutgInvcDocHdr._AdditionalCurrency2Role,
      OutgInvcDocHdr._AddlLedgerOplAcctgDocItem,
      OutgInvcDocHdr._BusinessTransactionType,
      OutgInvcDocHdr._BusinessTransactionTypeText,
      OutgInvcDocHdr._CompanyCode,
      OutgInvcDocHdr._CompanyCodeCurrency,
      OutgInvcDocHdr._FinancialManagementArea,
      OutgInvcDocHdr._FinancialManagementAreaText,
      OutgInvcDocHdr._FiscalPeriod,
      OutgInvcDocHdr._FiscalYear,
      OutgInvcDocHdr._JournalEntryItem,
      OutgInvcDocHdr._Ledger,
      OutgInvcDocHdr._LedgerGroup,
      OutgInvcDocHdr._LedgerText,
      OutgInvcDocHdr._LogicalSystem,
      OutgInvcDocHdr._OperationalAcctgDocItem,
      OutgInvcDocHdr._RefDocumentLogicalSystem,
      OutgInvcDocHdr._ReferenceDocumentType,
      OutgInvcDocHdr._TransactionCurrency,
      OutgInvcDocHdr._User,
      _OutgInvcARItem,
      _OutgInvcRevenueItem,
      _OutgInvcTaxItem
}
where
      OutgInvcDocHdr.IsReversal                         = ''
  and OutgInvcDocHdr._CompanyCode.Country               = 'IN'
  and I_IN_AcctDocTypeClassfctn.IN_AcctDocTypeClassfctn = 'GSTOI';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_IN_ACCTDOCTYPECLASSFCTN",
"I_JOURNALENTRY"
],
"ASSOCIATED":
[
"I_ACCOUNTINGDOCUMENTCATEGORY",
"I_ACCOUNTINGDOCUMENTTYPE",
"I_ACCOUNTINGDOCUMENTTYPETEXT",
"I_ADDLLEDGEROPLACCTGDOCITEM",
"I_BUSINESSTRANSACTIONTYPE",
"I_BUSTRANSACTIONTYPETEXT",
"I_COMPANYCODE",
"I_CURRENCY",
"I_CURRENCYROLE",
"I_FINANCIALMANAGEMENTAREA",
"I_FINANCIALMANAGEMENTAREATEXT",
"I_FISCALYEARFORCOMPANYCODE",
"I_FISCALYEARPERIODFORCMPNYCODE",
"I_IN_OUTGINVCACCTRBLITM",
"I_JOURNALENTRYITEM",
"I_LEDGER",
"I_LEDGERGROUP",
"I_LEDGERTEXT",
"I_LOGICALSYSTEM",
"I_OPERATIONALACCTGDOCITEM",
"I_REFERENCEDOCUMENTTYPE",
"I_USER"
],
"BASE":
[
"I_JOURNALENTRY"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/