I_DFS_OrganizationalMeasure

@AbapCatalog.sqlViewName: 'IORGM'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.representativeKey: 'DfsOrglMeasureUUID'
@ObjectModel.semanticKey: ['CaseID']
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@EndUserText.label: 'Organizational Measure (for User)'
define view I_DFS_OrganizationalMeasure
  as select from I_CaseAttribute          as _CaseAttribute
    inner join   I_WorkflowTaskApplObject as TaskApplicationObject on _CaseAttribute.CaseUniqueID = TaskApplicationObject.TechnicalWrkflwObject
    
  association [1..1] to I_WorkflowTask              as _WorkflowTask                 on  TaskApplicationObject.WorkflowTaskInternalID = _WorkflowTask.WorkflowTaskInternalID
  association [1..1] to I_DFS_MeasureAttributes     as _MeasureAttributes            on  $projection.DfsOrglMeasureUUID = _MeasureAttributes.DfsOrglMeasureUUID
  association [0..1] to I_UserContactCard           as _ResponsiblePerson        on  $projection.DfsOrglMeasureResponsible = _ResponsiblePerson.ContactCardID
  association [0..1] to I_FrcElmntOrgSuplmntyAttrib as _FrcElmntSuplmntyAttribAssgmt on  $projection.dfsorglmeasureheaderid                    = _FrcElmntSuplmntyAttribAssgmt.ForceElementOrgID
                                                                                     and _FrcElmntSuplmntyAttribAssgmt.FrcElmntOrgLanguage = $session.system_language
  association [1..1] to I_FrcElmntOrg as _FrcElmntOrg on  $projection.dfsorglmeasureheaderid = _FrcElmntOrg.ForceElementOrgID
{
  key CaseUniqueID as DfsOrglMeasureUUID,
  
      CaseType,
      'Organizational Measure'                                                       as DfsOrglMeasureCategoryText,

      CaseID,
      CaseExternalReference,
      CaseCreatedBy,
      cast( CaseCreatedOn as tzntstmps preserving type )        as CreationDateTime,
      CaseLastChangedBy,
      cast( CaseLastChangedOn as tzntstmps preserving type )    as LastChangeDateTime,
      CaseClosedBy,
      cast( CaseClosedTime as tzntstmps preserving type )       as CloseDateTime,
      CaseProcessor,
      CaseResponsible                                           as DfsOrglMeasureResponsible,
      CaseTitle                                                 as DfsOrglMeasureDescription,
      CaseAuthorizationLevel,
      
      CaseStatus,
      _CaseAttribute._Individual._Text[1:Language = $session.system_language].CaseStatusName,

      case
        when( CaseStatus = '10') then 2  //In Preperation    

        when( CaseStatus = '20') then 0  //In Process

        when( CaseStatus = '30') then 3   //Partly active

        when( CaseStatus = '40') then 3   //Active

        when( CaseStatus = '50') then 1   //Withdrawn        

      end                                                                            as StatusCriticality,

      CaseSystemStatus,
      CaseStatusObjectNumber,
      CaseSystemStatusName,
      CaseUserStatusName,
      CaseReason,

      TaskApplicationObject.WorkflowTaskInternalID,


       _MeasureAttributes.DfsOrglMeasureHeaderType,
       _MeasureAttributes.DfsOrglMeasureHeaderID,
       _MeasureAttributes._MeasureType._Text[1:Language = $session.system_language].DfsOrglMeasureTypeText,
       _MeasureAttributes.DfsOrglMeasureType,
       _MeasureAttributes.DfsOrglMsrEffectivenessDate,
       
       
      _Reasons,
      _CaseSystemStatus,
      _CaseEntity,
      _CaseTypes,
      _WorkflowTask,
      _MeasureAttributes,
      _ResponsiblePerson,

      _FrcElmntSuplmntyAttribAssgmt,
      _FrcElmntOrg
}
where
         CaseType                              = 'DFP1'
  and(
         CaseStatus                            = '20'
    or   CaseStatus                            = '25'
  )
  and(
         _WorkflowTask.WorkflowTaskCurrentUser = $session.user
    and(
         _WorkflowTask.WorkflowTaskStatus      = 'STARTED'
      or _WorkflowTask.WorkflowTaskStatus      = 'SELECTED'
      or _WorkflowTask.WorkflowTaskStatus      = 'COMMITTED'
    )
    and(
         _WorkflowTask.WorkflowTaskDefinition  = 'TS78907914'
      or _WorkflowTask.WorkflowTaskDefinition  = 'TS78907915'
    )
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CASEATTRIBUTE",
"I_CASEINDIVIDUALSTATUS",
"I_CASEINDIVIDUALSTATUSTEXT",
"I_DFS_MEASUREATTRIBUTES",
"I_DFS_MEASURETYPE",
"I_DFS_MEASURETYPETEXT",
"I_WORKFLOWTASK",
"I_WORKFLOWTASKAPPLOBJECT"
],
"ASSOCIATED":
[
"I_CASEENTITY",
"I_CASEREASONS",
"I_CASESYSTEMSTATUS",
"I_CASETYPES",
"I_DFS_MEASUREATTRIBUTES",
"I_FRCELMNTORG",
"I_FRCELMNTORGSUPLMNTYATTRIB",
"I_USERCONTACTCARD",
"I_WORKFLOWTASK"
],
"BASE":
[
"I_CASEATTRIBUTE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/