I_BusinessPartnerAddressProcTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Business Partner Address (Process Data)'

@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view entity I_BusinessPartnerAddressProcTP
  as select from I_BusinessPartnerAddressProc

  composition [0..*] of I_BusPartAddressUsageProcTP    as _BusinessPartnerAddressUsage
  composition [0..*] of I_BusPartTelephoneNumberProcTP as _BusinessPartnerPhoneNumber
  association [0..1] to I_BusPartTelephoneNumberProcTP as _StandardPhoneNumber         on  _StandardPhoneNumber.AddressNumber   = $projection.AddressNumber
                                                                                       and _StandardPhoneNumber.PhoneNumberType = '1'

  composition [0..*] of I_BusPartMobileNumberProcTP    as _BusinessPartnerMobileNumber
  association [0..1] to I_BusPartMobileNumberProcTP    as _StandardMobileNumber        on  _StandardMobileNumber.AddressNumber   = $projection.AddressNumber
                                                                                       and _StandardMobileNumber.PhoneNumberType = '3'
  composition [0..*] of I_BusPartEmailAddressProcTP    as _BusinessPartnerEmailAddress
  association [0..1] to I_BusPartEmailAddressProcTP    as _StandardEmailAddress        on  _StandardEmailAddress.AddressNumber         = $projection.AddressNumber
                                                                                       and _StandardEmailAddress.IsDefaultEmailAddress = 'X'
  composition [0..*] of I_BPFaxNumberProcessTP         as _BusinessPartnerFaxNumber
  association [0..1] to I_BPFaxNumberProcessTP         as _StandardFaxNumber           on  _StandardFaxNumber.AddressNumber      = $projection.AddressNumber
                                                                                       and _StandardFaxNumber.IsDefaultFaxNumber = 'X'
  composition [0..*] of I_BusPartWebsiteURLProcTP      as _BusinessPartnerWebsiteURL
  association [0..1] to I_BusPartWebsiteURLTP_2        as _StandardWebsiteURL          on  _StandardWebsiteURL.AddressNumber       = $projection.AddressNumber
                                                                                       and _StandardWebsiteURL.IsDefaultURLAddress = 'X'

  composition [0..*] of I_BusPartScriptedOrgAddrProcTP as _BusinessPartnerAddressScrOrg
  composition [0..*] of I_BusPartScriptedGrpAddrProcTP as _BusinessPartnerAddressScrGrp
  composition [0..*] of I_BPScriptedPersAddrProcTP     as _BusinessPartnerAddressScrPers

  association [1..1] to I_BPCurrentDefaultAddressProc  as _StandardAddrUsage           on  $projection.MasterDataChangeProcess = _StandardAddrUsage.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessSrceSystem  = _StandardAddrUsage.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject  = _StandardAddrUsage.MDChgProcessSrceObject
                                                                                       and $projection.MDChgProcessStep        = _StandardAddrUsage.MDChgProcessStep
  association        to parent I_BusinessPartnerProcessTP     as _BusinessPartner      on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                                       and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association [0..1] to I_Country                      as _Country                     on  $projection.Country = _Country.Country
  association [0..1] to I_CountryText                  as _CountryText                 on  $projection.Country   = _CountryText.Country
                                                                                       and _CountryText.Language = $session.system_language
  association [0..1] to I_Region                       as _Region                      on  $projection.Country = _Region.Country
                                                                                       and $projection.Region  = _Region.Region
  association [0..1] to I_LanguageText                 as _Language                    on  $projection.CorrespondenceLanguage = _Language.LanguageCode
                                                                                       and _Language.Language                 = $session.system_language
  association [0..1] to I_BusPartCommMdmTypeVH         as _CommType                    on  $projection.PrfrdCommMediumType = _CommType.CommunicationMediumType
  association [0..1] to I_TimeZone                     as _TimeZone                    on  $projection.AddressTimeZone = _TimeZone.TimeZoneID
  association [0..1] to I_Transportation_Zone_Text     as _TransportZone               on  $projection.TransportZone = _TransportZone.TransportZone
                                                                                       and $projection.Country       = _TransportZone.CountryCode
                                                                                       and _TransportZone.Language   = $session.system_language
  association [0..1] to I_Country                      as _POBoxCountry                on  $projection.POBoxDeviatingCountry = _POBoxCountry.Country
  association [0..1] to I_Region                       as _POBoxRegion                 on  $projection.POBoxDeviatingCountry = _POBoxRegion.Country
                                                                                       and $projection.POBoxDeviatingRegion  = _POBoxRegion.Region
  association [0..1] to I_BusPartDelivSrvcVH           as _DeliveryService             on  $projection.DeliveryServiceTypeCode = _DeliveryService.DeliveryServiceTypeCode
  association [0..1] to I_AddressNonDeliverableReason  as _AddressNonDeliverableReason on  $projection.AddressNonDeliverableReason = _AddressNonDeliverableReason.AddressNonDeliverableReason
  association [0..1] to I_AddressNonDeliverableReason  as _PostBoxNonDeliverableReason on  $projection.PostBoxNonDeliverableReason = _PostBoxNonDeliverableReason.AddressNonDeliverableReason
  association [0..1] to I_BPProcessKPIRecordType       as _RecordType                  on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                                       and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH      as _KPIUpdateStatusText         on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..*] to I_MDChgProcRecordMessages      as _RecordMessages              on  $projection.MasterDataChangeProcess = _RecordMessages.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessStep        = _RecordMessages.MDChgProcessStep
                                                                                       and $projection.MDChgProcessSrceSystem  = _RecordMessages.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject  = _RecordMessages.MDChgProcessSrceObject
  association [0..1] to I_MDChgProcessStepTP           as _Step                        on  $projection.MasterDataChangeProcess = _Step.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessStep        = _Step.MDChgProcessStep
  association [0..1] to I_BPAddrInfoManagementOut      as _AddrInfoMgmtOut             on  $projection.MasterDataChangeProcess        = _AddrInfoMgmtOut.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessStep               = _AddrInfoMgmtOut.MDChgProcessStep
                                                                                       and $projection.MDChgProcessSrceSystem         = _AddrInfoMgmtOut.MDChgProcessSrceSystem
                                                                                       and $projection.MDChgProcessSrceObject         = _AddrInfoMgmtOut.MDChgProcessSrceObject
                                                                                       and $projection.AddressNumber                  = _AddrInfoMgmtOut.AddressNumber
                                                                                       and _AddrInfoMgmtOut.AddressRepresentationCode = ''
  association [0..1] to I_MDChgProcKPIFilterStdznSts   as _StdStatus                   on  $projection.MDChgProcKPIStdznStatus = _StdStatus.MDChangeProcKPIValueKey
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
      @Search.defaultSearchElement: true
  key AddressNumber,
      BusinessPartner,
      case when  _StandardAddrUsage.AddressNumber = AddressNumber
      then cast('X' as abap_boolean)
      else cast(' ' as abap_boolean)
      end                                                                            as StandardUsage,
      BusinessPartnerAddressUUID,
      ValidityStartDate,
      ValidityEndDate,
      @Semantics.businessDate.from: true
      case when ValidityStartDate != 00010101000000
      then tstmp_to_dats(ValidityStartDate,'UTC',  $session.client, 'NULL')
      else cast ( '00010103' as abap.dats )
      end                                                                            as AddressValidityStartDate,
      @Semantics.businessDate.to: true
      case when ValidityEndDate != 00010101000000
      then tstmp_to_dats(ValidityEndDate,'UTC',  $session.client, 'NULL')
      else cast ( '99991231' as abap.dats)
      end                                                                            as AddressValidityEndDate,
      FormOfAddress,
      CareOfName,
      CityName,
      DistrictName,
      CityNumber,
      HomeCityName,
      CityFileTestStatus,
      PostalCode,
      POBoxPostalCode,
      CompanyPostalCode,
      POBox,
      AddressPostBoxUnusable,
      POBoxIsWithoutNumber,
      POBoxDeviatingCityName,
      POBoxDeviatingRegion,
      POBoxDeviatingCountry,
      TransportZone,
      StreetName,
      AddressStreetUnusable,
      HouseNumber,
      HouseNumberSupplementText,
      StreetPrefixName,
      AdditionalStreetPrefixName,
      StreetSuffixName,
      AdditionalStreetSuffixName,
      Building,
      Floor,
      RoomNumber,
      Country,
      CorrespondenceLanguage,
      Region,
      PrfrdCommMediumType,
      PhoneNumber,
      AddressFaxNumber,
      CitySearch,
      StreetSearch,
      AddressTimeZone,
      TaxJurisdiction,
      POBoxLobbyName,
      DeliveryServiceTypeCode,
      DeliveryServiceNumber,
      CountyCode,
      BPCountyText,
      AddressStreetUnusable                                                          as AddressNonDeliverableReason,
      AddressPostBoxUnusable                                                         as PostBoxNonDeliverableReason,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      MDChgProcessSourceModif2Binary,
      MDChgProcSrceLastChgdDateTime,
      /* Record Identification */
      /* Has been moved to a virtual field in the projection layer, therefore the dummy entry */
      cast( '' as abap.char(209) )  as AddressLine1Text,
      cast( case
        when MDChgProcessSourceModified = '' then 'N'
        when MDChgProcessSourceModified = 'X' then 'M'
        else MDChgProcessSourceModified end as mdc_source_modified preserving type ) as MDChgProcKPIUpdateStatus,

      cast( case
        when _Step.MDChgProcessStepAdapter = 'CL_MDC_ADAPTER_BP_DQMM'
              and MDChgProcessSourceModified = 'X'
                then 'M'
        when _Step.MDChgProcessStepAdapter = 'CL_MDC_ADAPTER_BP_DQMM'
              and MDChgProcessSourceModified = ''
              and CityFileTestStatus = ''
              and not _AddrInfoMgmtOut.AddressInfoCode between '2000' and '4999'
              and not _AddrInfoMgmtOut.AddressPostOfficeBoxInfoCode between '2000' and '4999'
              and not (
                (
                  _AddrInfoMgmtOut.AddressInfoCode = '' or _AddrInfoMgmtOut.AddressInfoCode = ' ' or _AddrInfoMgmtOut.AddressInfoCode = '5020'
                ) and (
                  _AddrInfoMgmtOut.AddressPostOfficeBoxInfoCode = '' or _AddrInfoMgmtOut.AddressPostOfficeBoxInfoCode = ' ' or _AddrInfoMgmtOut.AddressPostOfficeBoxInfoCode = '5020'
                )
              )
                then 'D'
        when _Step.MDChgProcessStepAdapter = 'CL_MDC_ADAPTER_BP_DQMM'
              and MDChgProcessSourceModified = ''
              and CityFileTestStatus = ''
              and ( _AddrInfoMgmtOut.AddressInfoCode between '2000' and '4999'
                 or _AddrInfoMgmtOut.AddressPostOfficeBoxInfoCode between '2000' and '4999'
              )
                then 'B'
        when _Step.MDChgProcessStepAdapter = 'CL_MDC_ADAPTER_BP_DQMM'
              and MDChgProcessSourceModified = ''
              and CityFileTestStatus = 'D'
                then 'O'
        when _Step.MDChgProcessStepAdapter = 'CL_MDC_ADAPTER_BP_DQMM'
              and MDChgProcessSourceModified = ''
              and CityFileTestStatus = 'C'
                then 'A'
        else '' end as mdc_kpi_filter_val
      )                                                                              as MDChgProcKPIStdznStatus,

      /* Associations */
      _BPProtectedAddress,
      _StandardAddrUsage,
      _BusinessPartnerAddressUsage,
      _BusinessPartnerPhoneNumber,
      _BusinessPartnerMobileNumber,
      _BusinessPartnerEmailAddress,
      _BusinessPartnerFaxNumber,
      _BusinessPartnerWebsiteURL,
      _BusinessPartnerAddressScrOrg,
      _BusinessPartnerAddressScrGrp,
      _BusinessPartnerAddressScrPers,
      _BusinessPartner,
      _Country,
      _CountryText,
      _Region,
      _Language,
      _CommType,
      _TimeZone,
      _TransportZone,
      _POBoxCountry,
      _POBoxRegion,
      _DeliveryService,
      _AddressNonDeliverableReason,
      _PostBoxNonDeliverableReason,
      _StandardPhoneNumber,
      _StandardMobileNumber,
      _StandardFaxNumber,
      _StandardEmailAddress,
      _StandardWebsiteURL,
      _RecordType,
      _KPIUpdateStatusText,
      _RecordMessages,
      _Step,
      _AddrInfoMgmtOut,
      _StdStatus
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPADDRINFOMANAGEMENTOUT",
"I_BPCURRENTDEFAULTADDRESSPROC",
"I_BUSINESSPARTNERADDRESSPROC",
"I_MDCHGPROCESSSTEPTP"
],
"ASSOCIATED":
[
"I_ADDRESSNONDELIVERABLEREASON",
"I_BPADDRINFOMANAGEMENTOUT",
"I_BPCURRENTDEFAULTADDRESSPROC",
"I_BPFAXNUMBERPROCESSTP",
"I_BPPROCESSKPIRECORDTYPE",
"I_BPSCRIPTEDPERSADDRPROCTP",
"I_BUSINESSPARTNERPROCESSTP",
"I_BUSPARTADDRESSUSAGEPROCTP",
"I_BUSPARTCOMMMDMTYPEVH",
"I_BUSPARTDELIVSRVCVH",
"I_BUSPARTEMAILADDRESSPROCTP",
"I_BUSPARTMOBILENUMBERPROCTP",
"I_BUSPARTPROTECTEDADDRESSPROC",
"I_BUSPARTSCRIPTEDGRPADDRPROCTP",
"I_BUSPARTSCRIPTEDORGADDRPROCTP",
"I_BUSPARTTELEPHONENUMBERPROCTP",
"I_BUSPARTWEBSITEURLPROCTP",
"I_BUSPARTWEBSITEURLTP_2",
"I_COUNTRY",
"I_COUNTRYTEXT",
"I_LANGUAGETEXT",
"I_MDCHANGEPROCESSKPIROWVH",
"I_MDCHGPROCESSSTEPTP",
"I_MDCHGPROCKPIFILTERSTDZNSTS",
"I_MDCHGPROCRECORDMESSAGES",
"I_REGION",
"I_TIMEZONE",
"I_TRANSPORTATION_ZONE_TEXT"
],
"BASE":
[
"I_BUSINESSPARTNERADDRESSPROC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/