I_CostCtrActivityTypeHierarchy

@ObjectModel.representativeKey: 'CostCtrActivityTypeHierarchy'
@EndUserText.label: 'Cost Center Activity Type Hierarchy'
@Analytics: { dataCategory: #DIMENSION }
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'IFCOSTCTRACTTYPH'
@AccessControl.authorizationCheck: #CHECK
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #XL
}
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #ANALYTICAL_DIMENSION, #EXTRACTION_DATA_SOURCE]
@Metadata.allowExtensions: true
@Analytics.internalName:#LOCAL
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@Analytics.dataExtraction: {enabled:true}

@AccessControl.privilegedAssociations: ['_ControllingAreaText']

define view I_CostCtrActivityTypeHierarchy
  as select from hrrp_dir_n
  association [0..1] to I_ControllingArea             as _ControllingAreaText on  $projection.ControllingArea = _ControllingAreaText.ControllingArea
  association [1..*] to I_CostCtrActivityTypeHierText as _Text                on  $projection.CostCtrActivityTypeHierarchy = _Text.CostCtrActivityTypeHierarchy
                                                                              and $projection.ControllingArea              = _Text.ControllingArea

  association [0..1] to I_ControllingArea             as _ControllingArea     on  $projection.ControllingArea = _ControllingArea.ControllingArea

{

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ControllingAreaStdVH',
                     element: 'ControllingArea' }
        }]
      @ObjectModel.text.association: '_ControllingAreaText'
      @ObjectModel.foreignKey.association: '_ControllingArea'
  key cast( hrrp_dir_n.kokrs as fis_kokrs preserving type )                    as ControllingArea,
      @ObjectModel.text.association: '_Text'
  key cast(hrrp_dir_n.hryid as fis_hryid_cctracttytpe preserving type )          as CostCtrActivityTypeHierarchy,
      @Semantics.businessDate.to: true
  key cast(hrrp_dir_n.hryvalto as fis_datbi preserving type )   as ValidityEndDate,
      @Semantics.businessDate.from: true
      cast(hrrp_dir_n.hryvalfrom as fis_datab preserving type ) as ValidityStartDate,
      @Semantics.user.lastChangedBy: true
      hrrp_dir_n.upduser                                        as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      hrrp_dir_n.updtime                                        as LastChangeDateTime,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:    'LastChangeDateTime'
      @VDM.lifecycle.status:     #DEPRECATED
      @VDM.lifecycle.successor:  'LastChangeDateTime'
      //@Semantics.systemDate.lastChangedAt: true

      hrrp_dir_n.updtime                                        as LastChangeTime,
      hrrp_dir_n.hrysid                                         as HierarchyShortID,
      @ObjectModel.association.boundFields.dataMatchesSourceAndTargetTypes: true
      _Text,
      _ControllingArea,
      @Consumption.hidden: true
      _ControllingAreaText

}
where
  hrrp_dir_n.hrytyp = '0105';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"HRRP_DIR_N"
],
"ASSOCIATED":
[
"I_CONTROLLINGAREA",
"I_COSTCTRACTIVITYTYPEHIERTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/