I_HandlingUnitItem

@EndUserText.label: 'Handling Unit Item'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type:  #PUBLIC_LOCAL_API
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

@AbapCatalog: {
    sqlViewName: 'IHANDLINGUNITIT',
    compiler.compareFilter: true,
    preserveKey:true
}

@ObjectModel: {
//   semanticKey:       [ 'ExternalId' ],

//  representativeKey: 'HandlingUnitInternalId',

    representativeKey: 'HandlingUnitItem',
    usageType: {
     serviceQuality:  #C,
     dataClass:       #MIXED,
     sizeCategory:    #XL
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ],
   modelingPattern: #NONE
}

@Metadata.ignorePropagatedAnnotations: true

define view I_HandlingUnitItem
  as select from vepo as HandlingUnitItem
  association [1..1] to I_HandlingUnitHeader        as _HandlingUnitHeader        on  $projection.HandlingUnitInternalID = _HandlingUnitHeader.HandlingUnitInternalID
  association [0..1] to I_Plant                     as _Plant                     on  $projection.Plant = _Plant.Plant
  association [0..1] to I_UnitOfMeasure             as _BaseUnitOfMeasure         on  _BaseUnitOfMeasure.UnitOfMeasure = $projection.HandlingUnitQuantityUnit
  association [0..1] to I_UnitOfMeasure             as _AlternativeUnitOfMeasure  on  _AlternativeUnitOfMeasure.UnitOfMeasure = $projection.HandlingUnitAltUnitOfMeasure
  association [0..1] to I_Material                  as _Material                  on  $projection.Material = _Material.Material
  association [0..1] to I_StorageLocation           as _StorageLocation           on  $projection.Plant           = _StorageLocation.Plant
                                                                                  and $projection.StorageLocation = _StorageLocation.StorageLocation
  association [0..*] to I_SerialNumberHandlingUnit  as _HandlingUnitSerialNumber  on  _HandlingUnitSerialNumber.HandlingUnitInternalID = $projection.HandlingUnitInternalID
                                                                                  and $projection.HandlingUnitItem                     = _HandlingUnitSerialNumber.HandlingUnitItem
  //  association [0..1]  to C_SrlNmbrAsGprfTemp          as _SerialNumberProfile        on _SerialNumberProfile.SerialNumberProfile = $projection.SerialNumberProfile

  association [0..1] to I_SalesDocumentItemCategory as _SalesDocumentItemCategory on  $projection.SalesDocumentItemCategory = _SalesDocumentItemCategory.SalesDocumentItemCategory
  association [0..1] to I_BatchCrossPlant           as _Batch                     on  $projection.Batch    = _Batch.Batch
                                                                                  and $projection.Material = _Batch.Material
  association [0..*] to I_JITCallCompMaterialBasic  as _JITCallCompMaterialBasic  on  $projection.HandlingUnitReferenceDocument = _JITCallCompMaterialBasic.SalesOrder
                                                                                  and $projection.HandlingUnitRefDocumentItem   = _JITCallCompMaterialBasic.SalesOrderItem
{
  @ObjectModel.foreignKey.association: '_HandlingUnitHeader'
  key        venum                                      as HandlingUnitInternalID,
  key        vepos                                      as HandlingUnitItem,

             _HandlingUnitHeader.HandlingUnitExternalID as HandlingUnitExternalID,

             velin                                      as HandlingUnitTypeOfContent,
             vbeln                                      as HandlingUnitReferenceDocument,
             posnr                                      as HandlingUnitRefDocumentItem,
             vbtyp                                      as SDDocumentCategory,
             unvel                                      as HandlingUnitNestedInternalID,
             @Semantics.quantity.unitOfMeasure: 'HandlingUnitQuantityUnit'
             vemng                                      as HandlingUnitQuantity,
             vemeh                                      as HandlingUnitQuantityUnit,
             altme                                      as HandlingUnitAltUnitOfMeasure,
             veanz                                      as HandlingUnitNrOfAuxPackgMat,
             kzbei                                      as HandlingUnitItemIsSupplement,
             matnr                                      as Material,
             charg                                      as Batch,
             werks                                      as Plant,
             lgort                                      as StorageLocation,
             cuobj                                      as ConfigurationObject,
             sobkz                                      as InventorySpecialStockType,
             sonum                                      as SpecialStockNumber,
             qplos                                      as HandlingUnitInspectLotNumber,
             anzsn                                      as HandlingUnitNumberOfSerialNumb,
             serail                                     as SerialNumberProfile,
             pstyv                                      as SalesDocumentItemCategory,
             posnr_gen                                  as HandlingUnitGenDeliveryItem,
             p_material                                 as MaterialByCustomer,
             wdatu                                      as HandlingUnitGoodsReceiptDate,
             vfdat                                      as ShelfLifeExpirationDate,
             sgt_scat                                   as StockSegment,
             handle_vepo                                as HandlingUnitItemUUID,


             // Associations

             _HandlingUnitHeader,
             _BaseUnitOfMeasure,
             _AlternativeUnitOfMeasure,
             _Material,
             _Plant,
             _StorageLocation,
             _SalesDocumentItemCategory,
             _Batch,
             _JITCallCompMaterialBasic,
             _HandlingUnitSerialNumber
             //_SerialNumberProfile,

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_HANDLINGUNITHEADER",
"VEPO"
],
"ASSOCIATED":
[
"I_BATCHCROSSPLANT",
"I_HANDLINGUNITHEADER",
"I_JITCALLCOMPMATERIALBASIC",
"I_MATERIAL",
"I_PLANT",
"I_SALESDOCUMENTITEMCATEGORY",
"I_SERIALNUMBERHANDLINGUNIT",
"I_STORAGELOCATION",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/