C_GLJrnlEntryItemToBeVerified

@AbapCatalog.sqlViewName: 'CGLJEIVER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.usageType.serviceQuality: #C
@VDM.viewType: #CONSUMPTION
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'LI in Inbox View of GL JE to be verified'
@Metadata: { ignorePropagatedAnnotations: true,
             allowExtensions: true }
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE]
define view C_GLJrnlEntryItemToBeVerified
  as select from    I_GLJrnlEntryItemToBeVerified
    left outer join I_GLAcctInCoCode             as _cocd on  I_GLJrnlEntryItemToBeVerified.CompanyCode = _cocd.CompanyCode
                                                          and I_GLJrnlEntryItemToBeVerified.GLAccount   = _cocd.GLAccount
    left outer join I_GLAccountInChartOfAccounts as _coa  on  I_GLJrnlEntryItemToBeVerified.GLAccount = _coa.GLAccount
                                                          and _cocd.ChartOfAccounts                   = _coa.ChartOfAccounts
  association [0..1] to I_DebitCreditCode as _DebitCreditCode on  $projection.DebitCreditCode = _DebitCreditCode.DebitCreditCode
  association [1..1] to I_CompanyCode     as _CompanyCode     on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_WBSElement      as _WBSElement      on  $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
  association [1..1] to I_JournalEntry    as _header          on  I_GLJrnlEntryItemToBeVerified.CompanyCode        = _header.CompanyCode
                                                              and I_GLJrnlEntryItemToBeVerified.FiscalYear         = _header.FiscalYear
                                                              and I_GLJrnlEntryItemToBeVerified.AccountingDocument = _header.AccountingDocument
{
      @UI.lineItem: {
        position:10,
        importance:#HIGH}
  key I_GLJrnlEntryItemToBeVerified.AccountingDocumentItem,
      @UI.hidden: true
  key I_GLJrnlEntryItemToBeVerified.SourceCompanyCode,
      @UI.hidden: true
  key I_GLJrnlEntryItemToBeVerified.FiscalYear,
      @UI.hidden: true
  key I_GLJrnlEntryItemToBeVerified.AccountingDocument,

      @UI.hidden: true
      I_GLJrnlEntryItemToBeVerified.AccountingDocumentCategory,

      @UI.lineItem:{
          position:20,
        importance:#HIGH }
      I_GLJrnlEntryItemToBeVerified.CompanyCode,

      @UI.lineItem: {
        position:30,
        importance:#HIGH}
      I_GLJrnlEntryItemToBeVerified.GLAccount,

      @UI.lineItem: {
        position:40,
        importance:#HIGH}
      cast( _cocd._Text[1:Language = $session.system_language].GLAccountName as fac_skat_txt20 ) as GLAccountName,

      @UI.lineItem: {
        position:50,
        importance:#HIGH}
      cast(I_GLJrnlEntryItemToBeVerified.DocumentItemText as fac_item_txt50)                     as DocumentItemText,



      @UI.hidden: true
      I_GLJrnlEntryItemToBeVerified.DebitCreditCode,

      @UI.lineItem: {
        position:60,
        importance:#HIGH}
      _DebitCreditCode._Text[1:Language = $session.system_language].DebitCreditCodeName          as DebitCreditCodeName,

      @Semantics.currencyCode: true
      I_GLJrnlEntryItemToBeVerified.TransactionCurrency,
      @UI.lineItem: {
        position:70,
        importance:#HIGH}
      @Semantics.amount.currencyCode:  'TransactionCurrency'
      I_GLJrnlEntryItemToBeVerified.AmountInTransactionCurrency,

      @Semantics.currencyCode: true
      _CompanyCode.Currency                                                                      as CompanyCodeCurrency,

      @UI.lineItem: {
        position:80,
        importance:#HIGH}
      @Semantics.amount.currencyCode:  'CompanyCodeCurrency'
      I_GLJrnlEntryItemToBeVerified.AmountInCompanyCodeCurrency,

      @Semantics.currencyCode: true
      I_GLJrnlEntryItemToBeVerified.GlobalCurrency,

      @UI.lineItem: {
        position:85,
        importance:#HIGH}
      @Semantics.amount.currencyCode:  'GlobalCurrency'
      I_GLJrnlEntryItemToBeVerified.AmountInGlobalCurrency,

      @Semantics.currencyCode: true
      I_GLJrnlEntryItemToBeVerified.FunctionalCurrency                                           as FunctionalCurrency, //FunctionalCurrency


      @UI.lineItem: {
        position:90,
        importance:#HIGH,
        label: 'Amount in Functional Currency'}
      @Semantics.amount.currencyCode:  'FunctionalCurrency'
      I_GLJrnlEntryItemToBeVerified.AmountInFunctionalCurrency, //Amount in functional currency


      @Semantics.currencyCode: true
      I_GLJrnlEntryItemToBeVerified.FreeDefinedCurrency1                                         as FreeDefinedCurrency1, //3rd FI currency


      @UI.lineItem: {
        position:95,
        importance:#HIGH}
      @Semantics.amount.currencyCode:  'FreeDefinedCurrency1'
      I_GLJrnlEntryItemToBeVerified.AmountInFreeDefinedCurrency1, //Amount in 3rd FI currency


      @UI.lineItem: {
        position:100,
        importance:#HIGH}
      I_GLJrnlEntryItemToBeVerified.ProfitCenter,
      @UI.lineItem: {
        position:110,
        importance:#HIGH}
      I_GLJrnlEntryItemToBeVerified.CostCenter,

      _coa.GLAccountGroup,

      I_GLJrnlEntryItemToBeVerified.WBSElementInternalID,

      @UI.lineItem: {
        position:120,
        importance:#HIGH}
      _WBSElement.WBSElement                                                                     as WBSElementExternalID,

      @UI.hidden: true
      _header.LedgerGroup
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPANYCODE",
"I_DEBITCREDITCODE",
"I_DEBITCREDITCODETEXT",
"I_GLACCOUNTINCHARTOFACCOUNTS",
"I_GLACCOUNTTEXTINCOMPANYCODE",
"I_GLACCTINCOCODE",
"I_GLJRNLENTRYITEMTOBEVERIFIED",
"I_JOURNALENTRY",
"I_WBSELEMENT"
],
"ASSOCIATED":
[
"I_COMPANYCODE",
"I_DEBITCREDITCODE",
"I_JOURNALENTRY",
"I_WBSELEMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/