I_CFinRpldSalesDocScheduleLine

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'ICFINRSOSLN'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@EndUserText.label: 'CFin Rpld Sales Document: Schedule Line'
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel: {
   representativeKey: 'CFinRpldSalesDocScheduleLine',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
/*+[hideWarning] { "IDS" :
[ "KEY_CHECK" ] } */
define view I_CFinRpldSalesDocScheduleLine
  as select from cfin_av_so_sln
  association [1..1] to I_CFinReplicatedSalesDocument  as _CFinReplicatedSalesDocument on  $projection.SenderLogicalSystem         = _CFinReplicatedSalesDocument.SenderLogicalSystem
                                                                                       and $projection.CFinReplicatedSalesDocument = _CFinReplicatedSalesDocument.CFinReplicatedSalesDocument
  association [1..1] to I_CFinRpldSalesDocumentItem    as _CFinRpldSalesDocumentItem   on  $projection.SenderLogicalSystem         = _CFinRpldSalesDocumentItem.SenderLogicalSystem
                                                                                       and $projection.CFinRpldSalesDocumentItem   = _CFinRpldSalesDocumentItem.CFinRpldSalesDocumentItem
                                                                                       and $projection.CFinReplicatedSalesDocument = _CFinRpldSalesDocumentItem.CFinReplicatedSalesDocument
  association [0..1] to I_UnitOfMeasure                as _OrderQuantityUnit           on  $projection.OrderQuantityUnit = _OrderQuantityUnit.UnitOfMeasure
  association [0..1] to I_GoodsMovementType            as _GoodsMovementType           on  $projection.GoodsMovementType = _GoodsMovementType.GoodsMovementType

{
  key fins_logsys                                                    as SenderLogicalSystem,
  key cast(vbeln as fins_cfin_av_rpld_sls_doc preserving type )      as CFinReplicatedSalesDocument,
  key cast(posnr as fins_cfin_av_rpld_sls_doc_item preserving type ) as CFinRpldSalesDocumentItem,
  key cast(etenr as fins_cfin_av_rpld_sched_line preserving type )   as CFinRpldSalesDocScheduleLine,
      aufnr                                                          as OrderID,
      @ObjectModel.foreignKey.association: '_GoodsMovementType'
      bwart                                                          as GoodsMovementType,
      edatu                                                          as DeliveryDate,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_OrderQuantityUnit'
      vrkme                                                          as OrderQuantityUnit,
      wadat                                                          as GoodsIssueDate,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      wmeng                                                          as ScheduleLineOrderQuantity,
      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      bmeng                                                          as ConfdOrderQtyByMatlAvailCheck,
      req_dlvdate                                                    as ConfdSchedLineReqdDelivDate,
      _CFinReplicatedSalesDocument,
      _CFinRpldSalesDocumentItem,
      _OrderQuantityUnit,
      _GoodsMovementType

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CFIN_AV_SO_SLN"
],
"ASSOCIATED":
[
"I_CFINREPLICATEDSALESDOCUMENT",
"I_CFINRPLDSALESDOCUMENTITEM",
"I_GOODSMOVEMENTTYPE",
"I_UNITOFMEASURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/