I_BPCustomerTaxIndicatorGov

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'BP Customer Tax Indicator Governance'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #XL,
  dataClass: #MIXED
}
@VDM.viewType: #TRANSACTIONAL
define view entity I_BPCustomerTaxIndicatorGov
  as select from I_BPCustomerTaxIndicatorProc
  association [1..1] to I_BPCustomerGov           as _Customer                on  $projection.MasterDataChangeProcess = _Customer.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _Customer.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _Customer.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _Customer.MDChgProcessSrceObject

  association [0..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key DepartureCountry,
  key CustomerTaxCategory,
      BPAssignmentID,
      Customer,
      CustomerTaxClassification,

      cast(
        case
          when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000'
              or MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000'
            then 'X'
          else ' '
        end as abap_boolean preserving type
      ) as MasterDataIsCurrent,

      /* Associations */
      _Customer
}

union all select from I_BPCustomerTaxIndicator
association [1..1] to I_BPCustomerGov             as _Customer                  on  $projection.MasterDataChangeProcess = _Customer.MasterDataChangeProcess
                                                                                and $projection.MDChgProcessStep        = _Customer.MDChgProcessStep
                                                                                and $projection.MDChgProcessSrceSystem  = _Customer.MDChgProcessSrceSystem
                                                                                and $projection.MDChgProcessSrceObject  = _Customer.MDChgProcessSrceObject

association [1..1] to I_CustomerToBusinessPartner as _CustomerToBusinessPartner on  $projection.Customer = _CustomerToBusinessPartner.Customer
{
  key '000000000000'                                              as MasterDataChangeProcess,
  key '0000'                                                      as MDChgProcessStep,
  key ''                                                          as MDChgProcessSrceSystem,
  key _CustomerToBusinessPartner._BusinessPartner.BusinessPartner as MDChgProcessSrceObject,
  key DepartureCountry,
  key CustomerTaxCategory,
      '000000000002'                                              as BPAssignmentID,
      Customer,
      CustomerTaxClassification,
      cast( 'X' as abap_boolean preserving type )                 as MasterDataIsCurrent,

      /* Associations */
      _Customer
}
where 
  _CustomerToBusinessPartner._BusinessPartner.BusinessPartner is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPCUSTOMERTAXINDICATOR",
"I_BPCUSTOMERTAXINDICATORPROC",
"I_BUSINESSPARTNER",
"I_CUSTOMERTOBUSINESSPARTNER",
"I_MASTERDATACHANGEPROCESS"
],
"ASSOCIATED":
[
"I_BPCUSTOMERGOV"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/