I_BPContactFaxNmbrTP

@AbapCatalog.sqlViewName: 'IBPCPFAXNMBRTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm : #SESSION_VARIABLE
@EndUserText.label: 'BO view for BP contact Fax number'
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL

@ObjectModel.writeEnabled: true
@ObjectModel.writeDraftPersistence: 'BPCP_FAX_D'

@ObjectModel.createEnabled
@ObjectModel.deleteEnabled
@ObjectModel.updateEnabled

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
define view I_BPContactFaxNmbrTP  as select from I_BpContactToAddress as ContactPerson
    inner join I_AddressFaxNumber_2 as FaxNumber on  ContactPerson.AddressID = FaxNumber.AddressID
                                               and ContactPerson.PersonNumber = FaxNumber.AddressPersonID

 association [1..1] to I_BusinessPartnerTP as _BusinessPartner on  $projection.BusinessPartner1 = _BusinessPartner.BusinessPartner
 
 association [1..1] to I_BPContactAddressTP as _BPContactAddress on  $projection.BusinessPartner1     = _BPContactAddress.BusinessPartner1
                                                                 and $projection.BusinessPartner2     = _BPContactAddress.BusinessPartner2
                                                                 and $projection.RelationshipNumber     = _BPContactAddress.RelationshipNumber
                                                                 and $projection.ValidityEndDate      = _BPContactAddress.ValidityEndDate
                                                                 and $projection.AddressID            = _BPContactAddress.AddressID                             

  association [0..1] to I_BusPartTelCountryPrefix as _CountryPrefix on  $projection.FaxCountry = _CountryPrefix.Country

{
      @Search.defaultSearchElement: true
  key ContactPerson.BusinessPartnerCompany    as BusinessPartner1,
      @Search.defaultSearchElement: true
  key ContactPerson.BusinessPartnerPerson     as BusinessPartner2,
  //key _BusPartRelationship.RelationshipCategory,

  key ContactPerson.RelationshipNumber,
  key ContactPerson.ValidityEndDate,
  key ContactPerson.AddressID,
  key FaxNumber.CommMediumSequenceNumber as OrdinalNumber,
  
    
   ContactPerson.BusinessPartnerCompany  as BusinessPartner1ForEdit,
   ContactPerson.BusinessPartnerPerson   as BusinessPartner2ForEdit,  
   ContactPerson.ValidityEndDate as ValidityEndDateForEdit,
   ContactPerson.AddressID as AddressIDForEdit,
   FaxNumber.CommMediumSequenceNumber as OrdinalNumberForEdit,
   ContactPerson.RelationshipNumber as RelationshipNumberForEdit,
   
      FaxNumber.FaxNumberCountry as FaxCountry,
      @ObjectModel.readOnly: true
      _CountryPrefix.TelephoneCountryPrefix    as CountryDialingCode,
      FaxNumber.FaxNumberIsCurrentDefault      as IsDefaultFaxNumber,
      FaxNumber.CommLineNotForUnsolicitedCntct as CommNumberIsNotUsed,
      FaxNumber.FaxAreaCodeSubscriberNumber    as FaxNumber,
      FaxNumber.FaxExtensionNumber             as FaxNumberExtension,
      FaxNumber._AddressCommunicationRemark.CommunicationRemarkText as AddressCommunicationRemarkText,

      /* Associations */ 
      _BusinessPartnerCompany   as _BusinessPartner1,
      _BusinessPartnerPerson    as _BusinessPartner2,
      _CountryPrefix,
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
      _BusinessPartner,
      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
      _BPContactAddress
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESSCOMMUNICATIONREMARK_2",
"I_ADDRESSFAXNUMBER_2",
"I_BPCONTACTTOADDRESS",
"I_BUSPARTTELCOUNTRYPREFIX"
],
"ASSOCIATED":
[
"I_BPCONTACTADDRESSTP",
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERTP",
"I_BUSPARTTELCOUNTRYPREFIX"
],
"BASE":
[
"I_BPCONTACTTOADDRESS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/