I_EngmntProjectWithRoleAssgmt

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IENGPRJWROLASGMT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@AccessControl.personalData.blockingIndicator: 'IsBusinessPurposeCompleted'
@ObjectModel.representativeKey: 'ProjectRoleType'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION,
                            #CDS_MODELING_ASSOCIATION_TARGET,
                            #CDS_MODELING_DATA_SOURCE,
                            #SQL_DATA_SOURCE]

@EndUserText.label: 'Engagement Project With Roles'
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions:true

define view I_EngmntProjectWithRoleAssgmt
  as select from P_EngmntProjectRoleAssgmt as B
    inner join   P_WFPersonIdentification  as C on B.BusinessPartner = C.BusinessPartner
  association [0..1] to I_BusinessUserBasic         as _BusinessUser      on  $projection.BusinessPartner = _BusinessUser.BusinessPartner
  association [0..1] to I_BusinessPartner           as _BusinessPartner   on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_WorkplaceAddress          as _WorkplaceAddress  on  $projection.BusinessPartnerUUID = _WorkplaceAddress.BusinessPartnerUUID
  association [0..1] to I_WorkforcePersonImageURL   as _Image             on  _Image.Person = B.BusinessPartner
  association [0..1] to I_EnterpriseProjectRoleType as _ProjectRole       on  $projection.ProjectRoleType = _ProjectRole.ProjectRoleType
  association [1]    to I_EngagementProject         as _EngagementProject on  $projection.EngagementProject = _EngagementProject.EngagementProject
  association [0..1] to I_PPM_ProjectRoleTypeText   as _ProjectRoleText   on  _ProjectRoleText.LanguageCode    = $session.system_language
                                                                          and _ProjectRoleText.ProjectRoleType = $projection.ProjectRoleType
  association [1..1] to I_EngmntProjWithUserInvlmnt as _MyProjects        on  $projection.EngagementProjectUUID = _MyProjects.ProjectUUID
{

      @ObjectModel.foreignKey.association: '_EngagementProject'
      @EndUserText.label: 'Engagement Project ID'
  key B.EngagementProject,

      @EndUserText.label: 'Project Role'
  key B.EngagementProjectTeamRole as ProjectRoleType,

      @EndUserText.label: 'Created On'
      B.CreationDateTime,

      @ObjectModel.foreignKey.association: '_BusinessPartner'
      @EndUserText.label: 'Business Partner ID'
      B.BusinessPartner,

      @EndUserText.label: 'Project Role Name'
      @Semantics.name.jobTitle: true
      _ProjectRoleText.ObjectName,

      @Consumption.hidden: true
      B.EngagementProjectUUID,

      @Consumption.hidden: true
      B.EngagementProjectTeamRoleUUID,

      @Consumption.hidden: true
      B.EngmtProjTeamMemberUUID,

      @Consumption.hidden: true
      B.EngagementProjectMemberUUID,

      @Consumption.hidden: true
      B.BusinessPartnerUUID,

      @EndUserText.label: 'Business Partner Name'
      B.BusinessPartnerFullName,

      @EndUserText.label: 'Business Partner Type'
      B.BusinessPartnerType,
      
      @EndUserText.label: 'Business User'  
      _BusinessUser.UserID, //  as BusinessUser,


      @EndUserText.label: 'User name'
      C.BPIdentificationNumber    as PersonExternalID,

      _BusinessUser,
      _Image,
      _ProjectRole,
      _ProjectRoleText,
      _EngagementProject,
      _WorkplaceAddress,
      _BusinessPartner,
      _MyProjects

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSUSERBASIC",
"I_PPM_PROJECTROLETYPETEXT",
"P_ENGMNTPROJECTROLEASSGMT",
"P_WFPERSONIDENTIFICATION"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_BUSINESSUSERBASIC",
"I_ENGAGEMENTPROJECT",
"I_ENGMNTPROJWITHUSERINVLMNT",
"I_ENTERPRISEPROJECTROLETYPE",
"I_PPM_PROJECTROLETYPETEXT",
"I_WORKFORCEPERSONIMAGEURL",
"I_WORKPLACEADDRESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/