C_CO_UGPPFinStmntStructure

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Colombia UGPP Fin Statement structure'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  dataClass: #MIXED,
  serviceQuality: #D,
  sizeCategory: #L
}
@VDM.viewType: #CONSUMPTION

define view entity C_CO_UGPPFinStmntStructure
  with parameters
    @EndUserText.label: 'Financial Statement Version'
    P_FinancialStatementVersion : versn_011

  as select from           I_CO_GLAccountHierarchy(
                              P_FinancialStatementVersion: $parameters.P_FinancialStatementVersion ) as GLAccountHierarchy

    inner join             I_FinancialStatementHier                                                  as Hierarchy on  Hierarchy.FinancialStatementHierarchy = GLAccountHierarchy.FinancialStatementHierarchy
                                                                                                                  and Hierarchy.ValidityEndDate             = GLAccountHierarchy.ValidityEndDate

    left outer to one join I_GLAccountHierarchyNodeT                                                 as NodeText  on  NodeText.GLAccountHierarchy = Hierarchy.FinancialStatementHierarchy
                                                                                                                  and NodeText.HierarchyNode      = GLAccountHierarchy.HierarchyNode
                                                                                                                  and NodeText.ValidityEndDate    = GLAccountHierarchy.ValidityEndDate
                                                                                                                  and NodeText.Language           = $session.system_language
                                                                                                                  and GLAccountHierarchy.NodeType = 'N'

    left outer to one join I_GLAccountText                                                                        on  I_GLAccountText.ChartOfAccounts = GLAccountHierarchy.ChartOfAccounts
                                                                                                                  and I_GLAccountText.GLAccount       = GLAccountHierarchy.HierarchyNodeVal
                                                                                                                  and I_GLAccountText.Language        = $session.system_language
                                                                                                                  and GLAccountHierarchy.NodeType     = 'L'
{
  key GLAccountHierarchy.FinancialStatementHierarchy       as FinancialStatementHierarchy,
  key GLAccountHierarchy.HierarchyNode                     as HierarchyNode,
  key GLAccountHierarchy.ValidityEndDate                   as ValidityEndDate,
      GLAccountHierarchy.ValidityStartDate                 as ValidityStartDate,

      cast( left( case
                    when GLAccountHierarchy.ChartOfAccounts is initial
                    then Hierarchy.ChartOfAccounts
                    else GLAccountHierarchy.ChartOfAccounts
                  end , 4 ) as fis_ktopl preserving type ) as ChartOfAccounts,

      GLAccountHierarchy.HierarchyNodeVal                  as HierarchyNodeVal,
      GLAccountHierarchy.HierarchyNodeLevel                as HierarchyNodeLevel,
      GLAccountHierarchy.GLAccount                         as GLAccount,

      case
        when GLAccountHierarchy.NodeType = 'N'
        then NodeText.HierarchyNodeText
        else I_GLAccountText.GLAccountLongName
      end                                                  as HierarchyNodeText,

      GLAccountHierarchy.NodeType                          as FinancialStatementNodeType,
      GLAccountHierarchy.HierarchyRank                     as CO_UGPPStartingHierarchyRank,

      case
        when GLAccountHierarchy.NodeType = 'L'
        then GLAccountHierarchy.HierarchyRank
        else (GLAccountHierarchy.HierarchyRank + GLAccountHierarchy.HierarchyTreeSize)
      end                                                  as CO_UGPPEndingHierarchyRank
}
where
       GLAccountHierarchy.HierarchyNode <> '00NOTASSGND'
  and  GLAccountHierarchy.ParentNode    <> '00NOTASSGND'
  and(
       GLAccountHierarchy.NodeType      =  'N' -- Normal non-leaf node
    or GLAccountHierarchy.NodeType      =  'L' -- Normal leaf node
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CO_GLACCOUNTHIERARCHY",
"I_FINANCIALSTATEMENTHIER",
"I_GLACCOUNTHIERARCHYNODET",
"I_GLACCOUNTTEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/