I_BPAddlOwnerSentRecordTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'BP Additional Owner Sent Record - TP'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #XXL,
  dataClass: #MIXED
}
@VDM.viewType: #TRANSACTIONAL
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define view entity I_BPAddlOwnerSentRecordTP
  as select from            I_BusinessPartnerProcess as BusinessPartner
    inner join              I_MDChgProcessStep       as _Step             on  BusinessPartner.MasterDataChangeProcess = _Step.MasterDataChangeProcess
                                                                          and BusinessPartner.MDChgProcessStep        = _Step.MDChgProcessStep
    left outer to many join I_MDFederationAddlOwnr   as _AdditionalOwners on  BusinessPartner.MasterDataChangeProcess          = _AdditionalOwners.MasterDataChangeProcess
                                                                          and BusinessPartner.MDChgProcessStep                 = _AdditionalOwners.MDChgProcessStep
                                                                          and BusinessPartner.MDChgProcessSrceSystem           = _AdditionalOwners.MDChgProcessSrceSystem
                                                                          and BusinessPartner.MDChgProcessSrceObject           = _AdditionalOwners.MDChgProcessSrceObject
                                                                          and _AdditionalOwners.MDChgProcessSrceObjectTypeCode = '147'
  association        to parent I_BPAdditionalOwnerOverviewTP as _AdditionalOwnersOverview on  _AdditionalOwnersOverview.MasterDataChangeProcess = $projection.MasterDataChangeProcess
                                                                                          and _AdditionalOwnersOverview.MDChgProcessStep        = $projection.MDChgProcessStep
                                                                                          and _AdditionalOwnersOverview.MDChgProcessSrceSystem  = $projection.MDChgProcessSrceSystem
                                                                                          and _AdditionalOwnersOverview.MDChgProcessSrceObject  = $projection.MDChgProcessSrceObject
  association [0..1] to I_MDChgProcKPIFltrFederation         as _FederationStatusText     on  $projection.MDChgProcessFederationStatus = _FederationStatusText.MDChangeProcKPIValueKey
  association [0..1] to I_AddlOwnrReplicationStatus          as _ReplicationStatus        on  $projection.MasterDataChangeProcess               = _ReplicationStatus.MasterDataChangeProcess
                                                                                          and $projection.MDChgProcessStep                      = _ReplicationStatus.MDChgProcessStep
                                                                                          and $projection.MDChgProcessFederationDRFKey          = _ReplicationStatus.MDChgProcessFederationDRFKey
                                                                                          and $projection.MDChgProcessAddlOwnerSystem           = _ReplicationStatus.BusinessSystemName
                                                                                          and $projection.DataReplicationFrameworkRun           = _ReplicationStatus.DataReplicationFrameworkRun
                                                                                          and _ReplicationStatus.MDChgProcessSrceObjectTypeCode = 'FED_147'
  association [0..*] to I_BPReplicationStatusText            as _ReplicationStatusText  on  $projection.DRFReplicationStatus = _ReplicationStatusText.BPReplicationStatus
{
  key BusinessPartner.MasterDataChangeProcess,
  key BusinessPartner.MDChgProcessStep,
  key BusinessPartner.MDChgProcessSrceSystem,
  key BusinessPartner.MDChgProcessSrceObject,
  key _AdditionalOwners.MDChgProcessAddlOwnerSystem,
      cast(
      case
        when _AdditionalOwners.MasterDataChangeProcess is null then 'N'
        when _AdditionalOwners.MDAddlOwnerHasReportedBack = 'X' then 'F'
      else 'P'
      end as mdc_fed_addowner_status preserving type) as MDChgProcessFederationStatus,
      cast(
        case
          when _AdditionalOwners.MasterDataChangeProcess is null then 0
          when _AdditionalOwners.MDAddlOwnerHasReportedBack = 'X' then 3
          else 2
      end as int1 preserving type)                    as MDChgProcFederationStsCritlty,
      _AdditionalOwners.MDLastSentToAddlOwnerDteTme,
      _AdditionalOwners.DataReplicationFrameworkRun,
      _AdditionalOwners.MDChgProcessFederationDRFKey,
      BusinessPartner.AuthorizationGroup,
      @Semantics.booleanIndicator
      BusinessPartner.IsBusinessPurposeCompleted,

      BusinessPartner.DataControllerSet,
      BusinessPartner.DataController1,
      BusinessPartner.DataController2,
      BusinessPartner.DataController3,
      BusinessPartner.DataController4,
      BusinessPartner.DataController5,
      BusinessPartner.DataController6,
      BusinessPartner.DataController7,
      BusinessPartner.DataController8,
      BusinessPartner.DataController9,
      BusinessPartner.DataController10,

      cast(
        case  
          when _AdditionalOwners.MasterDataChangeProcess is null then ' '
          when _ReplicationStatus.DRFReplicationStatus is null then 'TS'
          else _ReplicationStatus.DRFReplicationStatus
      end as drf_repstat preserving type )            as DRFReplicationStatus,

      _AdditionalOwnersOverview,
      _FederationStatusText,
      _ReplicationStatus,
      _ReplicationStatusText
}
where
  _Step.MDChgProcessStepType = 'FED'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDLOWNRREPLICATIONSTATUS",
"I_BUSINESSPARTNERPROCESS",
"I_MDCHGPROCESSSTEP",
"I_MDFEDERATIONADDLOWNR"
],
"ASSOCIATED":
[
"I_ADDLOWNRREPLICATIONSTATUS",
"I_BPADDITIONALOWNEROVERVIEWTP",
"I_BPREPLICATIONSTATUSTEXT",
"I_MDCHGPROCKPIFLTRFEDERATION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/