I_GLAcctInCoCode

@EndUserText.label: 'General Ledger Account in Company Code'
//@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}

@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IGLACOCD'
@ObjectModel.entityChangeStateId: 'LastChangeDateTime'
@ObjectModel.representativeKey: 'GLAccount'
@AbapCatalog.buffering.status: #NOT_ALLOWED
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass:  #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #CHECK
define view I_GLAcctInCoCode
  as select from           I_GLAccountInCompanyCode as skb1
    left outer to one join I_CompanyCode            as t001 on skb1.CompanyCode = t001.CompanyCode
  association [0..1] to I_CompanyCode                as _CompanyCode             on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..*] to I_GlAccountTextInCompanycode as _Text                    on  $projection.CompanyCode = _Text.CompanyCode
                                                                                 and $projection.GLAccount   = _Text.GLAccount
  association [1..1] to I_User                       as _User                    on  $projection.CreatedByUser = _User.UserID
  association [0..1] to I_Reconciliationaccttype     as _Reconciliationaccttype  on  $projection.ReconciliationAccountType = _Reconciliationaccttype.ReconciliationAccountType
  association [0..1] to I_InflationKey               as _InflationKey            on  $projection.Country            = _InflationKey.Country
                                                                                 and $projection.GLAcctInflationKey = _InflationKey.GLAcctInflationKey
  association [0..1] to I_JointVentureRecovery       as _JointVentureRecovery    on  $projection.CompanyCode              = _JointVentureRecovery.CompanyCode
                                                                                 and $projection.JointVentureRecoveryCode = _JointVentureRecovery.JointVentureRecoveryCode
  association [0..1] to I_MultiCurrencyAccounting    as _MultiCurrencyAccounting on  $projection.MultiCurrencyAccountingCode = _MultiCurrencyAccounting.MultiCurrencyAccountingCode
  association [0..1] to I_FieldStatusGroup           as _FieldStatusGroup        on  $projection.FieldStatusVariant = _FieldStatusGroup.FieldStatusVariant
                                                                                 and $projection.FieldStatusGroup   = _FieldStatusGroup.FieldStatusGroup
  association [0..1] to I_FieldStatusVariant         as _FieldStatusVariant      on  $projection.FieldStatusVariant = _FieldStatusVariant.FieldStatusVariant
  association [0..1] to I_TaxCategory                as _TaxCategory             on  $projection.CompanyCode = _TaxCategory.CompanyCode
                                                                                 and $projection.TaxCategory = _TaxCategory.TaxCategory
  association [0..1] to I_ChartOfAccounts            as _ChartOfAccounts         on  $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts
  association [0..1] to I_GLAcctInCoCodeImplementStat as _GLAcctInCoCodeStatus      on  $projection.CompanyCode  = _GLAcctInCoCodeStatus.CompanyCode
                                                                                  and $projection.GLAccount    = _GLAcctInCoCodeStatus.GLAccount  
{
      @ObjectModel.text.association: '_Text'
  key skb1.GLAccount                                                   as GLAccount,
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key skb1.CompanyCode                                                 as CompanyCode,
      skb1.AuthorizationGroup                                          as AuthorizationGroup,
      skb1.AccountingClerk                                             as AccountingClerk,
      skb1.LastInterestCalcRunDate                                     as LastInterestCalcRunDate,
      skb1.CreationDate                                                as CreationDate,
      skb1.CreatedByUser                                               as CreatedByUser,
      skb1.LastChangeDateTime                                          as LastChangeDateTime,
      skb1.PlanningLevel                                               as PlanningLevel,
      skb1.HouseBank                                                   as HouseBank,
      skb1.HouseBankAccount                                            as HouseBankAccount,
      skb1.ExchRateDifferencesAccountDetn                              as ExchRateDifferencesAccountDetn,
      @ObjectModel.foreignKey.association: '_Reconciliationaccttype'
      skb1.ReconciliationAccountType                                   as ReconciliationAccountType,
      @ObjectModel.foreignKey.association: '_TaxCategory'
      skb1.TaxCategory                                                 as TaxCategory,
      skb1.InterestCalculationCode                                     as InterestCalculationCode,
      skb1.GLAccountCurrency                                           as GLAccountCurrency,
      skb1.ReconciliationAcctIsChangeable                              as ReconciliationAcctIsChangeable,
      skb1.IsManagedExternally                                         as IsManagedExternally,
      skb1.IsAutomaticallyPosted                                       as IsAutomaticallyPosted,
      skb1.LineItemDisplayIsEnabled                                    as LineItemDisplayIsEnabled,
      skb1.SupplementIsAllowed                                         as SupplementIsAllowed,
      skb1.IsOpenItemManaged                                           as IsOpenItemManaged,
      skb1.InterestCalculationDate                                     as InterestCalculationDate,
      skb1.IntrstCalcFrequencyInMonths                                 as IntrstCalcFrequencyInMonths,
      skb1.AcctgDocItmDisplaySequenceRule                              as AcctgDocItmDisplaySequenceRule,
      skb1.AlternativeGLAccount                                        as AlternativeGLAccount,
      skb1.JointVentureRecoveryCode                                    as JointVentureRecoveryCode,
      skb1.CommitmentItem                                              as CommitmentItem,
      skb1.TaxCodeIsRequired                                           as TaxCodeIsRequired,
      skb1.BalanceHasLocalCurrency                                     as BalanceHasLocalCurrency,
      skb1.ValuationGroup                                              as ValuationGroup,
      skb1.APARToleranceGroup                                          as APARToleranceGroup,
      skb1.AccountIsBlockedForPosting                                  as AccountIsBlockedForPosting,
      skb1.AccountIsMarkedForDeletion                                  as AccountIsMarkedForDeletion,
      skb1.ClearingIsLedgerGroupSpecific                               as ClearingIsLedgerGroupSpecific,
//      skb1.CashPlanningGroup                                           as CashPlanningGroup,

      skb1.IsCashFlowAccount                                           as IsCashFlowAccount,
      skb1.GLAcctInflationKey                                          as GLAcctInflationKey,
      @ObjectModel.foreignKey.association: '_FieldStatusGroup'
      skb1.FieldStatusGroup                                            as FieldStatusGroup,
      skb1.MultiCurrencyAccountingCode                                 as MultiCurrencyAccountingCode,
      skb1.IsExtendedOpenItemManaged                                   as IsExtendedOpenItemManaged,
//      skb1._GLAcctInCoCodeImst.GLAcctCoCodeImplementStatus             as GLAcctCoCodeImplementStatus, 

//      skb1._GLAcctInCoCodeImst.GLAccountCoCodIsDeliveredBySAP          as GLAccountCoCodIsDeliveredBySAP,

      t001.Country                                                     as Country,
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
      t001.ChartOfAccounts                                             as ChartOfAccounts,
      t001.ControllingArea                                             as ControllingArea,
      @ObjectModel.foreignKey.association: '_FieldStatusVariant'
      t001.FieldStatusVariant                                          as FieldStatusVariant,
      t001.CountryChartOfAccounts                                      as CountryChartOfAccounts,
      _User,
      _CompanyCode,
      _Text,
      _InflationKey,
      _Reconciliationaccttype,
      _JointVentureRecovery,
      _MultiCurrencyAccounting,
      _FieldStatusGroup,
      _FieldStatusVariant,
      _TaxCategory,
      _ChartOfAccounts,
      _GLAcctInCoCodeStatus
};
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_GLACCOUNTINCOMPANYCODE"
],
"ASSOCIATED":
[
"I_CHARTOFACCOUNTS",
"I_COMPANYCODE",
"I_FIELDSTATUSGROUP",
"I_FIELDSTATUSVARIANT",
"I_GLACCOUNTTEXTINCOMPANYCODE",
"I_GLACCTINCOCODEIMPLEMENTSTAT",
"I_INFLATIONKEY",
"I_JOINTVENTURERECOVERY",
"I_MULTICURRENCYACCOUNTING",
"I_RECONCILIATIONACCTTYPE",
"I_TAXCATEGORY",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/