I_ChangeRecdRefClassTP_2

@AbapCatalog.sqlViewName: 'ICHGRECREFCLSTP2'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@VDM.viewType: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@EndUserText.label: 'Change Record Reference Object Class'
define view I_ChangeRecdRefClassTP_2
  as select from           I_ChangeRecordRefClassBsc as reference_class
    left outer to one join I_ClfnClass               as Classification on  reference_class.ChgRecRefInternalKey1 = Classification.Class
                                                                       and reference_class.ChgRecRefInternalKey3 = Classification.ClassType

  association [0..*] to I_ClfnClassCharcBasic     as _ClassCharcBasic   on  $projection.ClassInternalID          = _ClassCharcBasic.ClassInternalID
                                                                        and _ClassCharcBasic.CharcPositionNumber = '001'
  association        to parent I_ChangeRecordTP_2 as _ChangeRecordAPITP on  $projection.ChangeRecordUUID = _ChangeRecordAPITP.ChangeRecordUUID

  association [1..1] to I_ChangeRecordDraftTP     as _ChangeRecordTP    on  $projection.ChangeRecordUUID = _ChangeRecordTP.ChangeRecordUUID
  association [0..1] to E_ChangeRecordRefClassBsc as _ClassExtension    on  $projection.ChangeRecordReferenceUUID = _ClassExtension.ChangeRecordReferenceUUID
{

  key          reference_class.ChangeRecordReferenceUUID,

               case
                 when Classification.Class is null then cast(SUBSTRING( reference_class.ChangeRecordReference, 1, 18) as klasse_d)
                 else cast(Classification.Class as klasse_d)
                 end                                                                                               as Class,

               case
                  when Classification.ClassType is null then  cast(SUBSTRING( reference_class.ChangeRecordReference, 31, 3) as klassenart)
                  else cast(Classification.ClassType as klassenart)
                  end                                                                                              as ClassType,


               case
                when _ClassCharcBasic.ChangeNumber is null then  cast(SUBSTRING( reference_class.ChangeRecordReference, 19, 12) as aennr)
                else cast(_ClassCharcBasic.ChangeNumber as aennr)
                end                                                                                                as ChangeNumber,




               Classification.ClassInternalID,
               Classification._ClassDescription[1:Language = $session.system_language].ClassDescription            as ClassName,
               Classification._ClassType._ClassTypeText[1:Language = $session.system_language].ClassTypeName       as ClassTypeName,


               Classification.ClassStatus                                                                          as ClassStatus,
               Classification._ClassStatus._ClassStatusText[1:Language = $session.system_language].ClassStatusName as ClassStatusName,

               Classification.ValidityStartDate,
               reference_class.ChangeRecordUUID,
               reference_class.ChangeRecord,
               reference_class.ChangeRecordReferenceType,
               reference_class.ChangeRecordReferenceSubtype,
               reference_class.ChangeRecordReference,
               reference_class.ParentChangeRecordRefUUID,
               reference_class.IsMainReference,
               reference_class.CreatedByUser,
               reference_class.CreationDateTime,
               reference_class.LastChangedByUser,
               reference_class.LastChangeDateTime,
               reference_class.ChangeRecordItemRelevance,
               reference_class.ChangeRecordVirtualRefInd,
               reference_class.ChangeRecordRefObjectUUID,
               reference_class.ChangeRecordItemProcgStatus,
               _ChangeRecordTP,
               _ClassCharcBasic,
               _ChangeRecordAPITP

}
where
  reference_class.ChangeRecordReferenceType = 'CLS'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGERECORDREFCLASSBSC",
"I_CLFNCLASS",
"I_CLFNCLASSCHARCBASIC",
"I_CLFNCLASSDESCRIPTION",
"I_CLFNCLASSSTATUS",
"I_CLFNCLASSSTATUSTEXT",
"I_CLFNCLASSTYPEBASIC",
"I_CLFNCLASSTYPETEXT"
],
"ASSOCIATED":
[
"E_CHANGERECORDREFCLASSBSC",
"I_CHANGERECORDDRAFTTP",
"I_CHANGERECORDTP_2",
"I_CLFNCLASSCHARCBASIC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/