I_BusinessPartnerAddressProc

@AbapCatalog.sqlViewName: 'IBPADDRPROC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm : #SESSION_VARIABLE
@EndUserText.label: 'Core View: Bus Part Address (Process)'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.viewType: #BASIC
define view I_BusinessPartnerAddressProc
  as select from           but020_prc
    left outer to one join but_adrc_prc on  but020_prc.process_id        = but_adrc_prc.process_id
                                        and but020_prc.process_step_no   = but_adrc_prc.process_step_no
                                        and but020_prc.source_system     = but_adrc_prc.source_system
                                        and but020_prc.source_id         = but_adrc_prc.source_id
                                        and but020_prc.source_addrnumber = but_adrc_prc.source_addrnumber
                                        and but020_prc.nation            = but_adrc_prc.nation

  association [1..1] to I_BusinessPartnerProcess      as _BusinessPartner    on  but020_prc.process_id      = _BusinessPartner.MasterDataChangeProcess
                                                                             and but020_prc.process_step_no = _BusinessPartner.MDChgProcessStep
                                                                             and but020_prc.source_system   = _BusinessPartner.MDChgProcessSrceSystem
                                                                             and but020_prc.source_id       = _BusinessPartner.MDChgProcessSrceObject
  association [0..1] to I_BusPartProtectedAddressProc as _BPProtectedAddress on  but020_prc.process_id      = _BPProtectedAddress.MasterDataChangeProcess
                                                                             and but020_prc.process_step_no = _BPProtectedAddress.MDChgProcessStep
                                                                             and but020_prc.source_system   = _BPProtectedAddress.MDChgProcessSrceSystem
                                                                             and but020_prc.source_id       = _BPProtectedAddress.MDChgProcessSrceObject
{
      //but020_prc

  key but020_prc.process_id                 as MasterDataChangeProcess,
  key but020_prc.process_step_no            as MDChgProcessStep,
  key but020_prc.source_system              as MDChgProcessSrceSystem,
  key but020_prc.source_id                  as MDChgProcessSrceObject,
  key but020_prc.source_addrnumber          as AddressNumber,
      partner                               as BusinessPartner,
      xdfadr                                as StandardUsage,
      but020_prc.address_guid               as BusinessPartnerAddressUUID,
      addr_valid_from                       as ValidityStartDate,
      addr_valid_to                         as ValidityEndDate,
      //but_adrc_prc

      title                                 as FormOfAddress,
      name1                                 as BusinessPartnerName1,
      name2                                 as BusinessPartnerName2,
      name3                                 as BusinessPartnerName3,
      name4                                 as BusinessPartnerName4,
      name_co                               as CareOfName,
      city1                                 as CityName,
      city2                                 as DistrictName,
      city_code                             as CityNumber,
      home_city                             as HomeCityName,
      chckstatus                            as CityFileTestStatus,
      post_code1                            as PostalCode,
      post_code2                            as POBoxPostalCode,
      post_code3                            as CompanyPostalCode,
      po_box                                as POBox,
      dont_use_p                            as AddressPostBoxUnusable,
      po_box_num                            as POBoxIsWithoutNumber,
      po_box_loc                            as POBoxDeviatingCityName,
      po_box_reg                            as POBoxDeviatingRegion,
      po_box_cty                            as POBoxDeviatingCountry,
      transpzone                            as TransportZone,
      street                                as StreetName,
      dont_use_s                            as AddressStreetUnusable,
      house_num1                            as HouseNumber,
      house_num2                            as HouseNumberSupplementText,
      str_suppl1                            as StreetPrefixName,
      str_suppl2                            as AdditionalStreetPrefixName,
      str_suppl3                            as StreetSuffixName,
      location                              as AdditionalStreetSuffixName,
      building                              as Building,
      floor                                 as Floor,
      roomnumber                            as RoomNumber,
      country                               as Country,
      langu                                 as CorrespondenceLanguage,
      region                                as Region,
      sort1                                 as SearchTerm1,
      sort2                                 as SearchTerm2,
      deflt_comm                            as PrfrdCommMediumType,
      tel_number                            as PhoneNumber,
      fax_number                            as AddressFaxNumber,
      mc_city1                              as CitySearch,
      mc_street                             as StreetSearch,
      time_zone                             as AddressTimeZone,
      taxjurcode                            as TaxJurisdiction,
      po_box_lobby                          as POBoxLobbyName,
      deli_serv_type                        as DeliveryServiceTypeCode,
      deli_serv_number                      as DeliveryServiceNumber,
      county_code                           as CountyCode,
      county                                as BPCountyText,
      but_adrc_prc.source_modified          as MDChgProcessSourceModified,
      but_adrc_prc.source_modification_blip as MDChgProcessSourceModifBinary,
      but020_prc.source_modification_blip   as MDChgProcessSourceModif2Binary,
      but_adrc_prc.source_recency           as MDChgProcSrceLastChgdDateTime,

      _BusinessPartner,
      _BPProtectedAddress
}
where
  but020_prc.nation = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"BUT020_PRC",
"BUT_ADRC_PRC"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERPROCESS",
"I_BUSPARTPROTECTEDADDRESSPROC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/