I_CapacityRequirement

@AbapCatalog.sqlViewName: 'IPPCAPRQMT'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@Analytics.dataExtraction.enabled: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.compositionRoot: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE]
@ObjectModel.representativeKey: 'CapacityRequirement'
@ObjectModel.semanticKey: ['CapacityRequirement']
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Capacity Requirement Header'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_CapacityRequirement
  as select from           kbko as kbko
    left outer to one join afko as afko on  kbko.aufpl = afko.aufpl
                                        and kbko.aufpl > '0000000000'

  association [1..1] to I_CapacityRequirementOrigin    as _CapacityRequirementOrigin    on  $projection.CapacityRequirementOrigin = _CapacityRequirementOrigin.CapacityRequirementOrigin
  association [0..1] to I_PlannedOrder                 as _PlannedOrder                 on  $projection.PlannedOrder = _PlannedOrder.PlannedOrder
  association [0..1] to I_LogisticsOrder               as _Order                        on  $projection.OrderID = _Order.OrderID
  association [0..1] to I_OrderInternalID              as _OrderInternalID              on  $projection.OrderInternalID = _OrderInternalID.OrderInternalID
  association [0..1] to I_SalesOperationsPlanningOrder as _SalesOperationsPlanningOrder on  $projection.SalesOperationsPlanningOrder= _SalesOperationsPlanningOrder.SalesOperationsPlanningOrder
  association [0..1] to I_BillOfOperationsType         as _BillOfOperationsType         on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [0..1] to I_BillOfOperationsGroup        as _BillOfOperationsGroup        on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
  association [0..1] to I_BillOfOperations             as _BillOfOperations             on  $projection.BillOfOperationsType  = _BillOfOperations.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup = _BillOfOperations.BillOfOperationsGroup
                                                                                        and $projection.BillOfOperations      = _BillOfOperations.BillOfOperationsVariant
  association [0..1] to I_SchedulingType               as _SchedulingType               on  $projection.SchedulingType = _SchedulingType.SchedulingType
  -- to child
  association [1..*] to I_CapacityRequirementItem      as _CapacityRequirementItem      on  $projection.CapacityRequirement = _CapacityRequirementItem.CapacityRequirement

  {
    // Key

    key kbko.bedid as CapacityRequirement,

    // Assignments

    @ObjectModel.foreignKey.association: '_CapacityRequirementOrigin'
    @ObjectModel.sapObjectNodeTypeReference: 'CapacityRequirementOrigin'
    cast(kbko.typkz as capacityrequirementorigin preserving type) as CapacityRequirementOrigin,
    @ObjectModel.foreignKey.association: '_PlannedOrder'
    @ObjectModel.sapObjectNodeTypeReference: 'PlannedOrder'
    kbko.plnum as PlannedOrder,
    @Consumption.valueHelpDefinition: [ { entity: { name: 'I_LogisticsOrderStdVH', element: 'OrderID' } } ]
    @ObjectModel.foreignKey.association: '_Order'
    afko.aufnr as OrderID,
    @ObjectModel.foreignKey.association: '_OrderInternalID'
    cast(kbko.aufpl as pph_aufpl preserving type)                 as OrderInternalID,
    @ObjectModel.foreignKey.association: '_SalesOperationsPlanningOrder'
    kbko.safnr as SalesOperationsPlanningOrder,
    @ObjectModel.foreignKey.association: '_BillOfOperationsType'
    kbko.plnty as BillOfOperationsType,
    @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
    kbko.plnnr as BillOfOperationsGroup,
    @ObjectModel.foreignKey.association: '_BillOfOperations'
    kbko.plnal as BillOfOperations,
    @ObjectModel.foreignKey.association: '_SchedulingType'
    @ObjectModel.sapObjectNodeTypeReference: 'SchedulingType'
    cast(kbko.terkz as pph_termkz preserving type)                as SchedulingType,

    // Dates and Times

    kbko.gstrs as ScheduledBasicStartDate,
    kbko.gsuzs as ScheduledBasicStartTime,
    kbko.gltrs as ScheduledBasicEndDate,
    kbko.gluzs as ScheduledBasicEndTime,
    kbko.trmdt as LastScheduledDate,
    kbko.plauf as BOOExplosionDate,

    // Associations

    @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
    _CapacityRequirementItem,
    _CapacityRequirementOrigin,
    _BillOfOperationsType,
    _BillOfOperationsGroup,
    _BillOfOperations,
    _SchedulingType,
    _PlannedOrder,
    _Order,
    _SalesOperationsPlanningOrder,
    @Consumption.hidden: true
    _OrderInternalID
  };
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"AFKO",
"KBKO"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_CAPACITYREQUIREMENTITEM",
"I_CAPACITYREQUIREMENTORIGIN",
"I_LOGISTICSORDER",
"I_ORDERINTERNALID",
"I_PLANNEDORDER",
"I_SALESOPERATIONSPLANNINGORDER",
"I_SCHEDULINGTYPE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/