@AbapCatalog.sqlViewName: 'IBPWEBPROCCHG'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BP Website Process Changes'
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XXL
@VDM.viewType: #TRANSACTIONAL
@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_BPWebsiteURLProcessChanges
as select from I_BusPartWebsiteURLProc as _Current
left outer to one join I_MDChangeProcessModelTable as _ModelTable on _ModelTable.MDChgProcessModelTableName = 'ADR12'
and _ModelTable.MDChgProcessSrceObjectTypeCode = '147'
association [1..1] to I_BusinessPartnerProcess as _BusinessPartner on $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
and $projection.MDChgProcessStep = _BusinessPartner.MDChgProcessStep
and $projection.MDChgProcessSrceSystem = _BusinessPartner.MDChgProcessSrceSystem
and $projection.MDChgProcessSrceObject = _BusinessPartner.MDChgProcessSrceObject
association [0..1] to I_BusPartProtectedAddressProc as _BPProtectedAddress on _Current.MasterDataChangeProcess = _BPProtectedAddress.MasterDataChangeProcess
and _Current.MDChgProcessStep = _BPProtectedAddress.MDChgProcessStep
and _Current.MDChgProcessSrceSystem = _BPProtectedAddress.MDChgProcessSrceSystem
and _Current.MDChgProcessSrceObject = _BPProtectedAddress.MDChgProcessSrceObject
association [1..1] to I_BusinessPartnerAddressProc as _Address on $projection.MasterDataChangeProcess = _Address.MasterDataChangeProcess
and $projection.MDChgProcessStep = _Address.MDChgProcessStep
and $projection.MDChgProcessSrceSystem = _Address.MDChgProcessSrceSystem
and $projection.MDChgProcessSrceObject = _Address.MDChgProcessSrceObject
and $projection.AddressNumber = _Address.AddressNumber
{
key _Current.MasterDataChangeProcess,
key _Current.MDChgProcessStep,
key _Current.MDChgProcessSrceSystem,
key _Current.MDChgProcessSrceObject,
key _Current.AddressNumber,
key _Current.OrdinalNumber,
// key _Current.ValidityStartDateTime,
key _ModelTable.MDChgProcessModelTableName,
key cast ( '' as fieldname ) as MDChangeProcessModelFieldName,
key cast( concat(
concat(
concat(_Current.MDChgProcessSrceSystem, concat( '%%', _Current.MDChgProcessSrceObject)),
concat( '%%', _Current.AddressNumber )),
concat( '%%', _Current.OrdinalNumber )) as abap.char(1000) ) as MDChgProcessRecordObjectID,
_ModelTable.MDChangeProcModelTableDesc,
cast ('' as as4text ) as MDChangeProcessModelFieldDesc,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
cast( 'BusinessPartnerWebsite' as fieldname ) as MDChgProcModelNodeExternalName,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
cast( 'I_BusPartWebsiteURLProcTP' as fieldname ) as MDChgProcModTableExternalName,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
cast( '' as fieldname ) as MDChgProcModFieldExternalName,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
cast( '' as abap.char( 260 ) ) as MDChgProcCurrentAttributeValue,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
cast( '' as abap.char( 260 ) ) as MDChgProcPrevAttributeValue,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
cast( '' as boolean ) as MDChgProcessAttributeIsChanged,
_Current.MDChgProcessSourceModified,
concat_with_space(
concat(
concat_with_space(
concat_with_space(
concat_with_space(
concat_with_space(_Address.StreetName,_Address.HouseNumber,1)
,_Address.PostalCode,1)
,_Address.CityName,1)
,_Address.Country,1),
','),
// _Current.WebsiteURL
_Current.SearchURLAddress
,1) as MDChgProcessRecordObjectText,
_BusinessPartner,
_BPProtectedAddress,
_Address
}
where
_Current.MDChgProcessSourceModified = 'I'
or _Current.MDChgProcessSourceModified = 'D'
union all select from I_BusPartWebsiteURLProc as _Current
left outer to many join I_MDChangeProcessModelField as _ModelField on _ModelField.MDChgProcessModelTableName = 'ADR12'
and _ModelField.MDChgProcessSrceObjectTypeCode = '147'
association [1..1] to I_BusinessPartnerProcess as _BusinessPartner on $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
and $projection.MDChgProcessStep = _BusinessPartner.MDChgProcessStep
and $projection.MDChgProcessSrceSystem = _BusinessPartner.MDChgProcessSrceSystem
and $projection.MDChgProcessSrceObject = _BusinessPartner.MDChgProcessSrceObject
association [0..1] to I_BusPartProtectedAddressProc as _BPProtectedAddress on _Current.MasterDataChangeProcess = _BPProtectedAddress.MasterDataChangeProcess
and _Current.MDChgProcessStep = _BPProtectedAddress.MDChgProcessStep
and _Current.MDChgProcessSrceSystem = _BPProtectedAddress.MDChgProcessSrceSystem
and _Current.MDChgProcessSrceObject = _BPProtectedAddress.MDChgProcessSrceObject
association [1..1] to I_BusinessPartnerAddressProc as _Address on $projection.MasterDataChangeProcess = _Address.MasterDataChangeProcess
and $projection.MDChgProcessStep = _Address.MDChgProcessStep
and $projection.MDChgProcessSrceSystem = _Address.MDChgProcessSrceSystem
and $projection.MDChgProcessSrceObject = _Address.MDChgProcessSrceObject
and $projection.AddressNumber = _Address.AddressNumber
{
//I_BusinessPartnerProcess
key _Current.MasterDataChangeProcess,
key _Current.MDChgProcessStep,
key _Current.MDChgProcessSrceSystem,
key _Current.MDChgProcessSrceObject,
key _Current.AddressNumber,
key _Current.OrdinalNumber,
// key _Current.ValidityStartDateTime,
key _ModelField.MDChgProcessModelTableName,
key _ModelField.MDChangeProcessModelFieldName,
key cast( concat(
concat(
concat(_Current.MDChgProcessSrceSystem, concat( '%%', _Current.MDChgProcessSrceObject)),
concat( '%%', _Current.AddressNumber )),
concat( '%%', _Current.OrdinalNumber )) as abap.char(1000) ) as MDChgProcessRecordObjectID,
_ModelField.MDChangeProcModelTableDesc,
_ModelField.MDChangeProcessModelFieldDesc,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
cast( 'BusinessPartnerWebsite' as fieldname ) as MDChgProcModelNodeExternalName,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
cast( 'I_BusPartWebsiteURLProcTP' as fieldname ) as MDChgProcModTableExternalName,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
cast( '' as fieldname ) as MDChgProcModFieldExternalName,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
cast( '' as abap.char( 260 ) ) as MDChgProcCurrentAttributeValue,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
cast( '' as abap.char( 260 ) ) as MDChgProcPrevAttributeValue,
@ObjectModel.readOnly: true
@ObjectModel.virtualElement: true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_BP_BUPAPROCTP2_CALC_EXIT'
cast( '' as boolean ) as MDChgProcessAttributeIsChanged,
_Current.MDChgProcessSourceModified,
concat_with_space(
concat(
concat_with_space(
concat_with_space(
concat_with_space(
concat_with_space(_Address.StreetName,_Address.HouseNumber,1)
,_Address.PostalCode,1)
,_Address.CityName,1)
,_Address.Country,1),
','),
// _Current.WebsiteURL
_Current.SearchURLAddress
,1) as MDChgProcessRecordObjectText,
_BusinessPartner,
_BPProtectedAddress,
_Address
}
where
_Current.MDChgProcessSourceModified = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSPARTNERADDRESSPROC",
"I_BUSPARTWEBSITEURLPROC",
"I_MDCHANGEPROCESSMODELFIELD",
"I_MDCHANGEPROCESSMODELTABLE"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERADDRESSPROC",
"I_BUSINESSPARTNERPROCESS",
"I_BUSPARTPROTECTEDADDRESSPROC"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/