I_BPCustomerGov

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'BP Customer Data Governance'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #TRANSACTIONAL
}
@VDM.viewType: #COMPOSITE
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view entity I_BPCustomerGov
  as select from I_BPCustomerProcess

  association [1..1] to I_BusinessPartnerGov      as _BusinessPartnerGov      on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                              and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                              and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                              and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject

  association [0..1] to I_MasterDataChangeProcess as _MasterDataChangeProcess on  $projection.MasterDataChangeProcess = _MasterDataChangeProcess.MasterDataChangeProcess

{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
      BPAssignmentID,
      Customer,
      //      Country,

      //      Region,

      OrderIsBlockedForCustomer,
      ExpressTrainStationName,
      TrainStationName,
      AuthorizationGroup,
      BillingIsBlockedForCustomer,
      FiscalAddress,
      AlternativePayerAccount,
      CustomerCorporateGroup,
      CustomerAccountGroup,
      CustomerClassification,
      Supplier,
      DeliveryIsBlocked,
      DeletionIndicator,
      NielsenRegion,
      County,
      CityCode,
      PostingIsBlocked,
      VATLiability,
      AlternativePayeeIsAllowed,
      IndustryCode1,
      IndustryCode2,
      IndustryCode3,
      IndustryCode4,
      IndustryCode5,
      FreeDefinedAttribute01,
      FreeDefinedAttribute02,
      FreeDefinedAttribute03,
      FreeDefinedAttribute04,
      FreeDefinedAttribute05,
      FreeDefinedAttribute06,
      FreeDefinedAttribute07,
      FreeDefinedAttribute08,
      FreeDefinedAttribute09,
      FreeDefinedAttribute10,
      DataMediumExchangeIndicator,
      CustomerConditionGroup1,
      CustomerConditionGroup2,
      CustomerConditionGroup3,
      CustomerConditionGroup4,
      CustomerConditionGroup5,
      ResponsibleType,
      TaxInvoiceRepresentativeName,
      BusinessType,
      IndustryType,

      cast(
      case when MDChgProcessStep = _MasterDataChangeProcess.MDChgProcessCurrentStepNumber and _MasterDataChangeProcess.MDChgProcessCurrentStepNumber <> '0000' or
            MDChgProcessStep = '0001' and  _MasterDataChangeProcess.MDChgProcessCurrentStepNumber = '0000' then 'X'
       else ' '
      end as abap_boolean preserving type
      ) as MasterDataIsCurrent,

      DataControllerSet,
      DataController1,
      DataController2,
      DataController3,
      DataController4,
      DataController5,
      DataController6,
      DataController7,
      DataController8,
      DataController9,
      DataController10,

      _BusinessPartnerGov
}
where
  MDChgProcessSourceModified <> 'D'

union all

select from I_Customer

association [1..1] to I_BusinessPartnerGov        as _BusinessPartnerGov        on  $projection.MasterDataChangeProcess = _BusinessPartnerGov.MasterDataChangeProcess
                                                                                and $projection.MDChgProcessStep        = _BusinessPartnerGov.MDChgProcessStep
                                                                                and $projection.MDChgProcessSrceSystem  = _BusinessPartnerGov.MDChgProcessSrceSystem
                                                                                and $projection.MDChgProcessSrceObject  = _BusinessPartnerGov.MDChgProcessSrceObject

association [1..1] to I_CustomerToBusinessPartner as _CustomerToBusinessPartner on  $projection.Customer = _CustomerToBusinessPartner.Customer

{
  key  '000000000000'                                              as MasterDataChangeProcess,
  key  '0000'                                                      as MDChgProcessStep,
  key  ''                                                          as MDChgProcessSrceSystem,
  key  _CustomerToBusinessPartner._BusinessPartner.BusinessPartner as MDChgProcessSrceObject,
       '000000000002'                                              as BPAssignmentID,
       Customer,
       //       Country,

       //       Region,

       OrderIsBlockedForCustomer,
       ExpressTrainStationName,
       TrainStationName,
       AuthorizationGroup,
       BillingIsBlockedForCustomer,
       FiscalAddress,
       AlternativePayerAccount,
       CustomerCorporateGroup,
       CustomerAccountGroup,
       CustomerClassification,
       Supplier,
       DeliveryIsBlocked,
       DeletionIndicator,
       NielsenRegion,
       County,
       CityCode,
       PostingIsBlocked,
       VATLiability,
       AlternativePayeeIsAllowed,
       IndustryCode1,
       IndustryCode2,
       IndustryCode3,
       IndustryCode4,
       IndustryCode5,
       FreeDefinedAttribute01,
       FreeDefinedAttribute02,
       FreeDefinedAttribute03,
       FreeDefinedAttribute04,
       FreeDefinedAttribute05,
       FreeDefinedAttribute06,
       FreeDefinedAttribute07,
       FreeDefinedAttribute08,
       FreeDefinedAttribute09,
       FreeDefinedAttribute10,
       DataMediumExchangeIndicator,
       CustomerConditionGroup1,
       CustomerConditionGroup2,
       CustomerConditionGroup3,
       CustomerConditionGroup4,
       CustomerConditionGroup5,
       ResponsibleType,
       TaxInvoiceRepresentativeName,
       BusinessType,
       IndustryType,

       cast( 'X' as abap_boolean preserving type )                 as MasterDataIsCurrent,



       DataControllerSet,
       DataController1,
       DataController2,
       DataController3,
       DataController4,
       DataController5,
       DataController6,
       DataController7,
       DataController8,
       DataController9,
       DataController10,

       _BusinessPartnerGov
}
where
  _CustomerToBusinessPartner._BusinessPartner.BusinessPartner is not initial
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPCUSTOMERPROCESS",
"I_BUSINESSPARTNER",
"I_CUSTOMER",
"I_CUSTOMERTOBUSINESSPARTNER",
"I_MASTERDATACHANGEPROCESS"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNERGOV"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/