I_IN_OutgInvcAcctRblItm

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Outgoing Invoice Account Receivable Item'
@Metadata.ignorePropagatedAnnotations: false
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
define view entity I_IN_OutgInvcAcctRblItm
  as select from I_OperationalAcctgDocItem as OutInvcAcctPyblItem
  inner join   I_IN_AcctDocTypeClassfctn on  ( I_IN_AcctDocTypeClassfctn.CompanyCode = OutInvcAcctPyblItem.CompanyCode
                                            or I_IN_AcctDocTypeClassfctn.CompanyCode = '' )
                                           and I_IN_AcctDocTypeClassfctn.AccountingDocumentType = OutInvcAcctPyblItem.AccountingDocumentType

  association [0..*] to I_OperationalAcctgDocItem as _OutgInvcRevenueItem on  $projection.CompanyCode                           = _OutgInvcRevenueItem.CompanyCode
                                                                          and $projection.AccountingDocument                    = _OutgInvcRevenueItem.AccountingDocument
                                                                          and $projection.FiscalYear                            = _OutgInvcRevenueItem.FiscalYear
                                                                          and _OutgInvcRevenueItem.FinancialAccountType         = 'S'
                                                                          and _OutgInvcRevenueItem.AccountingDocumentItemType   = ''
                                                                          and _OutgInvcRevenueItem.TransactionTypeDetermination = ''
                                                                          and _OutgInvcRevenueItem.IsAutomaticallyCreated       = ''

  association [0..*] to I_OperationalAcctgDocItem as _OutgInvcTaxItem     on  $projection.CompanyCode                       =  _OutgInvcTaxItem.CompanyCode
                                                                          and $projection.AccountingDocument                =  _OutgInvcTaxItem.AccountingDocument
                                                                          and $projection.FiscalYear                        =  _OutgInvcTaxItem.FiscalYear
                                                                          and _OutgInvcTaxItem.FinancialAccountType         =  'S'
                                                                          and _OutgInvcTaxItem.AccountingDocumentItemType   =  'T'
                                                                          and _OutgInvcTaxItem.TransactionTypeDetermination <> ''
                                                                          and _OutgInvcTaxItem.IsAutomaticallyCreated       =  'X'
                                           
  association [0..1] to I_BusinessPlace           as _BusinessPlace       on  $projection.CompanyCode   = _BusinessPlace.CompanyCode
                                                                          and $projection.BusinessPlace = _BusinessPlace.BusinessPlace
{
  key OutInvcAcctPyblItem.CompanyCode,
  key OutInvcAcctPyblItem.AccountingDocument,
  key OutInvcAcctPyblItem.FiscalYear,
  key OutInvcAcctPyblItem.AccountingDocumentItem,
      OutInvcAcctPyblItem.FinancialAccountType,
      OutInvcAcctPyblItem.SpecialGLCode,
      OutInvcAcctPyblItem.SpecialGLTransactionType,
      OutInvcAcctPyblItem.DebitCreditCode,
      OutInvcAcctPyblItem.BillingDocument,
      OutInvcAcctPyblItem.SalesDocument,
      OutInvcAcctPyblItem.SalesDocumentItem,
      OutInvcAcctPyblItem.IsSalesRelated,
      OutInvcAcctPyblItem.IsAutomaticallyCreated,
      OutInvcAcctPyblItem.IsUsedInPaymentTransaction,
      OutInvcAcctPyblItem.Customer,
      OutInvcAcctPyblItem.InvoiceReference,
      OutInvcAcctPyblItem.InvoiceReferenceFiscalYear,
      OutInvcAcctPyblItem.InvoiceItemReference,
      OutInvcAcctPyblItem.FollowOnDocumentType,
      OutInvcAcctPyblItem.Material,
      OutInvcAcctPyblItem.Product,
      OutInvcAcctPyblItem.Plant,
      OutInvcAcctPyblItem.PurchasingDocument,
      OutInvcAcctPyblItem.PurchasingDocumentItem,
      OutInvcAcctPyblItem.IsNegativePosting,
      OutInvcAcctPyblItem.BusinessPlace,
      OutInvcAcctPyblItem.TaxSection,
      OutInvcAcctPyblItem.ReferenceDocumentType,
      OutInvcAcctPyblItem.OriginalReferenceDocument,
      OutInvcAcctPyblItem.ReferenceDocumentLogicalSystem,
      OutInvcAcctPyblItem.AccountingDocumentItemRef,
      OutInvcAcctPyblItem.FiscalPeriod,
      OutInvcAcctPyblItem.AccountingDocumentCategory,
      OutInvcAcctPyblItem.PostingDate,
      OutInvcAcctPyblItem.DocumentDate,
      OutInvcAcctPyblItem.AccountingDocumentType,
      OutInvcAcctPyblItem.BaseUnit,
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      OutInvcAcctPyblItem.Quantity,
      OutInvcAcctPyblItem.IN_GSTPartner,
      OutInvcAcctPyblItem.IN_GSTPlaceOfSupply,
      OutInvcAcctPyblItem.IN_HSNOrSACCode,
      //      /* Associations */

      OutInvcAcctPyblItem._CompanyCode,
      OutInvcAcctPyblItem._Customer,
      OutInvcAcctPyblItem._DebitCreditCode,
      OutInvcAcctPyblItem._FinancialAccountType,
      OutInvcAcctPyblItem._FiscalYear,
      OutInvcAcctPyblItem._JournalEntry,
      OutInvcAcctPyblItem._Material,
      OutInvcAcctPyblItem._Plant,
      OutInvcAcctPyblItem._Product,
      OutInvcAcctPyblItem._ProductText,
      OutInvcAcctPyblItem._PurchasingDocument,
      OutInvcAcctPyblItem._PurchasingDocumentItem,
      OutInvcAcctPyblItem._ReferenceDocumentType,
      OutInvcAcctPyblItem._SalesDoc,
      OutInvcAcctPyblItem._SalesDocItem,
      OutInvcAcctPyblItem._SalesDocument,
      OutInvcAcctPyblItem._SalesDocumentItem,
      _OutgInvcRevenueItem,
      _OutgInvcTaxItem,
      _BusinessPlace
}
where
      OutInvcAcctPyblItem.FinancialAccountType          = 'D'
  and OutInvcAcctPyblItem.AccountingDocumentItemType    = ''
  and OutInvcAcctPyblItem.SpecialGLTransactionType      = ''
  and OutInvcAcctPyblItem.SpecialGLCode                 = ''
  and OutInvcAcctPyblItem.IsUsedInPaymentTransaction    = ''
  and OutInvcAcctPyblItem._JournalEntry.IsReversal      = ''
  and OutInvcAcctPyblItem._CompanyCode.Country          = 'IN'
  and I_IN_AcctDocTypeClassfctn.IN_AcctDocTypeClassfctn = 'GSTOI';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_IN_ACCTDOCTYPECLASSFCTN",
"I_JOURNALENTRY",
"I_OPERATIONALACCTGDOCITEM"
],
"ASSOCIATED":
[
"I_BUSINESSPLACE",
"I_COMPANYCODE",
"I_CUSTOMER",
"I_DEBITCREDITCODE",
"I_FINANCIALACCOUNTTYPE",
"I_FISCALYEARFORCOMPANYCODE",
"I_JOURNALENTRY",
"I_MATERIAL",
"I_OPERATIONALACCTGDOCITEM",
"I_PLANT",
"I_PRODUCT",
"I_PRODUCTDESCRIPTION",
"I_PURCHASINGDOCUMENT",
"I_PURCHASINGDOCUMENTITEM",
"I_REFERENCEDOCUMENTTYPE",
"I_SALESDOCUMENT",
"I_SALESDOCUMENTITEM",
"I_SALESORDER",
"I_SALESORDERITEM"
],
"BASE":
[
"I_OPERATIONALACCTGDOCITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/