I_GroupReportingFSItemHierNode

@AbapCatalog:{
  sqlViewName: 'IGRFSITMHN'
  }
@Hierarchy.parentChild: {
  recurse:          { parent:    'ParentNode',
                      child:     'HierarchyNode'   },
  siblingsOrder:    [{ by:       'HierarchyNodeSequence',
                      direction: #ASC   }],
  directory:        '_Hierarchy'
}
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel:
  {usageType: {
    dataClass: #MASTER,
    serviceQuality: #A,
    sizeCategory: #XL},
  dataCategory: #HIERARCHY,
  representativeKey: 'HierarchyNode'
}
@VDM.viewType: #BASIC
@EndUserText.label: 'Financial Statement Item - HierarchyNode'

define view I_GroupReportingFSItemHierNode
  as select from hrrp_node_n as _GRFSItemHierNode

  association [0..*] to I_FinStmntItmHierT         as _Text            on  $projection.FinancialStatementItemHier   = _Text.FinancialStatementItemHier
                                                                       and $projection.HierarchyNode                = _Text.HierarchyNode
                                                                       and $projection.ConsolidationChartOfAccounts = _Text.ConsolidationChartOfAccounts
                                                                       and $projection.FinancialStatementItem       = ''


  association [0..1] to I_GroupReportingFSItem     as _FinStmntItm     on  $projection.FinancialStatementItem       = _FinStmntItm.FinancialStatementItem
                                                                       and $projection.ConsolidationChartOfAccounts = _FinStmntItm.ConsolidationChartOfAccounts

  association [1..1] to I_CnsldtnFSItemHierarchy_2 as _Hierarchy       on  $projection.ConsolidationChartOfAccounts = _Hierarchy.ConsolidationChartOfAccounts
                                                                       and $projection.FinancialStatementItemHier   = _Hierarchy.CnsldtnFSItemHierarchy
                                                                       and $projection.ValidityEndDate              = _Hierarchy.ValidityEndDate

  association [0..1] to I_CnsldtnChartOfAccounts   as _ChartOfAccounts on  $projection.ConsolidationChartOfAccounts = _ChartOfAccounts.ConsolidationChartOfAccounts

{
      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
  key cast( left( _GRFSItemHierNode.nodecls, 2) as fc_itclg )                  as ConsolidationChartOfAccounts,

      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast( substring( _GRFSItemHierNode.hryid, 9, 10 ) as fc_ithry)           as FinancialStatementItemHier,

      @ObjectModel.text.association: '_Text'
  key _GRFSItemHierNode.hrynode                                                as HierarchyNode,

      @Consumption.filter: {mandatory : true, selectionType : #SINGLE, multipleSelections : false }
      @Semantics.businessDate.to: true
  key _GRFSItemHierNode.hryvalto                                               as ValidityEndDate,

      @Semantics.businessDate.from: true
      _GRFSItemHierNode.hryvalfrom                                             as ValidityStartDate,

      _GRFSItemHierNode.parnode                                                as ParentNode,

      cast('000000000000001' as fincs_hierarchyversion preserving type )       as HierarchyVersion,

      @ObjectModel.foreignKey.association: '_FinStmntItm'
      cast( left(_GRFSItemHierNode.leafvalue, 10) as fc_item preserving type ) as FinancialStatementItem,

      _GRFSItemHierNode.hryseqnbr                                              as HierarchyNodeSequence,
      _GRFSItemHierNode.hrylevel                                               as HierarchyNodeLevel,
      _GRFSItemHierNode.nodetype                                               as NodeType,

      //  CE2011 sign reversal

      @Semantics.signReversalIndicator: true
      cast ( _GRFSItemHierNode.sign as rr_rsign preserving type )              as SignIsInverted,


      _Text,
      _FinStmntItm,
      _Hierarchy,
      _ChartOfAccounts
}
where
       _GRFSItemHierNode.hrytyp   = 'CS15'
  and(
       _GRFSItemHierNode.nodetype = 'R'
    or _GRFSItemHierNode.nodetype = 'N'
    or _GRFSItemHierNode.nodetype = 'L'
  );
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_NODE_N"
],
"ASSOCIATED":
[
"I_CNSLDTNCHARTOFACCOUNTS",
"I_CNSLDTNFSITEMHIERARCHY_2",
"I_FINSTMNTITMHIERT",
"I_GROUPREPORTINGFSITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/