I_CFinReplicatedSalesDocument

@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'CFin Replicated Sales Document: Header'
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #NOT_REQUIRED
}
@AbapCatalog: {
  sqlViewName: 'ICFINRSOROOT',
  preserveKey: true,
  compiler.compareFilter: true
}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}

define view I_CFinReplicatedSalesDocument
  as select from           cfin_av_so_root
    left outer to one join cfin_av_so_biz on  cfin_av_so_root.fins_logsys = cfin_av_so_biz.fins_logsys
                                          and cfin_av_so_root.vbeln       = cfin_av_so_biz.vbeln
                                          and cfin_av_so_biz.posnr        = '000000'

  association [0..1] to I_SDDocumentCategory          as _SDDocumentCategory          on  $projection.SDDocumentCategory = _SDDocumentCategory.SDDocumentCategory
  association [0..1] to I_SalesDocumentType           as _SalesDocumentType           on  $projection.SalesDocumentType = _SalesDocumentType.SalesDocumentType
  association [0..1] to I_SalesOrganization           as _SalesOrganization           on  $projection.SalesOrganization = _SalesOrganization.SalesOrganization
  association [0..1] to I_DistributionChannel         as _DistributionChannel         on  $projection.DistributionChannel = _DistributionChannel.DistributionChannel
  association [0..1] to I_Division                    as _OrganizationDivision        on  $projection.OrganizationDivision = _OrganizationDivision.Division
  association [0..1] to I_SalesGroup                  as _SalesGroup                  on  $projection.SalesGroup = _SalesGroup.SalesGroup
  association [0..1] to I_SalesOffice                 as _SalesOffice                 on  $projection.SalesOffice = _SalesOffice.SalesOffice
  association [0..1] to I_Currency                    as _TransactionCurrency         on  $projection.TransactionCurrency = _TransactionCurrency.Currency
  association [0..1] to I_CompanyCode                 as _BillingCompanyCode          on  $projection.BillingCompanyCode = _BillingCompanyCode.CompanyCode
  association [0..1] to I_SlsPricingProcedure         as _SDPricingProcedure          on  $projection.SDPricingProcedure = _SDPricingProcedure.PricingProcedure
  association [0..1] to I_ControllingArea             as _ControllingArea             on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_SDDocumentCategory          as _ReferenceSDDocumentCategory on  $projection.ReferenceSDDocumentCategory = _ReferenceSDDocumentCategory.SDDocumentCategory

  association [0..*] to I_CFinRpldSalesDocumentItem   as _Item                        on  $projection.SenderLogicalSystem         = _Item.SenderLogicalSystem
                                                                                      and $projection.CFinReplicatedSalesDocument = _Item.CFinReplicatedSalesDocument
  association [0..1] to I_CustomerGroup               as _CustomerGroup               on  $projection.CustomerGroup = _CustomerGroup.CustomerGroup
  //compatible with union view ,because union association is 0..1

  association [0..1] to I_LogicalSystem               as _LogicalSystem               on  $projection.SenderLogicalSystem = _LogicalSystem.LogicalSystem
  association [1..1] to E_CFinReplicatedSalesDocument as _Extension                   on  $projection.CFinReplicatedSalesDocument = _Extension.CFinReplicatedSalesDocument
                                                                                      and $projection.SenderLogicalSystem         = _Extension.SourceSystemLogicalSystem

{
      @ObjectModel.foreignKey.association: '_LogicalSystem'
  key cfin_av_so_root.fins_logsys                                                as SenderLogicalSystem,
  key cast( cfin_av_so_root.vbeln as fins_cfin_av_rpld_sls_doc preserving type ) as CFinReplicatedSalesDocument,
      cfin_av_so_root.vgbel                                                      as ReferenceSDDocument,
      @ObjectModel.foreignKey.association: '_ReferenceSDDocumentCategory'
      cfin_av_so_root.vgtyp                                                      as ReferenceSDDocumentCategory,
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      cfin_av_so_root.vkorg                                                      as SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      cfin_av_so_root.vtweg                                                      as DistributionChannel,
      @ObjectModel.foreignKey.association: '_BillingCompanyCode'
      cfin_av_so_root.bukrs_vf                                                   as BillingCompanyCode,
      cfin_av_so_root.erdat                                                      as CreationDate,
      @ObjectModel.foreignKey.association: '_SDDocumentCategory'
      cfin_av_so_root.vbtyp                                                      as SDDocumentCategory,
      @ObjectModel.foreignKey.association: '_SalesDocumentType'
      cast( cfin_av_so_root.auart as auart_unv preserving type )                 as SalesDocumentType,
      cfin_av_so_root.kostl                                                      as CostCenter,
      @Semantics.currencyCode: true
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      cfin_av_so_root.waerk                                                      as TransactionCurrency,
      cfin_av_so_root.aedat                                                      as LastChangeDate,
      cfin_av_so_root.ernam                                                      as CreatedByUser,
      cfin_av_so_root.audat                                                      as SalesDocumentDate,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cfin_av_so_root.netwr                                                      as TotalNetAmount,
      @ObjectModel.foreignKey.association: '_SalesGroup'
      cfin_av_so_root.vkgrp                                                      as SalesGroup,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      cfin_av_so_root.vkbur                                                      as SalesOffice,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      cfin_av_so_root.kokrs                                                      as ControllingArea,
      cfin_av_so_root.knumv                                                      as SalesDocumentCondition,
      @ObjectModel.foreignKey.association: '_SDPricingProcedure'
      cfin_av_so_root.kalsm                                                      as SDPricingProcedure,
      cfin_av_so_root.landtx                                                     as TaxDepartureCountry,
      cfin_av_so_root.kunnr                                                      as SoldToParty,
      @ObjectModel.foreignKey.association: '_OrganizationDivision'
      cfin_av_so_root.spart                                                      as OrganizationDivision,

      @ObjectModel.foreignKey.association: '_CustomerGroup'
      cfin_av_so_biz.kdgrp                                                       as CustomerGroup,
      cfin_av_so_biz.prsdt                                                       as PricingDate,
      cfin_av_so_biz.valtg                                                       as AdditionalValueDays,
      cfin_av_so_biz.fkdat                                                       as BillingDocumentDate,

      _SDDocumentCategory,
      _SalesDocumentType,
      _SalesOrganization,
      _DistributionChannel,
      _OrganizationDivision,
      _SalesGroup,
      _SalesOffice,
      _TransactionCurrency,
      _BillingCompanyCode,
      _SDPricingProcedure,
      _ControllingArea,
      _ReferenceSDDocumentCategory,
      _Item,
      _CustomerGroup,
      _LogicalSystem
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CFIN_AV_SO_BIZ",
"CFIN_AV_SO_ROOT"
],
"ASSOCIATED":
[
"E_CFINREPLICATEDSALESDOCUMENT",
"I_CFINRPLDSALESDOCUMENTITEM",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_CURRENCY",
"I_CUSTOMERGROUP",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_LOGICALSYSTEM",
"I_SALESDOCUMENTTYPE",
"I_SALESGROUP",
"I_SALESOFFICE",
"I_SALESORGANIZATION",
"I_SDDOCUMENTCATEGORY",
"I_SLSPRICINGPROCEDURE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/