I_COMMODITYHEDGEPLANEXPOSURE

@AbapCatalog.sqlViewName: 'ICMMDTYHDGPLNEXP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Basic for Commodity Hedge Plan Exposure'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel:{ representativeKey: 'CommodityHedgePlanExposureUUID',
               semanticKey: [ 'CmmdtyHdgPlnExpsrCompanyCode', 'CmmdtyHedgePlanExposureDCSID',
                              'CmmdtyHdgPlanExpsrMktIDCode',   'CmmdtyHdgPlanExposureDirection',
                              'CmmdtyHdgPlnExpsrHedgingArea', 'CmmdtyHdgPlnExpsrPerdStartDate',
                              'CmmdtyHdgPlnExpsrPeriodClass' ],
               usageType: { dataClass: #MIXED,
                            serviceQuality: #C,
                            sizeCategory: #L } }
@Metadata.ignorePropagatedAnnotations: true
define view I_CommodityHedgePlanExposure
  as select from cmmt_exposure
  association [0..1] to I_CmmdtyDrvtvContrSpecAttrib  as _DCSAttributes on $projection.CmmdtyHedgePlanExposureDCSID = _DCSAttributes.DerivativeContrSpecification
  association [0..1] to I_CompanyCode                 as _CompanyCode   on $projection.CmmdtyHdgPlnExpsrCompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_CmmdtyHdgBookCompleteDetail as _HedgeBook     on $projection.CmmdtyHdgPlanExposureHedgeBook = _HedgeBook.CommodityHedgeBookIdentifier
{
  key commodityhedgeplanexposureuuid      as CommodityHedgePlanExposureUUID,
      cmmdtyhdgplnexposureparentuuid      as CmmdtyHdgPlnExposureParentUUID,
      cmmdtyhedgeplanexposurehashkey      as CmmdtyHedgePlanExposureHashKey,
      cmmdtyhdgplnexpsrcompanycode        as CmmdtyHdgPlnExpsrCompanyCode,
      cmmdtyhedgeplanexposuredcsid        as CmmdtyHedgePlanExposureDCSID,
      cmmdtyhdgplanexpsrmktidcode         as CmmdtyHdgPlanExpsrMktIDCode,
      cmmdtyhdgplanexposuredirection      as CmmdtyHdgPlanExposureDirection,
      cmmdtyhdgplnexpsrhedgingarea        as CmmdtyHdgPlnExpsrHedgingArea,
      cmmdtyhdgplanexposurehedgebook      as CmmdtyHdgPlanExposureHedgeBook,
      _HedgeBook.CmmdtyHdgBookAuthznGroup as CmmdtyHdgBookAuthznGroup,
      cmmdtyhdgplnexpsrperdstartdate      as CmmdtyHdgPlnExpsrPerdStartDate,
      cmmdtyhdgplnexpsrperiodclass        as CmmdtyHdgPlnExpsrPeriodClass,
      cmmdtyhdgplnexpsrbusinessarea       as CmmdtyHdgPlnExpsrBusinessArea,
      cmmdtyhdgplnexpsrvalidfromdate      as CmmdtyHdgPlnExpsrValidFromDate,
      cmmdtyhdgplanexposureportfolio      as CmmdtyHdgPlanExposurePortfolio,
      cmmdtyhdgplnexpsrprofitcenter       as CmmdtyHdgPlnExpsrProfitCenter,
      cmmdtyhdgplnexposurecostcenter      as CmmdtyHdgPlnExposureCostCenter,
      cmmdtyhedgeplanexposureplant        as CmmdtyHedgePlanExposurePlant,
      cmmdtyhedgeplanexposureitemid       as CmmdtyHedgePlanExposureItemID,
      cmmdtyhdgplnexpsrisacctgrlvt        as CmmdtyHdgPlnExpsrIsAcctgRlvt,
      cmmdtyhdgplnexposureremarknote      as CmmdtyHdgPlnExposureRemarkNote,
      commodityhedgeplanexposureid        as CommodityHedgePlanExposureID,
      cmmdtyhdgplanexposurecategory       as CmmdtyHdgPlanExposureCategory,
      cmmdtyhdgplnexpsrdelivstrtdate      as CmmdtyHdgPlnExpsrDelivStrtDate,
      cmmdtyhdgplnexpsrdelivenddate       as CmmdtyHdgPlnExpsrDelivEndDate,
      cmmdtyhdgplnexpsrdelivperdtext      as CmmdtyHdgPlnExpsrDelivPerdText,
      cmmdtyhdgplnexpsrdelivperdtype      as CmmdtyHdgPlnExpsrDelivPerdType,
      cmmdtyhdgplnexpsrdelivperdyear      as CmmdtyHdgPlnExpsrDelivPerdYear,
      cmmdtyhdgplnexpsrprcgstartdate      as CmmdtyHdgPlnExpsrPrcgStartDate,
      cmmdtyhdgplnexpsrprcgenddate        as CmmdtyHdgPlnExpsrPrcgEndDate,
      planningdatauuid                    as PlanningDataUUID,
      @Semantics.quantity.unitOfMeasure: 'CmmdtyHdgPlnExpsrQuantityUnit'
      cmmdtyhedgeplnexposurequantity      as CmmdtyHedgePlnExposureQuantity,
      cmmdtyhdgplnexpsrquantityunit       as CmmdtyHdgPlnExpsrQuantityUnit,
      cmmdtyhdgplanexposureloghandle      as CmmdtyHdgPlanExposureLogHandle,
      cmmdtyhedgeplanexposurestatus       as CmmdtyHedgePlanExposureStatus,
      cmmdtyhedgeplanexposureversion      as CmmdtyHedgePlanExposureVersion,
      cmmdtyhdgplnexpsrstschgreason       as CmmdtyHdgPlnExpsrStsChgReason,
      //      @Semantics.user.createdBy: true

      cmmdtyhdgplnexpsrcreatedbyuser      as CmmdtyHdgPlnExpsrCreatedByUser,
      cmmdtyhdgplnexpsrcrtndatetime       as CmmdtyHdgPlnExpsrCrtnDateTime,
      //      @Semantics.user.lastChangedBy: true

      cmmdtyhdgplnexpsrlastchgdbyusr      as CmmdtyHdgPlnExpsrLastChgdByUsr,
      cmmdtyhdgplnexpsrchgdatetime        as CmmdtyHdgPlnExpsrChgDateTime,
      _DCSAttributes.PhysicalCommodity,

      case  cmmdtyhdgplnexposureparentuuid
       when hextobin('00000000000000000000000000000000') then cast( 'X' as xfeld preserving type )
       else cast( '' as xfeld preserving type )
       end                                as CmmdtyHdgPlnExpsrIsLtstVersion,

      case when cmmdtyhdgplnexpsrprcgstartdate = cmmdtyhdgplnexpsrdelivstrtdate
        and cmmdtyhdgplnexpsrprcgenddate = cmmdtyhdgplnexpsrdelivenddate then cast( 'X' as xfeld preserving type )
        else cast( '' as xfeld preserving type )
      end                                 as CmmdtyHdgIsPrcgInDelivPeriod,

      _DCSAttributes,
      _CompanyCode,
      _CompanyCode._ControllingArea,
      _CompanyCode.ControllingArea,
      _HedgeBook

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CMMDTYDRVTVCONTRSPECATTRIB",
"I_CMMDTYHDGBOOKCOMPLETEDETAIL",
"I_COMPANYCODE",
"CMMT_EXPOSURE"
],
"ASSOCIATED":
[
"I_CMMDTYDRVTVCONTRSPECATTRIB",
"I_CMMDTYHDGBOOKCOMPLETEDETAIL",
"I_COMPANYCODE",
"I_CONTROLLINGAREA"
],
"BASE":
[
"I_COMPANYCODE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/