I_FldLogsKitReceivableItem

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Kit Receivable Items'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
define view entity I_FldLogsKitReceivableItem
  as select from R_FldLogsKitMaintOrderItem
{
  key FieldLogisticsKitItemUUID,
  key FieldLogisticsKitHeaderUUID,
      FldLogsReferenceDocumentNumber,
      FldLogsKitItmRefDocument1,
      ItemDescription,
      FldLogsDelivIsHeldOnShore,
      RequirementDate,
      FldLogsKitPlannedDeliveryDate,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      Quantity,
      BaseUnit,
      cast('' as ebeln)                              as PurchaseOrder,
      cast ( '' as ebelp )                           as PurchaseOrderItem,
      MaintenanceOrder,
      PurchaseRequisition,
      hextobin( '00000000000000000000000000000000' ) as FldLogsContainerUnitUUID,
      Material,
      Reservation,
      ReservationItem,
      LastChangeDateTime,
      case
      when _MaintenanceOrderComponent.FldLogsSupplyProcess = 'SP15'
        then _RemotePlant.SupplyingPlant
      else FldLogsSrcePlnt
      end                                            as FldLogsSrcePlnt,
       @Semantics.booleanIndicator : true
      IsEndOfPurposeBlocked,
       cast ( '' as bwart)                            as GoodsMovementType,
      cast ( '' as mblnr)                            as MaterialDocument
}
union select from I_FldLogsKitRblPurrOrderItem
{
  key FieldLogisticsKitItemUUID,
  key FieldLogisticsKitHeaderUUID,
      FldLogsReferenceDocumentNumber,
      FldLogsKitItmRefDocument1,
      ItemDescription,
      case when _MaintenanceOrderComponent.FldLogsDelivIsHeldOnShore is initial or _MaintenanceOrderComponent.FldLogsDelivIsHeldOnShore is null
      then _SupplierItem.FldLogsIsWorkOrderOnHold
      else _MaintenanceOrderComponent.FldLogsDelivIsHeldOnShore end as FldLogsDelivIsHeldOnShore,
      _MaintenanceOrderComponent.RequirementDate,
      FldLogsKitPlannedDeliveryDate,
      Quantity,
      BaseUnit,
      PurchaseOrder,
      cast ( '' as ebelp )                                          as PurchaseOrderItem,
      case
       when AccountAssignmentCategory = 'F'
        then _PurOrdAccAssgmt.ProductionOrder
       else _MaintenanceOrderComponent.MaintenanceOrder
      end as MaintenanceOrder,
      PurchaseRequisition,
      _PurchaseOrderShipmentItem.FldLogsContainerUnitUUID,
      Material,
      _MaintenanceOrderComponent.Reservation,
      _MaintenanceOrderComponent.ReservationItem,
      LastChangeDateTime,
      FldLogsSrcePlnt,
      IsEndOfPurposeBlocked,
      cast ( '' as bwart)                                           as GoodsMovementType,
      cast ( '' as mblnr)                                           as MaterialDocument
}
where
         RefPurchaseRequisition                      is null
  or(
         RefPurchaseRequisition                      is not null
    and(
         _PurchaseRequisitionItem.PurchasingDocument is null
      or _PurchaseRequisitionItem.PurchasingDocument is initial
    )
  )
// (To handle SP13 scenario => STO -> PO)

// display STO until PO is created


union select from I_FldLogsKitMatlDocumentItem
association [1..1] to I_PurchaseOrderItem           as _PurchaseOrderItem    on  $projection.PurchaseOrder     = _PurchaseOrderItem.PurchaseOrder
                                                                             and $projection.PurchaseOrderItem = _PurchaseOrderItem.PurchaseOrderItem
association [1..1] to I_FldLogsKitRblPurMaintOrdDet as _KitRblPurMaintOrdDet on  $projection.PurchaseOrder     = _KitRblPurMaintOrdDet.PurchaseOrder
                                                                             and $projection.PurchaseOrderItem = _KitRblPurMaintOrdDet.FldLogsKitItmRefDocument2

{
  key FieldLogisticsKitItemUUID,
  key FieldLogisticsKitHeaderUUID,
      cast(concat(concat(PurchaseOrder, '/'),PurchaseOrderItem) as flog_doc)   as FldLogsReferenceDocumentNumber,
      cast ('' as flog_doc )                                                   as FldLogsKitItmRefDocument1,
      cast(_PurchaseOrderItem.PurchaseOrderItemText as maktx preserving type ) as ItemDescription,
      cast ( '' as flog_hold )                                                 as FldLogsDelivIsHeldOnShore,
      _KitRblPurMaintOrdDet._MaintenanceOrderComponent.RequirementDate         as RequirementDate,
      _KitRblPurMaintOrdDet.FldLogsKitPlannedDeliveryDate                      as FldLogsKitPlannedDeliveryDate,
      QuantityInBaseUnit                                                       as Quantity,
      OrderQuantityUnit                                                         as BaseUnit,
      PurchaseOrder,
      PurchaseOrderItem,
      _KitRblPurMaintOrdDet.MaintenanceOrder                                   as MaintenanceOrder,
      _PurchaseOrderItem.PurchaseRequisition,
      hextobin( '00000000000000000000000000000000' )                           as FldLogsContainerUnitUUID,
      Material,
      _KitRblPurMaintOrdDet._MaintenanceOrderComponent.Reservation             as Reservation,
      _KitRblPurMaintOrdDet._MaintenanceOrderComponent.ReservationItem         as ReservationItem,
      LastChangeDateTime,
      _KitRblPurMaintOrdDet.FldLogsSrcePlnt,
      _PurchaseOrderItem._PurchaseOrder.IsEndOfPurposeBlocked,
      GoodsMovementType,
      MaterialDocument

}
where
  (
    (
         GoodsMovementType          =  '103'
      or GoodsMovementType          =  '107'
    )
    and  FldLogsKitIsTwoStpGRCmpltd <> 'X'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHGIMPACTPURDOCACCTASSIGN",
"I_FLDLOGSKITMATLDOCUMENTITEM",
"I_FLDLOGSKITPURRORDERSHPTITEM",
"I_FLDLOGSKITRBLPURMAINTORDDET",
"I_FLDLOGSKITRBLPURRORDERITEM",
"I_FLDLOGSPLANTBASIC",
"I_FLDLOGSSUPPLIERITEM",
"I_MAINTENANCEORDERCOMPONENT",
"I_PURCHASEORDER",
"I_PURCHASEORDERITEM",
"I_PURCHASEREQUISITIONITEMBASIC",
"R_FLDLOGSKITMAINTORDERITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/