I_FinancialStatementHier

@AbapCatalog.sqlViewName: 'IFIGLACCHER'
@ObjectModel.representativeKey: 'FinancialStatementHierarchy'
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.buffering.status: #NOT_ALLOWED
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass:  #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Financial Statement Hierarchy'
//@VDM.viewType: #COMPOSITE

@VDM.viewType: #BASIC
@Metadata.allowExtensions:true
@Search.searchable: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #ANALYTICAL_DIMENSION, #EXTRACTION_DATA_SOURCE]
//@ObjectModel.representativeKey: 'HierarchyVersion'

@Analytics:{
    dataCategory: #DIMENSION,
    dataExtraction: {
        enabled: true
    }
}
define view I_FinancialStatementHier
  as select from hrrp_dir_n
  association [0..*] to I_FinancialStatementHierT as _Text on  $projection.FinancialStatementHierarchy = _Text.FinancialStatementHierarchy
                                                           and $projection.ValidityEndDate             = _Text.ValidityEndDate
{
      @ObjectModel.text.association: '_Text'
      @Search.defaultSearchElement:true
      @Search.fuzzinessThreshold:0.8
      @Search.ranking:#HIGH
  key hrrp_dir_n.hryid_42                                     as FinancialStatementHierarchy,
      @Semantics.businessDate.to: true
  key cast(hrrp_dir_n.hryvalto as fis_datbi preserving type ) as ValidityEndDate,
      @Semantics.businessDate.from: true
      case when hrrp_dir_n.hrysource = 'UH'
           then hrrp_dir_n.hryvalfrom  //for FSV from Global Hierarchy

           else cast( '19000101' as fis_datab ) end           as ValidityStartDate, //always set valid from as 19000101 for FSV from OB58

      hrrp_dir_n.hrytyp                                       as HierarchyType,
      @Semantics.user.lastChangedBy: true
      hrrp_dir_n.upduser                                      as LastChangedByUser,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'LastChangeDateTime'
      @VDM.lifecycle.status:     #DEPRECATED
      @VDM.lifecycle.successor:  'LastChangeDateTime'
      //@Semantics.systemDate.lastChangedAt: true

      hrrp_dir_n.updtime                                      as LastChangeTime,
      @Semantics.systemDateTime.lastChangedAt: true
      hrrp_dir_n.updtime                                      as LastChangeDateTime,
      _Text,
      cast( hrrp_dir_n.ktopl as char80 )                      as ChartOfAccounts,
      cast( hrrp_dir_n.aktva as char80 )                      as FinancialStatementAssetsItem,
      cast( hrrp_dir_n.pssva as char80 )                      as FinStatementLiabilitiesItem,
      cast( hrrp_dir_n.ergak as char80 )                      as FinancialStatementNetLossItem,
      cast( hrrp_dir_n.ergpa as char80 )                      as FinStatementNetProfitItem,
      cast( hrrp_dir_n.erggv as char80 )                      as FinStatementProfitAndLossItem,
      cast( hrrp_dir_n.zuord as char80 )                      as FinancialStatementOrphansItem,
      cast( hrrp_dir_n.anhng as char80 )                      as FinancialStatementNotesItem,
      cast( hrrp_dir_n.xergs as char80 )                      as GroupChartOfAccountIsUsed,
      cast( hrrp_dir_n.funareaassigned as char80 )            as FunctionalAreaIsUsed
}
where
       hrrp_dir_n.hrytyp            =    'FSVN'
  and  not hrrp_dir_n.hryid         like '0109/%'
  and  not hrrp_dir_n.hryid         like '0102/%'
  and  not hrrp_dir_n.hryid         like 'H109/%'
  and(
       hrrp_dir_n.hryvalto          =    '99991231'
    or hrrp_dir_n.hrysource         =    'UH'
  )
  and  hrrp_dir_n.aging             =    ''
  and  hrrp_dir_n.banksplitassigned =    ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_DIR_N"
],
"ASSOCIATED":
[
"I_FINANCIALSTATEMENTHIERT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/