I_ChangeMstrObMgReDocInfoRecd

@AbapCatalog.sqlViewName: 'IECNOMRDIR'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.supportedCapabilities: [ #CDS_MODELING_DATA_SOURCE,
                                      #CDS_MODELING_ASSOCIATION_TARGET,
                                      #SQL_DATA_SOURCE ]

@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.dataClass: #MASTER

@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API

@EndUserText.label: 'Change Number ObMaRe of Doc Info Record'
define view I_ChangeMstrObMgReDocInfoRecd
  as select from I_ChangeMstrObjectMgmtRecord
  association [0..1] to I_DocumentInfoRecord as _DocumentInfoRecord on  $projection.DocumentType       = _DocumentInfoRecord.DocumentInfoRecordDocType
                                                                    and $projection.DocumentInfoRecord = _DocumentInfoRecord.DocumentInfoRecordDocNumber
                                                                    and $projection.DocumentPart       = _DocumentInfoRecord.DocumentInfoRecordDocPart
                                                                    and $projection.DocumentVersion    = _DocumentInfoRecord.DocumentInfoRecordDocVersion
{
  key ChangeNumber,
  key cast(substring(ObjMgmtRecdObject, 1, 3) as dokar)    as DocumentType,
  key cast(substring(ObjMgmtRecdObject, 4, 25) as doknr)   as DocumentInfoRecord,
  key cast(substring(ObjMgmtRecdObject, 29, 3) as doktl_d) as DocumentPart,
  key cast(substring(ObjMgmtRecdObject, 32, 2) as dokvr)   as DocumentVersion,

      ObjMgmtRecdObject,
      ObjMgmtRecdObjectInternalID,

      ChgNmbrAlternativeDateCounter,
      ObjMgmtRecdDescription,
      ObjMgmtRecdItemUUID,

      ObjMgmtRecdLastChangedAt,
      ObjMgmtRecdLastChangedBy,

      ObjMgmtRecdCreationDate,
      ObjMgmtRecdCreatedBy,
      ObjMgmtRecdObjLastChangedAt,
      ObjMgmtRecdObjLastChangedBy,

      ObjMgmtRecdObjIsLockedForChg,
      ObjMgmtRecdObjIsBaselined,
      ObjMgmtRecdChangeType,
      ObjMgmtRecdObjIsPlanned,
      ObjMgmtRecdObjRevisionLevel,

      /* Associations */
      _ChangeMaster,
      _ChangeMasterAltDate
      //      _DocumentInfoRecord

}
where
  ChangeNumberObjectType = '31'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CHANGEMSTROBJECTMGMTRECORD"
],
"ASSOCIATED":
[
"I_CHANGEMASTER",
"I_CHANGEMASTERALTDATE",
"I_DOCUMENTINFORECORD"
],
"BASE":
[
"I_CHANGEMSTROBJECTMGMTRECORD"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/