I_SDDOCUMENTCATEGORYTEXT

CDS View

SD Document Category - Text

I_SDDOCUMENTCATEGORYTEXT is a CDS View in S/4HANA. SD Document Category - Text. It contains 1 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 1 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_ComplaintProcessFlowBasic view_entity inner COMPOSITE Complaint Process Flow StatusBasic

Fields (1)

KeyField CDS FieldsUsed in Views
SDDocumentCategoryName DocumentDescription,DocumentTypeDescription 1 
@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.dataCategory: #TEXT
@ObjectModel.representativeKey: 'SDDocumentCategory'
@ObjectModel.usageType.dataClass: #META 
@ObjectModel.usageType.serviceQuality: #A 
@ObjectModel.usageType.sizeCategory: #S 
@EndUserText.label: 'SD Document Category - Text'
@VDM.viewType: #BASIC
@Analytics.dataExtraction.enabled: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'ISDDOCCATTEXT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true
@ObjectModel.modelingPattern:           #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.supportedCapabilities:  [  #SQL_DATA_SOURCE,
                                        #CDS_MODELING_DATA_SOURCE,
                                        #CDS_MODELING_ASSOCIATION_TARGET,
                                        #LANGUAGE_DEPENDENT_TEXT,
                                        #EXTRACTION_DATA_SOURCE,
                                        #SEARCHABLE_ENTITY   ]
/*+[hideWarning] { "IDS" : [ "KEY_CHECK", "CALCULATED_FIELD_CHECK" ]  } */
define view I_SDDocumentCategoryText
as select from dd07t 

association[0..1] to I_SDDocumentCategory as _SDDocumentCategory on $projection.SDDocumentCategory = _SDDocumentCategory.SDDocumentCategory
association[0..1] to I_Language as _Language on $projection.Language = _Language.Language
{   
    @ObjectModel.foreignKey.association: '_SDDocumentCategory'
    key cast(SUBSTRING(dd07t.domvalue_l, 1, 4) as vbtypl preserving type) as SDDocumentCategory,
          
    @ObjectModel.foreignKey.association: '_Language'
    @Semantics.language: true
    key ddlanguage as Language,
    
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.8     
    @Semantics.text: true
    @Search.ranking: #LOW 
    cast(ddtext as sddocumentcategoryname preserving type) as SDDocumentCategoryName,

    @Consumption.hidden: true
    dd07t.domvalue_l as DomainValue, 
       
    //Associations

    _SDDocumentCategory,
    _Language
} 
where (domname = 'VBTYPL') and (as4local = 'A');   
 /*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_SDDOCUMENTCATEGORY"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More