I_BPAddlCustCompanyCodeTP

@AbapCatalog.sqlViewName: 'IBPADDCCCTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'BO view for Company Code of Customers'
@ObjectModel.writeEnabled: true
@ObjectModel.createEnabled
@ObjectModel.deleteEnabled: 'EXTERNAL_CALCULATION'
@ObjectModel.updateEnabled
@ObjectModel.semanticKey: ['BusinessPartner', 'Customer', 'CompanyCode']
@ObjectModel.writeDraftPersistence: 'BPADDCCC_D'
@ObjectModel.draftEnabled:true
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL

define view I_BPAddlCustCompanyCodeTP
  as select from I_CustomerCompany as BusinessPartnerCustomerCo 
                 inner join I_BPMultipleAssignment as BPMultipleAssignment on BusinessPartnerCustomerCo.Customer = BPMultipleAssignment.BPObjectID
                 left outer join t047 as CompanyCodeDunningControl on BusinessPartnerCustomerCo.CompanyCode = CompanyCodeDunningControl.bukrs

  association [1..1] to I_BusinessPartnerTP as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [1..1] to I_BPAdditionalCustomerTP as _BPAdditionalCustomer on $projection.BusinessPartner = _BPAdditionalCustomer.BusinessPartner
                                                                         and $projection.Customer = _BPAdditionalCustomer.Customer
                                                                         
  association [1..*] to I_BPAddlCustWhldgTaxTP as _BusinessPartnerCustWhdgTax on $projection.BusinessPartner = _BusinessPartnerCustWhdgTax.BusinessPartner
                                                                         and $projection.Customer = _BusinessPartnerCustWhdgTax.Customer
                                                                         and $projection.CompanyCode = _BusinessPartnerCustWhdgTax.CompanyCode
                                                                         
  association [1..*] to I_BPAddlCustDunningTP as _BPAddlCustDunning on $projection.BusinessPartner = _BPAddlCustDunning.BusinessPartner
                                                                         and $projection.Customer = _BPAddlCustDunning.Customer
                                                                         and $projection.CompanyCode = _BPAddlCustDunning.CompanyCode
  
  association [1..1] to I_CompanyCode                 as _Country                   on  $projection.CompanyCode = _Country.CompanyCode
  
{
      key BPMultipleAssignment.BusinessPartner,
      key BusinessPartnerCustomerCo.Customer,
      key BusinessPartnerCustomerCo.CompanyCode,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.CompanyCode     as CompanyCodeForEdit,
      BusinessPartnerCustomerCo.Customer as CustomerForEdit,
      BPMultipleAssignment.BusinessPartner as BusinessPartnerForEdit,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.AccountingClerk,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.ReconciliationAccount,
      BusinessPartnerCustomerCo.AuthorizationGroup,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.CustomerHeadOffice,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.AlternativePayerAccount,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.PaymentBlockingReason,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.InterestCalculationCode,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.InterestCalculationDate,
      BusinessPartnerCustomerCo.IntrstCalcFrequencyInMonths,
      BusinessPartnerCustomerCo.LastInterestCalcRunDate,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.CustomerAccountNote,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.APARToleranceGroup,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.HouseBank,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.ItemIsToBePaidSeparately,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.PaytAdviceIsSentbyEDI,
      BusinessPartnerCustomerCo.PhysicalInventoryBlockInd,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.UserAtCustomer,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.AccountingClerkPhoneNumber,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.AccountingClerkFaxNumber,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.AccountingClerkInternetAddress,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.AccountByCustomer,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.IsToBeLocallyProcessed,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.CollectiveInvoiceVariant,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.LayoutSortingRule,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.PaymentTerms,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.CustomerSupplierClearingIsUsed,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.RecordPaymentHistoryIndicator,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.PaymentMethodsList,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.CashPlanningGroup,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.ValueAdjustmentKey,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BusinessPartnerCustomerCo.KnownOrNegotiatedLeave,     
      _Country.Country, // country field to filter payment methods based on company code

      _Country.CompanyCodeName,
      CompanyCodeDunningControl.xmabe as CompanyCodeDunningIsByDunArea,
      
      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT]
      _BusinessPartner,     
      @ObjectModel.association.type: [#TO_COMPOSITION_PARENT]
      _BPAdditionalCustomer,      
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BusinessPartnerCustWhdgTax,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _BPAddlCustDunning
      
}

where BPMultipleAssignment.IsStandardAssignment <> 'X' and BPMultipleAssignment.BPAssignmentCategory = 'CUST'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPMULTIPLEASSIGNMENT",
"I_COMPANYCODE",
"I_CUSTOMERCOMPANY",
"T047"
],
"ASSOCIATED":
[
"I_BPADDITIONALCUSTOMERTP",
"I_BPADDLCUSTDUNNINGTP",
"I_BPADDLCUSTWHLDGTAXTP",
"I_BUSINESSPARTNERTP",
"I_COMPANYCODE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/