I_IHBMasterDataObjectComposite

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'IHB Master Data Object Composite'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.
  usageType: {
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #MASTER
}
@VDM.viewType: #COMPOSITE

define view entity I_IHBMasterDataObjectComposite
  as select from I_IHBMasterDataObject
  association [0..1] to I_IHBAccountComposite          as _IHBAccount                 on  $projection.IHBObjectKeyUUID = _IHBAccount.IHBAccountUUID
  with default filter $projection.IHBObjectCategory = '40' //Account

  association [0..1] to I_IHBGroupType                 as _IHBGroupType               on  $projection.IHBObjectKeyUUID = _IHBGroupType.IHBGroupUUID
  with default filter $projection.IHBObjectCategory = '45'
               or     $projection.IHBObjectCategory = '55' //Group and Bank Area Group

  association [0..1] to I_IHBObjectCategory            as _IHBObjectCategory          on  $projection.IHBObjectCategory = _IHBObjectCategory.IHBObjectCategory
  association [0..1] to I_IHBObjectReleaseStatus       as _IHBObjectReleaseStatus     on  $projection.IHBReleaseStatus = _IHBObjectReleaseStatus.IHBReleaseStatus
  association [0..1] to I_IHBObjectRelStsCriticality   as _IHBObjectRelStsCriticality on  $projection.IHBReleaseStatus = _IHBObjectRelStsCriticality.IHBReleaseStatus
  association [0..1] to I_IHBMasterDataObjectComposite as _IHBObjectParent            on  $projection.IHBObjectReferenceUUID = _IHBObjectParent.IHBObjectUUID
  association [0..1] to I_IHBMasterDataObjectComposite as _IHBObjectChild             on  $projection.IHBObjectUUID =  _IHBObjectChild.IHBObjectReferenceUUID
                                                                                      and $projection.IHBObjectUUID <> _IHBObjectChild.IHBObjectUUID
  association [0..1] to I_User                         as _CreatedBy                  on  $projection.IHBObjectCreatedByUser = _CreatedBy.UserID
  association [0..1] to I_User                         as _OpenedBy                   on  $projection.IHBObjectChangedByUser = _OpenedBy.UserID
  association [0..1] to I_User                         as _ReleasedBy                 on  $projection.IHBObjectReleasedByUser = _ReleasedBy.UserID

{
  key IHBObjectUUID,

      IHBObjectReferenceUUID,
      IHBObjectType,
      IHBObjectCategory,
      IHBObjectKeyUUID,

      IHBReleaseStatus,
      IHBObjectApprovalActivity,
      IHBObjectDeadlineDateTime,
      IHBObjectReleaseDateTime,
      IHBObjectReleasedByUser,

      IHBObjectTotalChangedDateTime,
      IHBObjectCreatedDateTime,
      IHBObjectCreatedByUser,
      IHBObjectChangedDateTime,
      IHBObjectChangedByUser,
   
      _IHBAccount,
      _IHBGroupType,
      _IHBObjectCategory,
      _IHBObjectReleaseStatus,
      _IHBObjectRelStsCriticality,
      _IHBObjectParent,
      _IHBObjectChild,
      _CreatedBy,
      _OpenedBy,
      _ReleasedBy

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_IHBMASTERDATAOBJECT"
],
"ASSOCIATED":
[
"I_IHBACCOUNTCOMPOSITE",
"I_IHBGROUPTYPE",
"I_IHBMASTERDATAOBJECTCOMPOSITE",
"I_IHBOBJECTCATEGORY",
"I_IHBOBJECTRELEASESTATUS",
"I_IHBOBJECTRELSTSCRITICALITY",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/