I_CustomerChangeLog

@AbapCatalog.sqlViewName: 'ICUSTOMERCHNGLOG'
@EndUserText.label: 'Customer change log'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #COMPOSITE
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
define view I_CustomerChangeLog
  as select from I_ChangeDocumentItem
    inner join   I_Customer on I_ChangeDocumentItem.ChangeDocObject = I_Customer.Customer
{
  key I_Customer.Customer,
  key I_ChangeDocumentItem.ChangeDocument,
  key I_ChangeDocumentItem.DatabaseTable,
  key I_ChangeDocumentItem.ChangeDocTableKey,
  key I_ChangeDocumentItem.ChangeDocDatabaseTableField,
  key I_ChangeDocumentItem.ChangeDocItemChangeType,

      cast (I_ChangeDocumentItem._ChangeDocument.CreationDate as fis_udate)      as ChangeDocCreationDate,
      cast(I_ChangeDocumentItem._ChangeDocument.CreatedByUser as lcm_changed_by) as LastChangedByUser,
      @EndUserText.label: 'New Field Value'
      I_ChangeDocumentItem.ChangeDocNewFieldValue,
      @EndUserText.label: 'Old Field Value'
      I_ChangeDocumentItem.ChangeDocPreviousFieldValue,
      @EndUserText.label: 'New Unit'
      I_ChangeDocumentItem.ChangeDocNewUnit,
      @EndUserText.label: 'Old Unit'
      I_ChangeDocumentItem.ChangeDocPreviousUnit,
      @EndUserText.label: 'New Currency'
      I_ChangeDocumentItem.ChangeDocNewCurrency,
      @EndUserText.label: 'Old Currency'
      I_ChangeDocumentItem.ChangeDocPreviousCurrency,

      I_Customer.CustomerName,
      I_Customer.BPCustomerName,
      I_Customer.CustomerAccountGroup,
      I_Customer.CreatedByUser,
      I_Customer.CreationDate,
      I_Customer.DeliveryIsBlocked,
      I_Customer.PostingIsBlocked,
      I_Customer.BillingIsBlockedForCustomer,
      I_Customer.OrderIsBlockedForCustomer,
      I_Customer.IsBusinessPurposeCompleted,
      I_Customer.IsOneTimeAccount,
      I_Customer.CityName,
      I_Customer.BPAddrCityName,
      I_Customer.Country,
      I_Customer.AuthorizationGroup,
      I_Customer.DeletionIndicator,
      I_Customer.AlternativePayerAccount,
      I_Customer.AlternativePayeeIsAllowed,
      @ObjectModel.foreignKey.association:'_CustomerClassification'
      I_Customer.CustomerClassification,
      //Adding 10 fields for DCP 10+1 development 

      @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController1,
       @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController2,
       @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController3,
       @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController4,
       @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController5,
       @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController6,
       @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController7,
       @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController8,
       @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController9,
       @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController10,
       @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataControllerSet,

      I_ChangeDocumentItem.ChangeDocObjectClass,

      I_Customer._CustomerClassification
}
where
  I_ChangeDocumentItem.ChangeDocObjectClass = 'DEBI'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEDOCUMENT",
"I_CHANGEDOCUMENTITEM",
"I_CUSTOMER"
],
"ASSOCIATED":
[
"I_CUSTOMERCLASSIFICATION"
],
"BASE":
[
"I_CUSTOMER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/