I_CASEATTRIBUTE

@AbapCatalog.sqlViewName: 'ICASEATTRIBUTE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Case Attribute'
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'CaseUniqueID'
//@Metadata.ignorePropagatedAnnotations

//@ClientHandling.algorithm:#SESSION_VARIABLE

@ObjectModel.supportedCapabilities
@AbapCatalog.preserveKey:true 
@ObjectModel.usageType.serviceQuality:#A
@ObjectModel.usageType.sizeCategory:#M  
@ObjectModel.usageType.dataClass:#TRANSACTIONAL

define view I_CaseAttribute
  as select from scmg_t_case_attr


  association [0..1] to I_Caseentity             as _CaseEntity       on  $projection.CaseUniqueID = _CaseEntity.CaseUniqueID

  association [0..1] to I_Casetypes              as _CaseTypes        on  $projection.CaseType = _CaseTypes.CaseType

  //  association [0..1] to I_Acmusr02               as _Usr02            on  $projection.CaseCreatedBy     = _Usr02.bname

  //                                                                      and $projection.CaseLastChangedBy = _Usr02.bname

  //                                                                      and $projection.CaseProcessor     = _Usr02.bname

  //                                                                      and $projection.CaseResponsible   = _Usr02.bname


  association [0..1] to I_CaseEscalationReason   as _Escalation       on  $projection.CaseEscalationReason = _Escalation.CaseEscalationReason

  association [0..1] to I_CaseCategory           as _Catego           on  $projection.CaseCategory = _Catego.CaseCategory
                                                                      and $projection.CaseType     = _Catego.CaseType

  association [0..1] to I_CasePriority           as _Priority         on  $projection.CasePriority = _Priority.CasePriority

  association [0..1] to I_Caseauthorizationlevel as _AuthLevel        on  $projection.CaseAuthorizationLevel = _AuthLevel.CaseAuthorizationLevel

  association [0..1] to I_CaseStatusProfile      as _StatProfile      on  $projection.CaseStatusProfile = _StatProfile.CaseStatusProfile

  association [0..1] to I_Caseindividualstatus   as _Individual       on  $projection.CaseStatus        = _Individual.CaseStatus
                                                                      and $projection.CaseStatusProfile = _Individual.CaseStatusProfile

  association [0..1] to I_CaseSystemStatus       as _CaseSystemStatus on  $projection.CaseSystemStatus = _CaseSystemStatus.CaseSystemStatus

  association [0..1] to I_CaseReasons            as _Reasons          on  $projection.CaseReason = _Reasons.CaseReason
                                                                      and $projection.CaseType   = _Reasons.CaseType
{
      @ObjectModel.foreignKey.association: '_CaseEntity'
  key scmg_t_case_attr.case_guid                as CaseUniqueID,
      @ObjectModel.foreignKey.association: '_CaseTypes'
      scmg_t_case_attr.case_type                as CaseType,
      scmg_t_case_attr.ext_key                  as CaseID,
      scmg_t_case_attr.ext_ref                  as CaseExternalReference,
      // @ObjectModel.foreignKey.association: '_Usr02'

      scmg_t_case_attr.created_by               as CaseCreatedBy,
      //@Semantics.dateTime:true

      scmg_t_case_attr.create_time              as CaseCreatedOn,
      //  @ObjectModel.foreignKey.association: '_Usr02'

      scmg_t_case_attr.changed_by               as CaseLastChangedBy,
      //@Semantics.dateTime:true

      scmg_t_case_attr.change_time              as CaseLastChangedOn,
      // @ObjectModel.foreignKey.association: '_Usr02'

      scmg_t_case_attr.closed_by                as CaseClosedBy,
      //@Semantics.dateTime:true

      scmg_t_case_attr.closing_time             as CaseClosedTime,
      scmg_t_case_attr.plan_end_date            as CasePlannedCloseDate,
      // @ObjectModel.foreignKey.association: '_Usr02'

      scmg_t_case_attr.processor                as CaseProcessor,
      scmg_t_case_attr.responsible              as CaseResponsible,
      scmg_t_case_attr.case_title               as CaseTitle,
      @ObjectModel.foreignKey.association: '_Escalation'
      scmg_t_case_attr.escal_reason             as CaseEscalationReason,
      scmg_t_case_attr.category                 as CaseCategory,
      @ObjectModel.foreignKey.association: '_Priority'
      scmg_t_case_attr.priority                 as CasePriority,
      scmg_t_case_attr.secure_level             as CaseAuthorizationLevel,
      @ObjectModel.foreignKey.association: '_StatProfile'
      scmg_t_case_attr.profile_id               as CaseStatusProfile,
      scmg_t_case_attr.stat_orderno             as CaseStatus,
      @ObjectModel.foreignKey.association: '_CaseSystemStatus'
      scmg_t_case_attr.stat_para                as CaseSystemStatus,

      scmg_t_case_attr.stat_objnr               as CaseStatusObjectNumber,
      scmg_t_case_attr.stat_line                as CaseSystemStatusName,
      scmg_t_case_attr.stat_user_line           as CaseUserStatusName,

      @ObjectModel.foreignKey.association: '_Reasons'
      scmg_t_case_attr.reason_code              as CaseReason,
      _CaseTypes,
      // _Usr02,

      _Priority,
      _StatProfile,
      _Individual,
      _CaseSystemStatus,
      _Catego,
      _AuthLevel,
      _Escalation,
      _CaseEntity,
      _Reasons


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"SCMG_T_CASE_ATTR"
],
"ASSOCIATED":
[
"I_CASEAUTHORIZATIONLEVEL",
"I_CASECATEGORY",
"I_CASEENTITY",
"I_CASEESCALATIONREASON",
"I_CASEINDIVIDUALSTATUS",
"I_CASEPRIORITY",
"I_CASEREASONS",
"I_CASESTATUSPROFILE",
"I_CASESYSTEMSTATUS",
"I_CASETYPES"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/