I_CmmdtyHedgeTransFlowActivity

@AbapCatalog.sqlViewName: 'ICMHDGTRANS'
@AbapCatalog.dataMaintenance: #RESTRICTED
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #S
@EndUserText.label: 'Financial Transaction Flow'
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_CmmdtyHedgeTransFlowActivity 
  with parameters
    P_CmmdtyHdgUtilznPlnExposureID : cmm_exposure_id,
    P_CmmdtyHdgUtilznEvalDate      : sydatum,
    P_CmmdtyHdgUtilznIsCnstltnData : xfeld,
    P_CmmdtyHdgUtilznAreOverHedged : xfeld,
    P_CmmdtyHdgPlanExposureVersion : cmm_exposure_version
  as select distinct from I_CmmdtyHdgCnstltnExtIntMirror
                          ( P_CmmdtyHdgUtilznPlnExposureID: $parameters.P_CmmdtyHdgUtilznPlnExposureID,
                            P_CmmdtyHdgUtilznIsCnstltnData: $parameters.P_CmmdtyHdgUtilznIsCnstltnData,
                            P_CmmdtyHdgUtilznAreOverHedged: $parameters.P_CmmdtyHdgUtilznAreOverHedged
                            )                                                                                                      as HdgConstlnDeals
    inner join            P_CmmdtyHdgExpsrRqdVersion(P_CmmdtyHdgPlanExposureVersion : $parameters.P_CmmdtyHdgPlanExposureVersion ) as MaxVersionExposure on MaxVersionExposure.CommodityHedgePlanExposureID = HdgConstlnDeals.CmmdtyHdgConstellationExposure
    inner join            I_CommodityHedgePlanExposure                                                                             as Exposures          on  Exposures.CommodityHedgePlanExposureID   = MaxVersionExposure.CommodityHedgePlanExposureID
                                                                                                                                                         and Exposures.CmmdtyHedgePlanExposureVersion = MaxVersionExposure.CmmdtyHedgePlanExposureVersion
    inner join            I_CmmdtyHdgTransFlowDetails                                                                              as TransactionFlow    on  TransactionFlow.CmmdtyHedgeConstellationDeal = HdgConstlnDeals.CmmdtyHedgeConstellationDeal
                                                                                                                                                         and TransactionFlow.CompanyCode                  = HdgConstlnDeals.CompanyCode
    inner join            vtbfha                                                                                                   as Transaction        on  TransactionFlow.CmmdtyHedgeConstellationDeal = Transaction.rfha
                                                                                                                                                         and Transaction.bukrs                            = HdgConstlnDeals.CompanyCode
    inner join            I_FinTransActivity                                                                                       as FinTransActivity   on  FinTransActivity.CompanyCode          = Transaction.bukrs
                                                                                                                                                         and FinTransActivity.FinancialTransaction = Transaction.rfha
    inner join            I_FinancialInstrProdTypeText                                                                             as TransProductType   on  Transaction.sgsart        = TransProductType.FinancialInstrumentProductType
                                                                                                                                                         and TransProductType.Language = $session.system_language

  //      inner join            I_CompanyCodeStdVH            as CompanyCode        on HdgConstlnDeals.CompanyCode = CompanyCode.CompanyCode

    inner join            I_CompanyCodeStdVH                                                                                       as CompanyCode        on Exposures.CmmdtyHdgPlnExpsrCompanyCode = CompanyCode.CompanyCode

{

  key HdgConstlnDeals.CmmdtyHedgeConstellationUUID,
      //  key HdgConstlnDeals.CmmdtyHedgePlanExposureHashKey,

  key HdgConstlnDeals.CmmdtyHedgeCnstltnRecordType,
  key HdgConstlnDeals.CmmdtyHedgeConstellationDeal,
  key HdgConstlnDeals.CmmdtyHdgConstellationDealType,
      HdgConstlnDeals.CmmdtyHdgConstellationExposure,
      HdgConstlnDeals.CmmdtyHdgCnstltnValdFrmDteTime,
      HdgConstlnDeals.CmmdtyHdgCnstltnExpsrVersion,
      HdgConstlnDeals.CmmdtyHdgCnstltnExposureItem,
//      HdgConstlnDeals.CmmdtyHdgCnstltnFrgnExchExpsr, "I517242: DB field deleted

      HdgConstlnDeals.CmmdtyHdgCnstltnFrgnExchHdgReq,
      //      TransactionFlow.CandidatePricingStartDate                                                              as TermStartDate,

      //      TransactionFlow.CandidatePricingEndDate                                                                as TermEndDate,

      TransactionFlow.FinTransactionPricingStartDate                                                     as TermStartDate,
      TransactionFlow.FinTransactionPricingEndDate                                                       as TermEndDate,
      Transaction.kontrh                                                                                 as Counterparty,
      Transaction.sgsart                                                                                 as FinancialInstrumentProductType,
      TransProductType.FinancialInstrProdTypeName,
      concat(concat(concat( TransProductType.FinancialInstrProdTypeName, '('), Transaction.sgsart), ')') as FinancialInstrProdTypeWithName,
      //Following code for determination of contract start date is temporary and later on,

      //it will be derived on ths basis of contract timestamp only after the resolution of incident 2170256428

      case
      when Transaction.contract_timestamp_utc <> 0
      then
      tstmp_to_dats( Transaction.contract_timestamp_utc,
                     abap_system_timezone( $session.client,'NULL' ),
                     $session.client,
                     'NULL' )
      else
      FinTransActivity.FinTransActyConclusionDate
      end                                                                                                as FinancialTransactionContrDate,
      //Following code for determination of contract start time is temporary and later on,

      //it will be derived on ths basis of contract timestamp only after the resolution of incident 2170256428

      case
      when Transaction.contract_timestamp_utc <> 0
      then
      tstmp_to_tims( Transaction.contract_timestamp_utc,
               abap_system_timezone( $session.client,'NULL' ),
               $session.client,
               'NULL' )
      else
      FinTransActivity.FinTransActyConclusionTime
      end                                                                                                as FinTransActyConclusionTime,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      TransactionFlow.Quantity                                                                           as Quantity,


      cast( 1 as ftr_quan)                                                                               as CmmdtyHdgSingleUnitOfQuantity,
      cast(Exposures.CmmdtyHedgePlnExposureQuantity as abap.fltp)                                        as CmmdtyHedgePlnExposureQuantity,
      Exposures.CmmdtyHdgPlnExpsrQuantityUnit,
      @Semantics.unitOfMeasure: true
      TransactionFlow.UnitOfMeasure,
      Exposures.CommodityHedgePlanExposureUUID,
      @ObjectModel.text.element: ['CompanyCodeName']
      HdgConstlnDeals.CompanyCode                                                                        as CompanyCode,
      CompanyCode.CompanyCodeName                                                                        as CompanyCodeName,
      concat(concat(concat( CompanyCode.CompanyCodeName, '('), HdgConstlnDeals.CompanyCode), ')')        as CmmdtyHdgCnstltnCoCodeWithName,
      Exposures.CmmdtyHedgePlanExposureDCSID,
      Exposures.CmmdtyHdgPlanExpsrMktIDCode,
      Exposures.CmmdtyHdgPlanExposureDirection,
      Exposures.CmmdtyHdgPlanExposureHedgeBook,
      Exposures.CmmdtyHdgPlnExpsrPerdStartDate,
      Exposures.CmmdtyHdgPlnExpsrPeriodClass,
      Exposures.CmmdtyHdgIsPrcgInDelivPeriod,
      Exposures.CmmdtyHdgPlnExpsrCompanyCode,
      Exposures.CmmdtyHedgePlanExposureVersion
}
where
  (
        TransactionFlow.Quantity                     is not initial
    and Exposures.CmmdtyHedgePlanExposureStatus      =  'ICPE4' //Released

    and Exposures.CmmdtyHdgPlnExpsrPrcgStartDate     <= TransactionFlow.FinTransactionPricingStartDate
    and Exposures.CmmdtyHdgPlnExpsrPrcgEndDate       >= TransactionFlow.FinTransactionPricingEndDate
    and TransactionFlow.FinTransCreationDate         <= $parameters.P_CmmdtyHdgUtilznEvalDate
    and TransactionFlow.FinTransactionPricingEndDate >= $parameters.P_CmmdtyHdgUtilznEvalDate
    and HdgConstlnDeals.CmmdtyHedgeCnstltnRecordType =  '1'
  )
  or(
        HdgConstlnDeals.CmmdtyHedgeCnstltnRecordType =  '2'
    and HdgConstlnDeals.CmmdtyHdgUtilznIsCnstltnData =  'X'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CMMDTYHDGCNSTLTNEXTINTMIRROR",
"I_CMMDTYHDGTRANSFLOWDETAILS",
"I_COMMODITYHEDGEPLANEXPOSURE",
"I_COMPANYCODESTDVH",
"I_FINANCIALINSTRPRODTYPETEXT",
"I_FINTRANSACTIVITY",
"P_CMMDTYHDGEXPSRRQDVERSION",
"VTBFHA"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/