C_BPAddlCustCompanyCode

@AbapCatalog.sqlViewName: 'CBPADDCCC'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@EndUserText.label: 'C view for Customer Company Code'

@Metadata.allowExtensions: true

@ObjectModel.type: #CONSUMPTION
@ObjectModel.writeEnabled: true
@ObjectModel: {
    semanticKey: ['BusinessPartner', 'Customer', 'CompanyCode'],
    createEnabled,
    updateEnabled,
    deleteEnabled
}
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true

@UI.headerInfo:{
  typeName: 'Company Code',
  typeNamePlural: 'Company Codes',
  title:  { label: 'Company Code Description', value: 'CompanyCodeName' }
  }

@VDM.viewType: #CONSUMPTION

define view C_BPAddlCustCompanyCode
  as select from I_BPAddlCustCompanyCodeTP as BusinessPartnerCustomerCo
  
  association [1..1]  to C_BusinessPartner         as _BusinessPartner         on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  
  association [1..1] to C_BusinessPartnerCustomer   as _BusinessPartnerCustomer    on  $projection.BusinessPartner = _BusinessPartnerCustomer.BusinessPartner

  association [1..1] to C_BPAdditionalCustomer      as _BPAdditionalCustomer       on  $projection.BusinessPartner = _BPAdditionalCustomer.BusinessPartner
                                                                                   and $projection.Customer        = _BPAdditionalCustomer.Customer

  association [1..*] to C_BPAddlCustWhldgTax        as _BusinessPartnerCustWhdgTax on  $projection.BusinessPartner = _BusinessPartnerCustWhdgTax.BusinessPartner
                                                                                   and $projection.Customer        = _BusinessPartnerCustWhdgTax.Customer
                                                                                   and $projection.CompanyCode     = _BusinessPartnerCustWhdgTax.CompanyCode
                                                                                   
  association [1..*] to C_BPAddlCustDunning      as _BPAddlCustDunning       on  $projection.BusinessPartner = _BPAddlCustDunning.BusinessPartner
                                                                               and $projection.Customer        = _BPAddlCustDunning.Customer
                                                                               and $projection.CompanyCode     = _BPAddlCustDunning.CompanyCode

  // Language Independent Value helps

  association [0..1] to I_CustomerCompanyCodeVH     as _CompanyCodeValueHelp       on  $projection.CompanyCodeForEdit = _CompanyCodeValueHelp.CompanyCode
                                                                                   and $projection.Country            = _CompanyCodeValueHelp.Country
                                                                                   
    association [0..1] to C_Custrecnclnacctvhtemp   as _ReconciliationAccountVH  on  $projection.ReconciliationAccount    = _ReconciliationAccountVH.ReconciliationAccount
                                                                                and $projection.CompanyCodeForEdit = _ReconciliationAccountVH.CompanyCode                                                                                 

  association [0..1] to C_AccountingClerkVHTemp     as _AccountingClerkValueHelp   on  $projection.AccountingClerk    = _AccountingClerkValueHelp.AccountingClerk
                                                                                   and $projection.CompanyCodeForEdit = _AccountingClerkValueHelp.CompanyCode
                                                                                
  association [0..1] to I_AlternativePayerVH        as _AlternativePayerValueHelp  on  $projection.AlternativePayerAccount = _AlternativePayerValueHelp.AlternativePayer
                                                                                   and $projection.CompanyCodeForEdit      = _AlternativePayerValueHelp.CompanyCode

  association [0..1] to I_CustheadoffcVH            as _HeadOfficeValueHelp        on  $projection.CustomerHeadOffice = _HeadOfficeValueHelp.Customer
                                                                                   and $projection.CompanyCodeForEdit = _HeadOfficeValueHelp.CompanyCode
  association [0..*] to C_ValAdjmtKeyValueHelpTmp  as _ValueAdjmtKeyValueHelp on  $projection.ValueAdjustmentKey = _ValueAdjmtKeyValueHelp.ValueAdjustmentKey

  //Text Views

  
  association [1..*] to C_SortKeyTextVHtemp         as _SortKeyText                on  $projection.LayoutSortingRule = _SortKeyText.AcctgDocItmDisplaySequenceRule

  association [0..*] to C_CustPaymentTermsTextVHTemp as _PaymentTermsText           on  $projection.PaymentTerms = _PaymentTermsText.CustomerPaymentTerms
    
  association [0..*] to C_ToleranceGroupTextVHTemp  as _ToleranceGroupText         on  _ToleranceGroupText.CompanyCode        = $projection.CompanyCode
                                                                                   and _ToleranceGroupText.APARToleranceGroup = $projection.APARToleranceGroup

  association [1..*] to C_PaymentmethodTextVHTemp   as _PaymentMethodText          on  $projection.PaymentMethodsList = _PaymentMethodText.PaymentMethod
                                                                                   and $projection.Country            = _PaymentMethodText.Country

  association [0..*] to I_PaymentBlockingReasonText as _PaymentBlockingReasonText  on  $projection.PaymentBlockingReason = _PaymentBlockingReasonText.PaymentBlockingReason
  
  association [0..*] to I_InterestCalculationCodeText as _InterestCalculationCodeText                    on $projection.InterestCalculationCode = _InterestCalculationCodeText.InterestCalculationCode              

  association [0..*] to I_CashPlanningGroupText as _PlanningGroupText on $projection.CashPlanningGroup = _PlanningGroupText.CashPlanningGroup

  association [0..*] to C_KnownOrNegotiatedLeaveTxtTmp as _KnownOrNegotiatedLeaveText on $projection.KnownOrNegotiatedLeave = _KnownOrNegotiatedLeaveText.KnownOrNegotiatedLeave

{
  key BusinessPartnerCustomerCo.BusinessPartner,
  key BusinessPartnerCustomerCo.Customer,
  key BusinessPartnerCustomerCo.CompanyCode,
      BusinessPartnerCustomerCo.BusinessPartnerForEdit,
      BusinessPartnerCustomerCo.CustomerForEdit,
      @ObjectModel: {
                 foreignKey.association: '_CompanyCodeValueHelp'
                }
      @ObjectModel.text.element: ['CompanyCodeName']          
      BusinessPartnerCustomerCo.CompanyCodeForEdit,
      @ObjectModel: {
                 foreignKey.association: '_AccountingClerkValueHelp'
               }
      BusinessPartnerCustomerCo.AccountingClerk,
      //@ObjectModel.foreignKey.association: '_ReconciliationAccountVH'

      BusinessPartnerCustomerCo.ReconciliationAccount, 
      BusinessPartnerCustomerCo.PhysicalInventoryBlockInd,
      @ObjectModel.text.association: '_PaymentBlockingReasonText'
      BusinessPartnerCustomerCo.PaymentBlockingReason,
      BusinessPartnerCustomerCo.UserAtCustomer,
      BusinessPartnerCustomerCo.AccountingClerkPhoneNumber,
      BusinessPartnerCustomerCo.AccountingClerkFaxNumber,
      BusinessPartnerCustomerCo.AccountingClerkInternetAddress,
      BusinessPartnerCustomerCo.AccountByCustomer,
      BusinessPartnerCustomerCo.IsToBeLocallyProcessed,
      BusinessPartnerCustomerCo.CustomerAccountNote,
      BusinessPartnerCustomerCo.CollectiveInvoiceVariant,
      @ObjectModel.text.association: '_PaymentTermsText'
      BusinessPartnerCustomerCo.PaymentTerms, 
      @ObjectModel.text.association: '_ToleranceGroupText'
      BusinessPartnerCustomerCo.APARToleranceGroup,
      BusinessPartnerCustomerCo.CustomerSupplierClearingIsUsed,
      BusinessPartnerCustomerCo.RecordPaymentHistoryIndicator,
      BusinessPartnerCustomerCo.ItemIsToBePaidSeparately,
      BusinessPartnerCustomerCo.PaytAdviceIsSentbyEDI,
      @ObjectModel.text.association: '_PaymentMethodText'
      BusinessPartnerCustomerCo.PaymentMethodsList,
      @ObjectModel: {
                  foreignKey.association: '_AlternativePayerValueHelp'
                }
      BusinessPartnerCustomerCo.AlternativePayerAccount,
      @ObjectModel: {
                  foreignKey.association: '_HeadOfficeValueHelp'
                }
      BusinessPartnerCustomerCo.CustomerHeadOffice,
      @ObjectModel.text.association: '_SortKeyText'
      BusinessPartnerCustomerCo.LayoutSortingRule,
      //@Consumption.hidden: true

      BusinessPartnerCustomerCo.AuthorizationGroup,
      @ObjectModel.text.association: '_InterestCalculationCodeText'
      BusinessPartnerCustomerCo.InterestCalculationCode,
      BusinessPartnerCustomerCo.InterestCalculationDate,
      @Consumption.hidden: true
      BusinessPartnerCustomerCo.IntrstCalcFrequencyInMonths,
      @Consumption.hidden: true
      BusinessPartnerCustomerCo.LastInterestCalcRunDate,
      BusinessPartnerCustomerCo.HouseBank,
      BusinessPartnerCustomerCo.Country,
      @ObjectModel.text.association: '_PlanningGroupText'
      BusinessPartnerCustomerCo.CashPlanningGroup,
      @Consumption.valueHelp: '_ValueAdjmtKeyValueHelp'   
      BusinessPartnerCustomerCo.ValueAdjustmentKey,
      @ObjectModel.text.association: '_KnownOrNegotiatedLeaveText'
      BusinessPartnerCustomerCo.KnownOrNegotiatedLeave,
      BusinessPartnerCustomerCo.CompanyCodeDunningIsByDunArea,
      BusinessPartnerCustomerCo.CompanyCodeName,
      
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
      _BusinessPartnerCustomer,
       @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
      _BusinessPartner,
      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
      _BPAdditionalCustomer,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _BusinessPartnerCustWhdgTax,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _BPAddlCustDunning,
      _HeadOfficeValueHelp,
      _CompanyCodeValueHelp,
      _ReconciliationAccountVH,
      _AccountingClerkValueHelp,
      _InterestCalculationCodeText,
      _AlternativePayerValueHelp,
      _SortKeyText,
      _PaymentTermsText,
      _ToleranceGroupText,
      _PaymentMethodText,
      _PaymentBlockingReasonText,
      _PlanningGroupText,
      _ValueAdjmtKeyValueHelp,
      _KnownOrNegotiatedLeaveText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPADDLCUSTCOMPANYCODETP"
],
"ASSOCIATED":
[
"C_ACCOUNTINGCLERKVHTEMP",
"C_BPADDITIONALCUSTOMER",
"C_BPADDLCUSTDUNNING",
"C_BPADDLCUSTWHLDGTAX",
"C_BUSINESSPARTNER",
"C_BUSINESSPARTNERCUSTOMER",
"C_CUSTPAYMENTTERMSTEXTVHTEMP",
"C_CUSTRECNCLNACCTVHTEMP",
"C_KNOWNORNEGOTIATEDLEAVETXTTMP",
"C_PAYMENTMETHODTEXTVHTEMP",
"C_SORTKEYTEXTVHTEMP",
"C_TOLERANCEGROUPTEXTVHTEMP",
"C_VALADJMTKEYVALUEHELPTMP",
"I_ALTERNATIVEPAYERVH",
"I_CASHPLANNINGGROUPTEXT",
"I_CUSTHEADOFFCVH",
"I_CUSTOMERCOMPANYCODEVH",
"I_INTERESTCALCULATIONCODETEXT",
"I_PAYMENTBLOCKINGREASONTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/