I_BPReplicationStatusText

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Text for Replication Status of a Business Partner'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.dataClass: #META
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.dataCategory: #TEXT
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
@ObjectModel.representativeKey: 'BPReplicationStatus'
@Search.searchable: true
@VDM.viewType: #BASIC
define view entity I_BPReplicationStatusText
  as select from dd07t
  association        to parent I_BPReplicationStatus as _BPReplicationStatus on $projection.BPReplicationStatus = _BPReplicationStatus.BPReplicationStatus
  association [0..1] to I_Language                   as _Language            on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type ) as Language,
      @ObjectModel.foreignKey.association: '_BPReplicationStatus'
      @ObjectModel.text.element: ['BPReplicationStatusText']
  key cast( dd07t.domvalue_l as drf_repstat )           as BPReplicationStatus,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                  as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      cast( dd07t.ddtext as val_text preserving type )  as BPReplicationStatusText,
      _BPReplicationStatus,
      _Language
}
where
      dd07t.domname  = 'DRF_REPSTAT'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DD07T"
],
"ASSOCIATED":
[
"I_BPREPLICATIONSTATUS",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/