I_DocInfoRecdAttchDetForBusObj

@AbapCatalog.sqlViewName: 'ICVOBJFILES'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #S, dataClass: #TRANSACTIONAL }
@VDM.viewType:#COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Documents with files for Business Object'

define view I_DocInfoRecdAttchDetForBusObj
  as select from     I_DocumentInfoRecordAttachment as Attachment


    right outer join I_DocInfoRecdObjTypeToDocType  as _DocType on Attachment.DocumentInfoRecordDocType = _DocType.DocumentInfoRecordDocType

  -- Association to get the Description of the attachment    
  association [1] to I_DocumentInfoRecordLgclDocID as AttachmentDescr on  Attachment.LogicalDocument = AttachmentDescr.LogicalDocument
                                                                      and AttachmentDescr.Language   = $session.system_language
        
  -- Association to get the Description of the DIRs
  association [1..1] to I_DocumentInfoRecordCntntMgmt as _Document         on  $projection.DocumentInfoRecordDocType    = _Document.DocumentInfoRecordDocType
                                                                           and $projection.DocumentInfoRecordDocPart    = _Document.DocumentInfoRecordDocPart
                                                                           and $projection.DocumentInfoRecordDocNumber  = _Document.DocumentInfoRecordDocNumber
                                                                           and $projection.DocumentInfoRecordDocVersion = _Document.DocumentInfoRecordDocVersion

  association [0..*] to I_DocumentInfoRecordDocTypeT  as _DocumentTypeText on  $projection.DocumentInfoRecordDocType = _DocumentTypeText.DocumentInfoRecordDocType


  association [1..1] to I_DocumentInfoRecord as _DocInfo on   $projection.DocumentInfoRecordDocType       = _DocInfo.DocumentInfoRecordDocType
                                                        and   $projection.DocumentInfoRecordDocPart       = _DocInfo.DocumentInfoRecordDocPart
                                                        and   $projection.DocumentInfoRecordDocNumber     = _DocInfo.DocumentInfoRecordDocNumber
                                                        and   $projection.DocumentInfoRecordDocVersion    = _DocInfo.DocumentInfoRecordDocVersion
{

  key _DocType.DocumentInfoRecordDocType      as  DocumentInfoRecordDocType,
  key Attachment.DocumentInfoRecordDocNumber  as  DocumentInfoRecordDocNumber,
  key Attachment.DocumentInfoRecordDocVersion as  DocumentInfoRecordDocVersion,
  key Attachment.DocumentInfoRecordDocPart    as  DocumentInfoRecordDocPart,
 

  
  @Consumption.hidden: true
  key Attachment.DocumentIndex as DocumentIndex,
  @Consumption.hidden: true
  key Attachment.FileUUID as FileUUID,
  key Attachment.PhysicalDocument as PhysicalDocument,
  key _DocType.LinkedSAPObject as  LinkedSAPObject,
  

      @EndUserText: {
           label: 'File Name'
         }
      Attachment.FileName                     as  FileName, 
      AttachmentDescr.FileDescription         as  FileDescription,
      Attachment.WorkstationApplication       as  WorkstationApplication,

      _Document.DocumentDescription           as  DocumentDescription,
      //concatenated DIR key 

      _DocInfo.DocumentInfoRecord             as  DocumentInfoRecord, 

      //associations

      _DocumentTypeText,
      _Document,
      _DocInfo

}
where
  Attachment.DocumentInfoRecordDocNumber <> ' ' and
  _DocInfo.DocInfoRecdIsMarkedForDeletion <>  'X'
//associastions

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_DOCINFORECDOBJTYPETODOCTYPE",
"I_DOCUMENTINFORECORD",
"I_DOCUMENTINFORECORDATTACHMENT",
"I_DOCUMENTINFORECORDCNTNTMGMT",
"I_DOCUMENTINFORECORDLGCLDOCID"
],
"ASSOCIATED":
[
"I_DOCUMENTINFORECORD",
"I_DOCUMENTINFORECORDCNTNTMGMT",
"I_DOCUMENTINFORECORDDOCTYPET",
"I_DOCUMENTINFORECORDLGCLDOCID"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/