I_ComplaintProcessFlowBasic

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel: {

   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #D,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Complaint Process Flow StatusBasic'

define view entity I_ComplaintProcessFlowBasic
  as select from            I_SDDocumentMultiLevelProcFlow
    left outer to many join I_ComplaintProcessFlowStatus as PrecedProcessFlow  on  I_SDDocumentMultiLevelProcFlow.PrecedingDocument     = PrecedProcessFlow.SalesDocument
                                                                               and I_SDDocumentMultiLevelProcFlow.PrecedingDocumentItem = PrecedProcessFlow.DocumentItemNumber
    left outer to many join I_ComplaintProcessFlowStatus as SubProcessFlow     on  I_SDDocumentMultiLevelProcFlow.SubsequentDocument     = SubProcessFlow.SalesDocument
                                                                               and I_SDDocumentMultiLevelProcFlow.SubsequentDocumentItem = SubProcessFlow.DocumentItemNumber


    inner join              I_SDDocumentCategoryText     as PrecedingCategory  on  I_SDDocumentMultiLevelProcFlow.PrecedingDocumentCategory = PrecedingCategory.SDDocumentCategory
                                                                               and PrecedingCategory.Language                               = $session.system_language
    inner join              I_SDDocumentCategoryText     as SubsequentCategory on  I_SDDocumentMultiLevelProcFlow.SubsequentDocumentCategory = SubsequentCategory.SDDocumentCategory
                                                                               and SubsequentCategory.Language                               = $session.system_language

{
  key     I_SDDocumentMultiLevelProcFlow.DocRelationshipUUID        as DocRelationshipUUID,
          I_SDDocumentMultiLevelProcFlow.PrecedingDocument          as PrecedingDocument,
          I_SDDocumentMultiLevelProcFlow.PrecedingDocumentItem      as PrecedingDocumentItem,
          I_SDDocumentMultiLevelProcFlow.SubsequentDocument         as SubsequentDocument,
          I_SDDocumentMultiLevelProcFlow.SubsequentDocumentItem     as SubsequentDocumentItem,
          I_SDDocumentMultiLevelProcFlow.PrecedingDocumentCategory  as PrecedingDocumentCategory,
          PrecedingCategory.SDDocumentCategoryName                  as DocumentTypeDescription,
          PrecedProcessFlow.SDProcessStatusDesc                     as PrecedingDocStatus,


          I_SDDocumentMultiLevelProcFlow.SubsequentDocumentCategory as SubsequentDocumentCategory,

          SubsequentCategory.SDDocumentCategoryName                 as DocumentDescription,
          SubProcessFlow.SDProcessStatusDesc                        as SubsequentDocStatus,

          I_SDDocumentMultiLevelProcFlow.ProcessFlowLevel           as ProcessFlowLevel
}
where
  (
       I_SDDocumentMultiLevelProcFlow.SubsequentDocumentCategory = 'C' --> Outbound Delivery
    or I_SDDocumentMultiLevelProcFlow.SubsequentDocumentCategory = 'H' --> Invoice
    or I_SDDocumentMultiLevelProcFlow.SubsequentDocumentCategory = 'M' --> Credit Memo Request
    or I_SDDocumentMultiLevelProcFlow.SubsequentDocumentCategory = 'O' --> Debit Memo Request
    or I_SDDocumentMultiLevelProcFlow.SubsequentDocumentCategory = 'P' --> Customer Return
    or I_SDDocumentMultiLevelProcFlow.SubsequentDocumentCategory = 'T' --> Credit Memo
    or I_SDDocumentMultiLevelProcFlow.SubsequentDocumentCategory = 'J' --> Debit Memo
    or I_SDDocumentMultiLevelProcFlow.SubsequentDocumentCategory = 'K' --> Order w/o charge
    or I_SDDocumentMultiLevelProcFlow.SubsequentDocumentCategory = 'L' --> Returns Delivery
  )
  and(
       I_SDDocumentMultiLevelProcFlow.PrecedingDocumentCategory  = 'C' --> Outbound Delivery
    or I_SDDocumentMultiLevelProcFlow.PrecedingDocumentCategory  = 'H' --> Invoice
    or I_SDDocumentMultiLevelProcFlow.PrecedingDocumentCategory  = 'M' --> Credit Memo Request
    or I_SDDocumentMultiLevelProcFlow.PrecedingDocumentCategory  = 'O' --> Debit Memo Request
    or I_SDDocumentMultiLevelProcFlow.PrecedingDocumentCategory  = 'P' --> Debit Memo Request
    or I_SDDocumentMultiLevelProcFlow.PrecedingDocumentCategory  = 'T' --> Customer Return
    or I_SDDocumentMultiLevelProcFlow.PrecedingDocumentCategory  = 'J' --> Credit Memo
    or I_SDDocumentMultiLevelProcFlow.PrecedingDocumentCategory  = 'K' --> Debit Memo
    or I_SDDocumentMultiLevelProcFlow.PrecedingDocumentCategory  = 'L' --> Order w/o charge
    or I_SDDocumentMultiLevelProcFlow.PrecedingDocumentCategory  = 'T' --> Returns Delivery

  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COMPLAINTPROCESSFLOWSTATUS",
"I_SDDOCUMENTCATEGORYTEXT",
"I_SDDOCUMENTMULTILEVELPROCFLOW"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/