I_BPContactAddressTP

@AbapCatalog.sqlViewName: 'IBPCPADDTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@ClientHandling.algorithm : #SESSION_VARIABLE
@EndUserText.label: 'TP View for BP Contact Person Address'

@ObjectModel.writeDraftPersistence: 'BUPA_CPADR_D'
@ObjectModel.draftEnabled:true
@ObjectModel.writeEnabled: true
@ObjectModel.createEnabled
@ObjectModel.deleteEnabled
@ObjectModel.updateEnabled

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL

define view I_BPContactAddressTP as select from I_BpContactToAddress 
  
  association [1..1] to I_BusinessPartnerTP        as _BusinessPartner         on  $projection.BusinessPartner1 = _BusinessPartner.BusinessPartner
 
  association [1..1] to I_BusinessPartnerContactTP  as _BPContactAddress on  $projection.BusinessPartner1 = _BPContactAddress.BusinessPartner
                                                                             and $projection.BusinessPartner2 = _BPContactAddress.BusinessPartnerPerson
                                                                             and $projection.RelationshipNumber = _BPContactAddress.RelationshipNumber
                                                                             and $projection.ValidityEndDate   = _BPContactAddress.ValidityEndDate
  association [0..*] to I_BPContactEmlAddrTP as _BPContactEmlAddr on  $projection.BusinessPartner1  = _BPContactEmlAddr.BusinessPartner1
                                                                      and $projection.BusinessPartner2  = _BPContactEmlAddr.BusinessPartner2                                                                    
                                                                      and $projection.RelationshipNumber    = _BPContactEmlAddr.RelationshipNumber
                                                                      and $projection.ValidityEndDate   = _BPContactEmlAddr.ValidityEndDate
                                                                      and $projection.AddressID = _BPContactEmlAddr.AddressID
 
  association [0..*] to I_BPContactTelNmbrTP as _BPContactTelNmbr on  $projection.BusinessPartner1  = _BPContactTelNmbr.BusinessPartner1
                                                                      and $projection.BusinessPartner2  = _BPContactTelNmbr.BusinessPartner2
                                                                      and $projection.RelationshipNumber    = _BPContactTelNmbr.RelationshipNumber
                                                                      and $projection.ValidityEndDate   = _BPContactTelNmbr.ValidityEndDate
                                                                      and $projection.AddressID = _BPContactTelNmbr.AddressID
  
  association [0..*] to I_BPContactMblNmbrTP as _BPContactMblNmbr on  $projection.BusinessPartner1  = _BPContactMblNmbr.BusinessPartner1
                                                                      and $projection.BusinessPartner2  = _BPContactMblNmbr.BusinessPartner2
                                                                      and $projection.RelationshipNumber    = _BPContactMblNmbr.RelationshipNumber
                                                                      and $projection.ValidityEndDate   = _BPContactMblNmbr.ValidityEndDate
                                                                      and $projection.AddressID = _BPContactMblNmbr.AddressID
  
  association [0..*] to I_BPContactFaxNmbrTP as _BPContactFaxNmbr on  $projection.BusinessPartner1  = _BPContactFaxNmbr.BusinessPartner1
                                                                      and $projection.BusinessPartner2  = _BPContactFaxNmbr.BusinessPartner2
                                                                      and $projection.RelationshipNumber    = _BPContactFaxNmbr.RelationshipNumber
                                                                      and $projection.ValidityEndDate   = _BPContactFaxNmbr.ValidityEndDate
                                                                      and $projection.AddressID = _BPContactFaxNmbr.AddressID
  
  association [0..*] to I_BPContactWbsteURLTP as _BPContactWbsteURL  on   $projection.BusinessPartner1  = _BPContactWbsteURL.BusinessPartner1
                                                                      and $projection.BusinessPartner2  = _BPContactWbsteURL.BusinessPartner2
                                                                      and $projection.RelationshipNumber    = _BPContactWbsteURL.RelationshipNumber
                                                                      and $projection.ValidityEndDate   = _BPContactWbsteURL.ValidityEndDate
                                                                      and $projection.AddressID = _BPContactWbsteURL.AddressID
  
{
    @Search.defaultSearchElement: true
    key BusinessPartnerCompany as BusinessPartner1,
    @Search.defaultSearchElement: true
    key BusinessPartnerPerson as BusinessPartner2,
    //key _BusPartRelationship.RelationshipCategory,

  
    @Search.defaultSearchElement: true
    key RelationshipNumber,
    key ValidityEndDate,
    key AddressID,
    
    BusinessPartnerCompany as BusinessPartner1ForEdit,
    BusinessPartnerPerson as BusinessPartner2ForEdit,
    ValidityEndDate as ValidityEndDateForEdit,
    @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
    AddressID as AddressIDForEdit,
    RelationshipNumber as RelationshipNumberForEdit,
    
    IsDefaultAddress,
    ContactRelationshipFunction,
    ContactRelationshipDepartment,
    Floor,
    Building,
    RoomNumber,
    PrfrdCommMediumType,
    CorrespondenceShortName,
    InhouseMail,
    
    concat_with_space(_BPCompanyPostalAddress.HouseNumber,
    concat_with_space(_BPCompanyPostalAddress.StreetName,
    concat_with_space(_BPCompanyPostalAddress.CityName,
    concat_with_space(_BPCompanyPostalAddress.PostalCode,_BPCompanyPostalAddress.Country,1),1),1),1) as FormattedAddress,
    _BPCompanyPostalAddress.FormOfAddress,
    _BPCompanyPostalAddress.FullName,
    _BPCompanyPostalAddress.HouseNumber,
    _BPCompanyPostalAddress.StreetName,
    _BPCompanyPostalAddress.CityName,
    _BPCompanyPostalAddress.PostalCode,
    _BPCompanyPostalAddress.Region,
    _BPCompanyPostalAddress.Country,
    _BPCompanyPostalAddress.AddressTimeZone,

    /* Associations */
    _BusinessPartnerCompany as _BusinessPartner1,
    _BusinessPartnerPerson as _BusinessPartner2,
   // _BPRelshpContactPerson,

   // _BusPartRelationship,

     @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
    _BPContactEmlAddr,
     @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
    _BPContactTelNmbr,
     @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
     _BusinessPartner,
     @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
     _BPContactMblNmbr,
     @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
     _BPContactFaxNmbr,
     @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
    _BPContactWbsteURL,
    @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
    _BPContactAddress
      
}
where AddressRepresentationCode = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPCONTACTTOADDRESS",
"I_BUSINESSPARTNERADDRESS"
],
"ASSOCIATED":
[
"I_BPCONTACTEMLADDRTP",
"I_BPCONTACTFAXNMBRTP",
"I_BPCONTACTMBLNMBRTP",
"I_BPCONTACTTELNMBRTP",
"I_BPCONTACTWBSTEURLTP",
"I_BUSINESSPARTNER",
"I_BUSINESSPARTNERCONTACTTP",
"I_BUSINESSPARTNERTP"
],
"BASE":
[
"I_BPCONTACTTOADDRESS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/