I_FLDLOGSKITRBLPURRORDERITEM

CDS View

Kit Receivable Purchase Order Items

I_FLDLOGSKITRBLPURRORDERITEM is a CDS View in S/4HANA. Kit Receivable Purchase Order Items. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_FldLogsKitReceivableItem view_entity union COMPOSITE Kit Receivable Items 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Kit Receivable Purchase Order Items'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #D,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
define view entity I_FldLogsKitRblPurrOrderItem
  as select from I_FldLogsKitPurchaseOrderItem
  association [0..1] to I_FldLogsKitPurrOrderShptItem  as _PurchaseOrderShipmentItem on  $projection.FldLogsReferenceDocumentNumber = _PurchaseOrderShipmentItem.FldLogsReferenceDocumentNumber
  //read PR based on STR, used to hide STO based on PO creation (ref : indirect link between PO and STO in case of SP13)

  association [0..1] to I_ExternalRefForPurgDoc        as _ExternalReference         on  $projection.PurchasingDocumentUniqueID = _ExternalReference.PurchasingDocumentUniqueID
                                                                                     and _ExternalReference.SAPObjectNodeType   = 'StockTransportRequisition'
                                                                                     and _ExternalReference.LinkType            = 'SS'
                                                                                     and _ExternalReference.SequenceNumber      = 1
  association [0..1] to I_PurchaseRequisitionItemBasic as _PurchaseRequisitionItem   on  $projection.RefPurchaseRequisition     = _PurchaseRequisitionItem.PurchaseRequisition
                                                                                     and $projection.RefPurchaseRequisitionItem = _PurchaseRequisitionItem.PurchaseRequisitionItem
  association [1]    to I_MaintenanceOrderComponent    as _MaintenanceOrderComponent on  $projection.MaintenanceOrder          = _MaintenanceOrderComponent.MaintenanceOrder
                                                                                     and $projection.MaintenanceOrderOperation = _MaintenanceOrderComponent.MaintenanceOrderOperation
                                                                                     and $projection.MaintenanceOrderComponent = _MaintenanceOrderComponent.MaintenanceOrderComponent
  association [1..1] to I_PurchasingDocument           as _PurchasingDocument        on  $projection.PurchaseOrder = _PurchasingDocument.PurchasingDocument

{
  key FieldLogisticsKitItemUUID,
  key FieldLogisticsKitHeaderUUID,
      FldLogsKitItmRefDocument1,
      FldLogsKitItmRefDocument2,
      FldLogsKitItmRefDocument1UUID,
      FldLogsReferenceDocumentNumber,
      ItemDescription,
      FldLogsKitPlannedDeliveryDate,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      cast((cast(OrderQuantity as abap.dec( 18, 3 )) - coalesce(_AggrgdQty.NumberOfReceivedParts, 0)) as abap.quan( 13, 3 )) as Quantity,
      PurchaseOrderQuantityUnit                                                                                              as BaseUnit,
      PurchaseOrder,
      PurchaseRequisition,
      PurchaseRequisitionItem,
      LastChangeDateTime,
      Material,
      PurchasingDocumentUniqueID,
      cast(substring( _ExternalReference.PurgDocExternalReference, 1, 10 ) as banfn)                                         as RefPurchaseRequisition, //  PR for an STR, is used to hide STO based on PO creation

      cast(substring( _ExternalReference.PurgDocExternalReference, 11, 15 ) as bnfpo)                                        as RefPurchaseRequisitionItem, // STR for an PR

      ParentObjectUUID,
      cast(_ParentNode.FldLogsKitItmRefDocument1 as abap.char(12))                                                           as MaintenanceOrder,
      cast(_ParentNode.FldLogsKitItmRefDocument2 as abap.char(4))                                                            as MaintenanceOrderOperation,
      cast(_ParentNode.FldLogsKitItmRefDocument3 as abap.char(4))                                                            as MaintenanceOrderComponent,
      case
      when _SupplierItem.FldLogsSuplrBasePlant is not initial
      then _SupplierItem.FldLogsSuplrBasePlant
      else FldLogsSrcePlnt
      end as FldLogsSrcePlnt,
      AccountAssignmentCategory,
      @Semantics.booleanIndicator : true
      _PurchasingDocument.IsEndOfPurposeBlocked,
      /* Associations */
      _AggrgdQty,
      _PurchaseOrderItem,
      _PurchaseOrderShipmentItem,
      _PurchaseRequisitionItem,
      _MaintenanceOrderComponent,
      _SupplierItem,
      _PurOrdAccAssgmt

}
where
  (
        _AggrgdQty.NumberOfReceivedParts          is null
    and _OutbDelivAggrgdQty.NumberOfReceivedParts is null
  )
  or(
        _AggrgdQty.NumberOfReceivedParts          is not null
    and OrderQuantity                             > _AggrgdQty.NumberOfReceivedParts
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EXTERNALREFFORPURGDOC",
"I_FIELDLOGISTICSKITITEM",
"I_FLDLOGSKITMATLDOCAGGRGDQTY",
"I_FLDLOGSKITOUTBDELIVAGGRGDQTY",
"I_FLDLOGSKITPURCHASEORDERITEM",
"I_FLDLOGSSUPPLIERITEM",
"I_PURCHASINGDOCUMENT"
],
"ASSOCIATED":
[
"I_CHGIMPACTPURDOCACCTASSIGN",
"I_FLDLOGSKITMATLDOCAGGRGDQTY",
"I_FLDLOGSKITPURRORDERSHPTITEM",
"I_FLDLOGSSUPPLIERITEM",
"I_MAINTENANCEORDERCOMPONENT",
"I_PURCHASEORDERITEM",
"I_PURCHASEREQUISITIONITEMBASIC"
],
"BASE":
[
"I_FLDLOGSKITPURCHASEORDERITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More