I_CostCtrActivityTypeHierNodeT

@AbapCatalog.sqlViewName: 'IFCOSTCTRACTYHNT'
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'HierarchyNode'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@Metadata.ignorePropagatedAnnotations:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL
}
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #LANGUAGE_DEPENDENT_TEXT, #EXTRACTION_DATA_SOURCE]
@AbapCatalog.compiler.compareFilter:true
@AbapCatalog.preserveKey:true
@Analytics.dataExtraction: {enabled:true}
@EndUserText.label: 'CostCtr Activty Type Hierarchy Node - Text'
define view I_CostCtrActivityTypeHierNodeT
  as select from hrrp_nodet_n


  //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

  association [0..1] to I_ControllingArea              as _ControllingAreaText on  $projection.ControllingArea = _ControllingAreaText.ControllingArea
  // ]--GENERATED

  association [0..1] to I_ControllingArea              as _ControllingArea     on  $projection.ControllingArea = _ControllingArea.ControllingArea

  association [0..1] to I_Language                     as _Language            on  $projection.Language = _Language.Language

  association [1..*] to I_CostCtrActivityTypeHierarchy as _Hierarchy           on  $projection.CostCtrActivityTypeHierarchy = _Hierarchy.CostCtrActivityTypeHierarchy
                                                                               and $projection.ControllingArea              = _Hierarchy.ControllingArea

{
      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ControllingAreaStdVH',
                     element: 'ControllingArea' }
        }]
      @ObjectModel.text.association: '_ControllingAreaText'
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_ControllingArea'
  key cast( hrrp_nodet_n.kokrs as fis_kokrs preserving type )          as ControllingArea,
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast(hrrp_nodet_n.hryid as fis_hryid_cctracttytpe preserving type ) as CostCtrActivityTypeHierarchy,
      @ObjectModel.text.element: 'HierarchyNodeText'
  key hrrp_nodet_n.hrynode                               as HierarchyNode,
      @Semantics.businessDate.to: true
  key hrrp_nodet_n.hryvalto                              as ValidityEndDate,
      @Semantics.language: true
  key hrrp_nodet_n.spras                                 as Language,
      @Semantics.text: true
      hrrp_nodet_n.nodetxt                               as HierarchyNodeText,
      @Semantics.text: true
      substring(hrrp_nodet_n.nodetxt, 1, 20)             as HierarchyNodeShortText,

      @Semantics.businessDate.from: true
      hrrp_nodet_n.hryvalfrom                            as ValidityStartDate,
      _ControllingArea,
      _Language,
      _Hierarchy,
      //--[ GENERATED:012:29JlHNUf7jY4ioM8lnJMdG

      @Consumption.hidden: true
      _ControllingAreaText
      // ]--GENERATED


}
where
  hrrp_nodet_n.hrytyp = '0105';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_NODET_N"
],
"ASSOCIATED":
[
"I_CONTROLLINGAREA",
"I_COSTCTRACTIVITYTYPEHIERARCHY",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/